Incorrect fix for 'use-parent-property' warning with blobContainer and fileShare

[StephenWeatherford]

param storageAccountName string = toLower(take('stg${uniqueString(resourceGroup().id, deployment().name)}', 24))
param blobContainerName string = 'blobcontainer${uniqueString(resourceGroup().id, deployment().name)}'

param fileShareName string = 'fileshare${uniqueString(resourceGroup().id, deployment().name)}'

resource storageAccount 'Microsoft.Storage/storageAccounts@2022-09-01' = {
  name: storageAccountName
  location: resourceGroup().location
  sku: {
    name: 'Standard_LRS'
  }
  kind: 'StorageV2'
  properties: {
    accessTier: 'Hot'
  }
}

resource blobContainer 'Microsoft.Storage/storageAccounts/blobServices/containers@2022-09-01' = {
  name: '${storageAccount.name}/default/${blobContainerName}'
  properties: {
    publicAccess: 'None'
  }
}

resource fileShare 'Microsoft.Storage/storageAccounts/fileServices/shares@2022-09-01' = {
  name: '${storageAccount.name}/default/${fileShareName}'
  properties: {
    shareQuota: 100
  }
}

Gives these warnings:

Use quick fix on the blobContainer and fileShare resources, and you get this:

resource blobContainer 'Microsoft.Storage/storageAccounts/blobServices/containers@2022-09-01' = {
  parent: storageAccount
  name: 'default/${blobContainerName}'
  properties: {
    publicAccess: 'None'
  }
}

resource fileShare 'Microsoft.Storage/storageAccounts/fileServices/shares@2022-09-01' = {
  parent: storageAccount
  name: 'default/${fileShareName}'
  properties: {
    shareQuota: 100
  }
}

with these errors:

	"message": "The property \"parent\" expected a value of type \"Microsoft.Storage/storageAccounts/blobServices\" but the provided value is of type \"Microsoft.Storage/storageAccounts@2022-09-01\".",
	"message": "Expected resource name to not contain any \"/\" characters. Child resources with a parent resource reference (via the parent property or via nesting) must not contain a fully-qualified name.",
	"message": "The property \"parent\" expected a value of type \"Microsoft.Storage/storageAccounts/fileServices\" but the provided value is of type \"Microsoft.Storage/storageAccounts@2022-09-01\".",
	"message": "Expected resource name to not contain any \"/\" characters. Child resources with a parent resource reference (via the parent property or via nesting) must not contain a fully-qualified name.",

EXPECTED: Not sure, but possibly one of:

1. better fix (is creating blobServer/fileService the only posible fix?)
2. no warning
3. ??

Here's the version that fully works (using copilot, multiple iterations, adding blobService and fileService resources)

resource blobService 'Microsoft.Storage/storageAccounts/blobServices@2022-09-01' = {
  parent: storageAccount
  name: 'default'
}

resource blobContainer 'Microsoft.Storage/storageAccounts/blobServices/containers@2022-09-01' = {
  parent: blobService
  name: blobContainerName
  properties: {
    publicAccess: 'None'
  }
}

resource fileService 'Microsoft.Storage/storageAccounts/fileServices@2022-09-01' = {
  parent: storageAccount
  name: 'default'
}

resource fileShare 'Microsoft.Storage/storageAccounts/fileServices/shares@2022-09-01' = {
  parent: fileService
  name: fileShareName
  properties: {
    shareQuota: 100
  }
}