Issue looping through name array to create resources using a module that calls another module

[sam-bryant]

I'm having looping related issues with some modules I've created. My modules call Azure Verified Modules with parameters customized to my organization. In this example I am trying to create three user assigned identities. When I deploy the rg-test.bicep file it creates three deployments. In each deployment Inputs.name shows the correct name but the outputs for all three deployments shows the same name (and other properties). The name shown there is the resource that actually gets created, the others do not.

I am at a loss at this point and couldn't find the right keywords to google to figure it out. Here are roughly the files that I have. Any suggestions are greatly appreciated.

rg-test.bicep

var userAssignedIdentityNames = [
  'id-test-001'
  'id-test-002'
  'id-test-003'
]

module userAssignedIdentity '/module.UserAssignedIdentity.bicep' = [ for (userAssignedIdentityName, i) in userAssignedIdentityNames: {
    dependsOn: [resourceGroup]
    name: 'deployment_${userAssignedIdentityName}_${deploymentDateTime}'
    scope: az.resourceGroup(resourceGroupName)
    params: {
      location: resourceLocation
      name: userAssignedIdentityName
      tags: resourceGroupTags
    }
  }]

module.UserAssignedIdentity.bicep

param name string
param location string
param tags object

module userAssignedIdentity 'br/public:avm/res/managed-identity/user-assigned-identity:0.2.1' = {
  name: 'userAssignedIdentityDeployment'
  params: {
    // Required parameters
    name: name
    // Non-required parameters
    location: location
    tags: tags
  }
}

@description('The name of the user assigned identity.')
output name string = userAssignedIdentity.outputs.name

@description('The resource ID of the user assigned identity.')
output resourceId string = userAssignedIdentity.outputs.resourceId

@description('The principal ID (object ID) of the user assigned identity.')
output principalId string = userAssignedIdentity.outputs.principalId

@description('The client ID (application ID) of the user assigned identity.')
output clientId string = userAssignedIdentity.outputs.clientId

@description('The resource group the user assigned identity was deployed into.')
output resourceGroupName string = resourceGroup().name

@description('The location the resource was deployed into.')
output location string = userAssignedIdentity.outputs.location

[sam-bryant]

5 minutes after creating this my coworker identified it was due to the name (deployment name) in the module definition:

module.UserAssignedIdentity.bicep

param name string
param location string
param tags object

module userAssignedIdentity 'br/public:avm/res/managed-identity/user-assigned-identity:0.2.1' = {
+  name: 'userAssignedIdentityDeployment-{name}'
-  name: 'userAssignedIdentityDeployment'
  params: {
    // Required parameters
    name: name
    // Non-required parameters
    location: location
    tags: tags
  }
}