-
Notifications
You must be signed in to change notification settings - Fork 4
/
Copy pathpure_alpha_equivScript.sml
3735 lines (3591 loc) · 130 KB
/
pure_alpha_equivScript.sml
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
(*
Alpha equivalence and permutations for PureCake expressions
*)
open HolKernel Parse boolLib bossLib term_tactic;
open fixedPointTheory arithmeticTheory listTheory stringTheory alistTheory
optionTheory pairTheory ltreeTheory llistTheory bagTheory
BasicProvers pred_setTheory relationTheory rich_listTheory finite_mapTheory
dep_rewrite;
open pure_expTheory pure_valueTheory pure_evalTheory pure_eval_lemmasTheory
pure_exp_lemmasTheory pure_limitTheory pure_exp_relTheory pure_miscTheory;
val _ = temp_delsimps ["lift_disj_eq", "lift_imp_disj"]
val _ = new_theory "pure_alpha_equiv";
val no_IN = SIMP_RULE std_ss [IN_DEF];
Definition perm1_def:
perm1 v1 v2 v = if v = v1 then v2 else if v = v2 then v1 else v
End
Definition perm_exp_def:
(perm_exp v1 v2 (Var v) = Var (perm1 v1 v2 v))
∧ (perm_exp v1 v2 (Prim op l) = Prim op (MAP (perm_exp v1 v2) l))
∧ (perm_exp v1 v2 (App e1 e2) = App (perm_exp v1 v2 e1) (perm_exp v1 v2 e2))
∧ (perm_exp v1 v2 (Lam v e) = Lam (perm1 v1 v2 v) (perm_exp v1 v2 e))
∧ (perm_exp v1 v2 (Letrec l e) =
Letrec
(MAP (λ(x,z). (perm1 v1 v2 x, perm_exp v1 v2 z)) l)
(perm_exp v1 v2 e)
)
Termination
WF_REL_TAC ‘measure(exp_size o SND o SND)’ >>
rw[] >> imp_res_tac exp_size_lemma >> rw[]
End
Theorem perm1_cancel[simp]:
perm1 v1 v2 (perm1 v1 v2 x) = x
Proof
rw[perm1_def] >> fs[CaseEq "bool"] >> fs[]
QED
Theorem perm_exp_cancel[simp]:
∀v1 v2 e. perm_exp v1 v2 (perm_exp v1 v2 e) = e
Proof
ho_match_mp_tac perm_exp_ind >>
rw[perm_exp_def,MAP_MAP_o,combinTheory.o_DEF,ELIM_UNCURRY] >>
rw[LIST_EQ_REWRITE] >>
gvs[MEM_EL,PULL_EXISTS,EL_MAP] >>
metis_tac[PAIR,FST,SND]
QED
Theorem perm1_eq_cancel[simp]:
perm1 v1 v2 v3 = perm1 v1 v2 v4 ⇔ v3 = v4
Proof
rw[perm1_def] >> simp[]
QED
Theorem perm_exp_eqvt:
∀fv2 fv3 e.
MAP (perm1 fv2 fv3) (freevars_l e) = freevars_l(perm_exp fv2 fv3 e)
Proof
ho_match_mp_tac perm_exp_ind >>
rw[perm_exp_def,freevars_def,FILTER_MAP,combinTheory.o_DEF,MAP_MAP_o,MAP_FLAT]
>- (AP_TERM_TAC >> rw[MAP_EQ_f])
>- (pop_assum (assume_tac o GSYM) >>
rw[FILTER_MAP,combinTheory.o_DEF])
>- (rw[ELIM_UNCURRY] >>
pop_assum (assume_tac o GSYM) >>
simp[FILTER_APPEND] >>
simp[FILTER_MAP,combinTheory.o_DEF] >>
qmatch_goalsub_abbrev_tac ‘a1 ++ a2 = a3 ++ a4’ >>
‘a1 = a3 ∧ a2 = a4’ suffices_by simp[] >>
unabbrev_all_tac >>
conj_tac >- (AP_TERM_TAC >> rw[FILTER_EQ,MEM_MAP]) >>
rw[FILTER_FLAT,MAP_FLAT,MAP_MAP_o,combinTheory.o_DEF,FILTER_FILTER] >>
AP_TERM_TAC >>
rw[MAP_EQ_f] >>
PairCases_on ‘x’ >>
first_assum (drule_then (assume_tac o GSYM o SIMP_RULE std_ss [])) >>
simp[FILTER_MAP,combinTheory.o_DEF,MEM_MAP])
QED
Theorem perm1_sym:
perm1 x y z = perm1 y x z
Proof
rw[perm1_def]
QED
Theorem perm_exp_sym:
∀x y e.
perm_exp x y e = perm_exp y x e
Proof
ho_match_mp_tac perm_exp_ind >>
rw[perm_exp_def,perm1_sym,MAP_EQ_f] >>
gvs[] >> pairarg_tac >> gvs[MAP_EQ_f,perm1_sym] >> res_tac
QED
Theorem closed_perm:
closed(perm_exp v1 v2 e) = closed e
Proof
rw[closed_def,freevars_equiv,GSYM perm_exp_eqvt]
QED
(**************** freevars/boundvars perm_exp lemmas ******************)
Theorem freevars_eqvt:
freevars (perm_exp x y e) = IMAGE (perm1 x y) (freevars e)
Proof
rw[freevars_equiv] >>
rw[EXTENSION, GSYM perm_exp_eqvt, MEM_MAP]
QED
Theorem boundvars_l_eqvt:
∀n m e. MAP (perm1 n m) (boundvars_l e) = boundvars_l (perm_exp n m e)
Proof
strip_tac >> strip_tac >> recInduct boundvars_l_ind >>
rw[boundvars_def, perm_exp_def] >>
simp[MAP_FLAT, MAP_MAP_o, combinTheory.o_DEF, LAMBDA_PROD] >> simp[GSYM FST_THM] >>
AP_TERM_TAC >> rw[MAP_EQ_f] >>
pairarg_tac >> gvs[] >>
first_x_assum drule >> simp[]
QED
Theorem boundvars_eqvt:
boundvars (perm_exp x y e) = IMAGE (perm1 x y) (boundvars e)
Proof
rw[boundvars_equiv] >>
rw[EXTENSION, GSYM boundvars_l_eqvt, MEM_MAP]
QED
(*******************)
Definition perm_v_def:
perm_v x y v =
gen_v (λpath.
case v_lookup path v of
(Closure' z e, len) => (Closure' (perm1 x y z) (perm_exp x y e), len)
| x => x)
End
Theorem perm_v_thm:
perm_v x y v =
case v of
Constructor s xs => Constructor s (MAP (perm_v x y) xs)
| Closure z e => Closure (perm1 x y z) (perm_exp x y e)
| v => v
Proof
‘∀v1 v2. ((∃v. v1 = perm_v x y v ∧
v2 = (case v of
Constructor s xs => Constructor s (MAP (perm_v x y) xs)
| Closure z e => Closure (perm1 x y z) (perm_exp x y e)
| v => v)) ∨ v1 = v2)
⇒ v1 = v2’ suffices_by metis_tac[] >>
ho_match_mp_tac v_coinduct >>
reverse(rw[])
>- (Cases_on ‘v1’ >> gvs[] >> match_mp_tac EVERY2_refl >> rw[]) >>
TOP_CASE_TAC
>- (rw[perm_v_def] >> rw[Once gen_v,v_lookup_Atom])
>- (rw[Once perm_v_def] >> rw[Once gen_v,v_lookup_Constructor] >>
‘MAP (perm_v x y) t =
MAP (perm_v x y) (GENLIST (λx. EL x t) (LENGTH t))
’
by(AP_TERM_TAC >> CONV_TAC SYM_CONV >>
match_mp_tac GENLIST_EL >> rw[]) >>
pop_assum SUBST_ALL_TAC >>
simp[MAP_GENLIST] >>
rw[LIST_REL_GENLIST,oEL_THM] >>
simp[perm_v_def])
>- (rw[perm_v_def] >> rw[Once gen_v,v_lookup_Closure])
>- (rw[perm_v_def] >> rw[Once gen_v,v_lookup_Diverge] >> rw[gen_v_Diverge])
>- (rw[perm_v_def] >> rw[Once gen_v,v_lookup_Error])
QED
Theorem perm_v_clauses:
perm_v x y (Constructor s xs) = Constructor s (MAP (perm_v x y) xs) ∧
perm_v x y Diverge = Diverge ∧
perm_v x y (Atom b) = Atom b ∧
perm_v x y Error = Error ∧
perm_v x y (Closure z e) = Closure (perm1 x y z) (perm_exp x y e) ∧
perm_v x y (Constructor s xs) = Constructor s (MAP (perm_v x y) xs)
Proof
rpt conj_tac >> rw[Once perm_v_thm] >>
PURE_ONCE_REWRITE_TAC[perm_v_thm] >>
simp[]
QED
Theorem perm_v_cancel[simp]:
perm_v x y (perm_v x y v) = v
Proof
‘∀v1 v2. v2 = perm_v x y (perm_v x y v1) ⇒ v1 = v2’ suffices_by metis_tac[] >>
ho_match_mp_tac v_coinduct >>
Cases >> TRY(rw[perm_v_thm] >> NO_TAC) >>
ntac 2 (rw[Once perm_v_thm]) >>
rw[LIST_REL_MAP2] >>
match_mp_tac EVERY2_refl >> rw[]
QED
Definition perm_v_prefix_def:
perm_v_prefix x y v =
case v of
| Closure' z e => Closure' (perm1 x y z) (perm_exp x y e)
| v => v
End
Definition perm_wh_def:
(perm_wh x y (wh_Constructor s xs) = wh_Constructor s (MAP (perm_exp x y) xs)) ∧
(perm_wh x y (wh_Closure s xs) = wh_Closure (perm1 x y s) (perm_exp x y xs)) ∧
(perm_wh x y wh = wh)
End
Theorem gen_v_eqvt:
perm_v v1 v2 (gen_v f) = gen_v(λx. (perm_v_prefix v1 v2 ## I) (f x))
Proof
‘∀v v' v1 v2 f. v = perm_v v1 v2 (gen_v f) ∧
v' = gen_v(λx. (perm_v_prefix v1 v2 ## I) (f x)) (*∨ v = v'*) ⇒ v = v'’
suffices_by metis_tac[] >>
Ho_Rewrite.PURE_REWRITE_TAC [GSYM PULL_EXISTS] >>
ho_match_mp_tac v_coinduct >>
reverse(rw[]) >> (*(Cases_on ‘v’ >> rw[] >> match_mp_tac EVERY2_refl >> simp[]) >>*)
simp[Once gen_v] >> rpt(TOP_CASE_TAC)
>- (rename1 ‘Atom’ >>
disj1_tac >> simp[perm_v_def,v_lookup_Atom] >>
simp[Once gen_v] >>
simp[Once gen_v] >>
simp[perm_v_prefix_def])
>- (rename1 ‘Constructor’ >>
disj2_tac >> disj1_tac >>
simp[Once gen_v] >>
simp[Once perm_v_thm] >>
simp[Once gen_v,v_lookup_Constructor] >>
simp[Once perm_v_prefix_def] >>
rw[MAP_GENLIST,LIST_REL_GENLIST] >>
qexists_tac ‘v1’ >>
qexists_tac ‘v2’ >>
qexists_tac ‘f o CONS n’ >>
simp[combinTheory.o_DEF])
>- (rename1 ‘Closure’ >>
ntac 2 disj2_tac >> disj1_tac >>
simp[Once gen_v] >>
simp[Once perm_v_thm] >>
simp[Once gen_v,v_lookup_Constructor] >>
simp[Once perm_v_prefix_def])
>- (rename1 ‘Diverge’ >>
ntac 3 disj2_tac >> disj1_tac >>
PURE_ONCE_REWRITE_TAC[gen_v] >>
simp[] >>
PURE_ONCE_REWRITE_TAC[perm_v_thm] >>
simp[] >>
PURE_ONCE_REWRITE_TAC[perm_v_prefix_def] >>
simp[])
>- (rename1 ‘Error’ >>
ntac 4 disj2_tac >>
simp[Once gen_v] >>
simp[Once perm_v_thm] >>
simp[Once gen_v,v_lookup_Constructor] >>
simp[Once perm_v_prefix_def])
QED
(* Slow (~10s) *)
Theorem perm_exp_inj:
∀v1 v2 e e'. (perm_exp v1 v2 e = perm_exp v1 v2 e') ⇔ e = e'
Proof
simp[EQ_IMP_THM] >>
ho_match_mp_tac perm_exp_ind >>
rpt conj_tac >>
simp[GSYM RIGHT_FORALL_IMP_THM] >>
CONV_TAC(RESORT_FORALL_CONV rev) >>
Cases >> rw[perm_exp_def]
>- (
rw[LIST_EQ_REWRITE] >>
gvs[MAP_EQ_EVERY2, LIST_REL_EL_EQN, MEM_EL, PULL_EXISTS]
)
>- (
rw[LIST_EQ_REWRITE] >>
gvs[MAP_EQ_EVERY2, LIST_REL_EL_EQN, MEM_EL, PULL_EXISTS] >>
first_x_assum drule >>
Cases_on `EL x l'` >> Cases_on `EL x l` >> rw[] >>
first_x_assum irule >> simp[] >>
goal_assum drule >> simp[Once EQ_SYM]
)
QED
Theorem perm_v_inj:
(perm_v v1 v2 v = perm_v v1 v2 v') ⇔ v = v'
Proof
‘∀v v'.
perm_v v1 v2 v = perm_v v1 v2 v' ⇒
v = v'’
suffices_by metis_tac[] >>
ho_match_mp_tac v_coinduct >>
Cases >> Cases >> rw[perm_v_clauses,perm_exp_inj] >>
pop_assum mp_tac >>
qid_spec_tac ‘t'’ >>
Induct_on ‘t’ >- rw[] >>
strip_tac >> Cases >> rw[]
QED
Theorem perm_wh_inj:
∀wh wh' v1 v2. (perm_wh v1 v2 wh = perm_wh v1 v2 wh') ⇔ wh = wh'
Proof
Cases >> Cases >> rw[perm_wh_def] >> eq_tac >> rw[]
>- (
gvs[MAP_EQ_EVERY2, LIST_REL_EL_EQN, LIST_EQ_REWRITE] >> rw[] >>
irule (iffLR perm_exp_inj) >>
first_x_assum drule >> rw[] >>
goal_assum drule
)
>- (
irule (iffLR perm_exp_inj) >>
goal_assum drule
)
QED
Definition perm_subst_def:
perm_subst v1 v2 s =
FUN_FMAP
(λz. perm_exp v1 v2 (THE(FLOOKUP s (perm1 v1 v2 z))))
{z | perm1 v1 v2 z ∈ FDOM s}
End
Theorem perm_subst_sym:
perm_subst v1 v2 s = perm_subst v2 v1 s
Proof
rw[perm_subst_def,perm_exp_sym,perm1_sym]
QED
Theorem perm1_sym':
perm1 v1 v2 = perm1 v2 v1
Proof
rw[FUN_EQ_THM,perm1_sym]
QED
Theorem perm_subst_flookup:
FLOOKUP(perm_subst v1 v2 s) x =
OPTION_MAP (perm_exp v1 v2) (FLOOKUP s (perm1 v1 v2 x))
Proof
rw[perm_subst_def] >>
dep_rewrite.DEP_ONCE_REWRITE_TAC [FLOOKUP_FUN_FMAP] >>
conj_tac
>- (match_mp_tac FINITE_PRED_11 >> rw[perm1_eq_cancel]) >>
rw[FLOOKUP_DEF]
QED
Theorem perm_subst_fdom:
FDOM(perm_subst v1 v2 s) = {z | perm1 v1 v2 z ∈ FDOM s}
Proof
rw[perm_subst_def] >>
dep_rewrite.DEP_ONCE_REWRITE_TAC [FDOM_FMAP] >>
match_mp_tac FINITE_PRED_11 >> rw[perm1_eq_cancel]
QED
Theorem perm_subst_cancel[simp]:
perm_subst v1 v2 (perm_subst v1 v2 s) = s
Proof
rw[fmap_eq_flookup,perm_subst_flookup,OPTION_MAP_COMPOSE,combinTheory.o_DEF]
QED
Theorem fdomsub_eqvt:
perm_subst v1 v2 (s \\ x) = (perm_subst v1 v2 s \\ perm1 v1 v2 x)
Proof
rw[fmap_eq_flookup,perm_subst_flookup,DOMSUB_FLOOKUP_THM] >>
rw[perm1_def] >>
rpt(PURE_FULL_CASE_TAC >> gvs[])
QED
Theorem FDIFF_eqvt:
perm_subst v1 v2 (FDIFF s s') =
FDIFF (perm_subst v1 v2 s) (IMAGE (perm1 v1 v2) s')
Proof
rw[fmap_eq_flookup,perm_subst_flookup,DOMSUB_FLOOKUP_THM,FDIFF_def,FLOOKUP_DRESTRICT] >>
rw[perm1_def] >>
rpt(PURE_FULL_CASE_TAC >> gvs[]) >>
metis_tac[]
QED
Theorem subst_eqvt:
∀v1 v2 s e.
perm_exp v1 v2 (subst s e) =
subst (perm_subst v1 v2 s) (perm_exp v1 v2 e)
Proof
ntac 2 strip_tac >>
ho_match_mp_tac subst_ind >>
rw[subst_def,perm_exp_def,perm_subst_flookup,MAP_MAP_o,MAP_EQ_f,combinTheory.o_DEF,
fdomsub_eqvt,FDIFF_eqvt]
>- (TOP_CASE_TAC >> simp[perm_exp_def])
>- (PairCases_on ‘x’ >> gvs[] >>
res_tac >>
simp[] >>
rw[LIST_TO_SET_MAP,IMAGE_IMAGE,ELIM_UNCURRY,combinTheory.o_DEF])
>- (rw[LIST_TO_SET_MAP,IMAGE_IMAGE,ELIM_UNCURRY,combinTheory.o_DEF])
QED
Theorem subst_eqvt_alt:
subst f (perm_exp x y e) =
perm_exp x y (subst (perm_subst x y f) e)
Proof
rw[subst_eqvt, perm_subst_cancel]
QED
Theorem subst1_eqvt:
∀v1 v2 s e1 e.
perm_exp v1 v2 (subst1 s e1 e) =
subst1 (perm1 v1 v2 s) (perm_exp v1 v2 e1) (perm_exp v1 v2 e)
Proof
rw[] >>
qspecl_then [`v1`,`v2`,`FEMPTY |+ (s,e1)`,`e`] assume_tac subst_eqvt >>
rw[] >> MK_COMB_TAC >> rw[] >> AP_TERM_TAC >>
rw[fmap_eq_flookup, perm_subst_flookup] >>
rw[FLOOKUP_DEF] >> gvs[perm1_cancel]
QED
Theorem subst1_eqvt_alt:
subst1 s e' (perm_exp x y e) =
perm_exp x y (subst1 (perm1 x y s) (perm_exp x y e') e)
Proof
rw[subst1_eqvt, perm_subst_cancel]
QED
Theorem bind_eqvt:
∀v1 v2 s e.
perm_exp v1 v2 (bind s e) =
bind (perm_subst v1 v2 s) (perm_exp v1 v2 e)
Proof
rw[] >> fs[bind_def] >>
reverse (IF_CASES_TAC) >> gvs[]
>- (
fs[perm_exp_def, perm_subst_flookup, PULL_EXISTS] >>
IF_CASES_TAC >> gvs[] >>
first_x_assum (qspec_then `perm1 v1 v2 n` assume_tac) >>
gvs[perm1_cancel, closed_perm]
) >>
reverse (IF_CASES_TAC) >> gvs[subst_eqvt, perm_subst_flookup] >>
last_x_assum (qspec_then `perm1 v1 v2 n` assume_tac) >> gvs[closed_perm]
QED
Theorem bind1_eqvt:
∀v1 v2 n e1 e.
perm_exp v1 v2 (bind1 n e1 e) =
bind1 (perm1 v1 v2 n) (perm_exp v1 v2 e1) (perm_exp v1 v2 e)
Proof
rw[] >> fs[bind_def, FLOOKUP_UPDATE, closed_perm] >>
IF_CASES_TAC >> gvs[perm_exp_def, subst1_eqvt]
QED
Theorem expandLets_eqvt:
∀v1 v2 i cn nm vs cs.
perm_exp v1 v2 (expandLets i cn nm vs cs) =
expandLets i cn (perm1 v1 v2 nm) (MAP (perm1 v1 v2) vs) (perm_exp v1 v2 cs)
Proof
ntac 2 strip_tac >>
CONV_TAC(RESORT_FORALL_CONV rev) >>
Induct_on ‘vs’ >> rw[expandLets_def,perm_exp_def]
QED
Theorem expandCases_eqvt:
∀v1 v2 x nm css.
perm_exp v1 v2 (expandCases x nm css) =
expandCases (perm_exp v1 v2 x) (perm1 v1 v2 nm)
(MAP (λ(x,y,z). (x,MAP (perm1 v1 v2) y,perm_exp v1 v2 z)) css)
Proof
ntac 2 strip_tac >>
simp[expandCases_def,perm_exp_def] >>
ho_match_mp_tac expandRows_ind >>
rw[perm_exp_def,expandRows_def,expandLets_eqvt]
QED
Theorem subst_funs_eqvt:
∀ v1 v2 fns e.
perm_exp v1 v2 (subst_funs fns e) =
subst_funs (MAP (perm1 v1 v2 ## perm_exp v1 v2) fns) (perm_exp v1 v2 e)
Proof
rw[subst_funs_def, bind_eqvt] >>
MK_COMB_TAC >> rw[] >> AP_TERM_TAC >>
rw[fmap_eq_flookup, perm_subst_flookup, flookup_fupdate_list] >>
gvs[GSYM MAP_REVERSE, ALOOKUP_MAP] >>
qmatch_goalsub_abbrev_tac `ALOOKUP (MAP (foo ## bar) l) x` >>
`ALOOKUP (MAP (foo ## bar) l) x =
ALOOKUP (MAP (λ(p1,p2). (p1,bar p2)) l) (foo x)` by (
unabbrev_all_tac >> rename1 `ALOOKUP (MAP _ l)` >>
Induct_on `l` >> gvs[] >> rw[] >>
PairCases_on `h` >> fs[] >>
IF_CASES_TAC
>- (qspec_then `h0` assume_tac (GEN_ALL perm1_cancel) >> gvs[]) >>
IF_CASES_TAC >> gvs[]) >>
rw[] >> unabbrev_all_tac >> rw[ALOOKUP_MAP] >>
Cases_on `ALOOKUP (REVERSE fns) (perm1 v1 v2 x)` >> gvs[] >>
fs[perm_exp_def] >>
rw[MAP_EQ_f] >> PairCases_on `e` >> fs[]
QED
Triviality subst_funs_eqvt_alt:
∀ v1 v2 fns e.
perm_exp v1 v2 (subst_funs fns e) =
subst_funs (MAP (λ(n,x). (perm1 v1 v2 n, perm_exp v1 v2 x)) fns) (perm_exp v1 v2 e)
Proof
rw[subst_funs_eqvt] >>
MK_COMB_TAC >> rw[] >> AP_TERM_TAC >>
rw[MAP_EQ_f] >> PairCases_on `e` >> fs[]
QED
Theorem error_Atom_perm_wh:
∀v1 v2 x. error_Atom (perm_wh v1 v2 x) = error_Atom x
Proof
ho_match_mp_tac perm_wh_ind \\ rw [perm_wh_def]
QED
Theorem dest_Atom_perm_wh:
∀v1 v2 x. ¬error_Atom x ⇒ dest_Atom (perm_wh v1 v2 x) = dest_Atom x
Proof
ho_match_mp_tac perm_wh_ind \\ rw [perm_wh_def]
QED
Triviality get_atoms_perm_cancel:
∀v1 v2 l.
get_atoms (MAP (perm_wh v1 v2) l) = get_atoms l
Proof
rw [get_atoms_def, EXISTS_MAP, error_Atom_perm_wh, SF ETA_ss]
\\ gs [MEM_MAP]
>- (
Cases_on ‘y’ \\ gs [perm_wh_def])
>- (
gs [DISJ_EQ_IMP, Once (DECIDE “A ⇒ ¬B ⇔ B ⇒ ¬A”)]
\\ first_x_assum (drule_then assume_tac)
\\ gs [perm_wh_def])
\\ rw [MAP_MAP_o, combinTheory.o_DEF, MAP_EQ_f]
\\ irule dest_Atom_perm_wh
\\ gs [EVERY_MEM]
QED
Theorem eval_wh_to_eqvt:
∀v1 v2 k e.
perm_wh v1 v2 (eval_wh_to k e) =
eval_wh_to k (perm_exp v1 v2 e)
Proof
gen_tac >> gen_tac >>
recInduct eval_wh_to_ind >> rw[] >>
gvs[perm_wh_def, eval_wh_to_def, perm_exp_def]
>- (
IF_CASES_TAC >> gvs[perm_wh_def] >>
TOP_CASE_TAC >> gvs[perm_wh_def]
>- (
Cases_on `eval_wh_to k x` >> gvs[dest_wh_Closure_def, perm_wh_def] >>
EVERY_CASE_TAC >> gvs[] >>
last_x_assum (assume_tac o GSYM) >> gvs[]
) >>
Cases_on `eval_wh_to k x` >> gvs[dest_wh_Closure_def, perm_wh_def] >>
last_x_assum (assume_tac o GSYM) >> gvs[] >>
IF_CASES_TAC >> gvs[perm_wh_def] >>
gvs[bind1_eqvt]
)
>- (
IF_CASES_TAC >> gvs[perm_wh_def] >>
gvs[subst_funs_eqvt, pure_miscTheory.PAIR_MAP_ALT]
) >>
TOP_CASE_TAC >> gvs[perm_wh_def]
>- (IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute])
>- (CONV_TAC $ DEPTH_CONV ETA_CONV >> simp[])
>- (IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute])
>- (IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute])
>- (
simp[MAP_MAP_o, combinTheory.o_DEF] >> EVERY_CASE_TAC >> gvs[perm_wh_def]
)
>- (
IF_CASES_TAC >> gvs[LENGTH_EQ_NUM_compute, perm_wh_def, MEM_MAP]
)
>- (
IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute] >>
gvs[DISJ_IMP_THM, FORALL_AND_THM] >> pop_assum $ assume_tac o GSYM >>
EVERY_CASE_TAC >> gvs[perm_wh_def]
)
>- (CONV_TAC $ DEPTH_CONV ETA_CONV >> simp[])
>- (
IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute] >>
gvs[DISJ_IMP_THM, FORALL_AND_THM] >> pop_assum $ assume_tac o GSYM >>
CASE_TAC >> gvs[perm_wh_def] >>
EVERY_CASE_TAC >> gvs[perm_wh_def]
)
>- (
IF_CASES_TAC >> gvs[perm_wh_def, LENGTH_EQ_NUM_compute] >>
gvs[DISJ_IMP_THM, FORALL_AND_THM] >> pop_assum $ assume_tac o GSYM >>
EVERY_CASE_TAC >> gvs[perm_wh_def, EL_MAP]
)
>- (
simp[MAP_MAP_o, combinTheory.o_DEF] >>
qmatch_goalsub_abbrev_tac `MAP f xs` >>
qpat_abbrev_tac `g = λa. eval_wh_to _ (_ a)` >>
`MAP g xs = MAP (λa. perm_wh v1 v2 (f a)) xs` by (
rw[MAP_EQ_f] >> unabbrev_all_tac >> gvs[] >>
first_x_assum $ irule o GSYM >> goal_assum drule) >>
unabbrev_all_tac >> gvs[] >>
simp[GSYM combinTheory.o_DEF, GSYM MAP_MAP_o] >>
TOP_CASE_TAC >> gvs[] >>
simp[get_atoms_perm_cancel, perm_wh_def] >>
TOP_CASE_TAC >> gvs[perm_wh_def] >>
rename1 `option_CASE x` >> Cases_on `x` >> gvs[perm_wh_def] >>
rename1 `sum_CASE x` >> Cases_on `x` >> gvs[perm_wh_def] >>
IF_CASES_TAC >> gvs[perm_wh_def]
)
>- (
simp[MAP_MAP_o, combinTheory.o_DEF] >>
Cases_on `LENGTH xs = 2` >> gvs[perm_wh_def] >>
gvs[LENGTH_EQ_NUM_compute, DISJ_IMP_THM, FORALL_AND_THM] >>
pop_assum $ assume_tac o GSYM >>
Cases_on `eval_wh_to (k - 1) h` >> gvs[perm_wh_def] >>
Cases_on `eval_wh_to (k - 1) h'` >> gvs[perm_wh_def]
)
QED
Theorem eval_wh_eqvt:
∀v1 v2 e.
perm_wh v1 v2 (eval_wh e) =
eval_wh (perm_exp v1 v2 e)
Proof
rw[eval_wh_def] >>
DEEP_INTRO_TAC some_intro >> rw[]
>- (
rename1 `eval_wh_to k` >>
qspecl_then [`v1`,`v2`,`k`,`e`] assume_tac eval_wh_to_eqvt >>
simp[] >>
DEEP_INTRO_TAC some_intro >> rw[] >> gvs[] >>
rename1 `_ = eval_wh_to k' _` >>
irule eval_wh_to_agree >> simp[] >>
once_rewrite_tac[GSYM eval_wh_to_eqvt] >>
pop_assum kall_tac >> pop_assum kall_tac >>
Cases_on `eval_wh_to k e` >> gvs[perm_wh_def]
)
>- (
DEEP_INTRO_TAC some_intro >> rw[] >> gvs[perm_wh_def] >>
pop_assum mp_tac >> simp[] >>
rename1 `eval_wh_to k` >>
qspecl_then [`v1`,`v2`,`k`,`e`] assume_tac (GSYM eval_wh_to_eqvt) >>
simp[perm_wh_def]
)
QED
Theorem follow_path_eval_wh_eqvt:
∀v1 v2 l f e.
(perm_v_prefix v1 v2 ## I) (follow_path eval_wh e l) =
follow_path eval_wh (perm_exp v1 v2 e) l
Proof
gen_tac >> gen_tac >>
Induct >> rw[follow_path_def] >>
simp[GSYM eval_wh_eqvt] >>
Cases_on `eval_wh e` >> gvs[perm_wh_def, perm_v_prefix_def] >>
gvs[oEL_THM] >>
IF_CASES_TAC >> gvs[EL_MAP, perm_v_prefix_def]
QED
Theorem v_lookup_eqvt:
∀v1 v2 path v. (perm_v_prefix v1 v2 ## I) (v_lookup path v) =
v_lookup path (perm_v v1 v2 v)
Proof
ntac 2 strip_tac >>
Induct >>
rw[v_lookup] >> TOP_CASE_TAC >> rw[perm_v_prefix_def,perm_v_thm] >>
simp[oEL_THM] >> rw[EL_MAP,perm_v_prefix_def]
QED
Theorem eval_eqvt:
perm_v v1 v2 (eval e) = eval (perm_exp v1 v2 e)
Proof
rw[eval_def, v_unfold_def] >>
rw[gen_v_eqvt] >>
AP_TERM_TAC >> irule EQ_EXT >> rw[] >>
simp[follow_path_eval_wh_eqvt]
QED
Theorem eval_wh_perm_closure:
eval_wh (perm_exp v1 v2 e) = wh_Closure x e'
⇔ eval_wh e = wh_Closure (perm1 v1 v2 x) (perm_exp v1 v2 e')
Proof
assume_tac (Q.SPECL [‘w1’,‘w2’,‘v1’,‘v2’] perm_wh_inj |> Q.GENL [‘w1’,‘w2’])
\\ pop_assum (fn th => simp [Once (GSYM th)])
\\ fs [eval_wh_eqvt,perm_wh_def]
QED
Theorem eval_wh_perm_cons:
eval_wh (perm_exp v1 v2 e) = wh_Constructor s e'
⇔ eval_wh e = wh_Constructor s (MAP (perm_exp v1 v2) e')
Proof
assume_tac (Q.SPECL [‘w1’,‘w2’,‘v1’,‘v2’] perm_wh_inj |> Q.GENL [‘w1’,‘w2’])
\\ pop_assum (fn th => simp [Once (GSYM th)])
\\ fs [eval_wh_eqvt,perm_wh_def]
QED
Theorem eval_wh_perm_atom:
eval_wh (perm_exp v1 v2 e) = wh_Atom a ⇔ eval_wh e = wh_Atom a
Proof
assume_tac (Q.SPECL [‘w1’,‘w2’,‘v1’,‘v2’] perm_wh_inj |> Q.GENL [‘w1’,‘w2’])
\\ pop_assum (fn th => simp [Once (GSYM th)])
\\ fs [eval_wh_eqvt,perm_wh_def]
QED
Theorem eval_wh_perm_diverge:
eval_wh (perm_exp v1 v2 e) = wh_Diverge ⇔ eval_wh e = wh_Diverge
Proof
assume_tac (Q.SPECL [‘w1’,‘w2’,‘v1’,‘v2’] perm_wh_inj |> Q.GENL [‘w1’,‘w2’])
\\ pop_assum (fn th => simp [Once (GSYM th)])
\\ fs [eval_wh_eqvt,perm_wh_def]
QED
Theorem eval_wh_perm_error:
eval_wh (perm_exp v1 v2 e) = wh_Error ⇔ eval_wh e = wh_Error
Proof
assume_tac (Q.SPECL [‘w1’,‘w2’,‘v1’,‘v2’] perm_wh_inj |> Q.GENL [‘w1’,‘w2’])
\\ pop_assum (fn th => simp [Once (GSYM th)])
\\ fs [eval_wh_eqvt,perm_wh_def]
QED
Theorem compatible_perm:
compatible b (λR. {(e1,e2) | ∃v1 v2 e3 e4. e1 = perm_exp v1 v2 e3 ∧
e2 = perm_exp v1 v2 e4 ∧ R(e3,e4)})
Proof
rw[compatible_def] >> simp[SUBSET_DEF] >>
Cases >> rw[FF_def,unfold_rel_def,ELIM_UNCURRY,eval_wh_perm_closure] >>
simp[closed_perm] >> gvs[eval_wh_perm_closure,eval_wh_perm_cons] >>
gvs[eval_wh_perm_atom,eval_wh_perm_diverge,eval_wh_perm_error]
>- (irule_at (Pos hd) (GSYM perm1_cancel) >>
irule_at (Pos hd) (GSYM perm_exp_cancel) >>
rw[] >>
irule_at (Pos hd) (GSYM perm_exp_cancel) >>
simp[subst1_eqvt] >>
PRED_ASSUM is_forall (irule_at (Pos last)) >>
simp[subst1_eqvt,closed_perm]) >>
qexists_tac ‘MAP (perm_exp v1 v2) e2s’ >>
gvs[eval_thm] >>
fs [MAP_MAP_o,combinTheory.o_DEF,perm_exp_cancel] >>
fs[EVERY2_MAP] >>
drule_at_then (Pos last) match_mp_tac EVERY2_mono >>
rw[] >>
goal_assum (first_assum o mp_then (Pos last) mp_tac) >>
irule_at (Pos hd) (GSYM perm_exp_cancel) >> fs []
QED
Theorem app_similarity_eqvt:
(e1 ≲ e2) b ⇒ (perm_exp x y e1 ≲ perm_exp x y e2) b
Proof
strip_tac >>
match_mp_tac companion_app_similarity >>
simp[companion_def] >>
irule_at Any compatible_perm >>
rw[monotone_def,SUBSET_DEF] >>
metis_tac[IN_DEF]
QED
Inductive exp_alpha:
[~Refl:]
(∀e. exp_alpha e e)
(*[~Sym:]
(∀e e'. exp_alpha e' e ⇒ exp_alpha e e') ∧*)
[~Trans:]
(∀e e' e''. exp_alpha e e' ∧ exp_alpha e' e'' ⇒ exp_alpha e e'')
[~Lam:]
(∀e x e'. exp_alpha e e' ⇒ exp_alpha (Lam x e) (Lam x e'))
[~Alpha:]
(∀e x y. x ≠ y ∧ y ∉ freevars e ⇒
exp_alpha (Lam x e) (Lam y (perm_exp x y e)))
[~Prim:]
(∀op es es'. LIST_REL exp_alpha es es' ⇒ exp_alpha (Prim op es) (Prim op es'))
[~App:]
(∀e1 e1' e2 e2'. exp_alpha e1 e1' ∧ exp_alpha e2 e2' ⇒
exp_alpha (App e1 e2) (App e1' e2'))
[~Letrec:]
(∀e1 e2 funs funs'.
exp_alpha e1 e2 ∧ MAP FST funs = MAP FST funs' ∧
LIST_REL exp_alpha (MAP SND funs) (MAP SND funs') ⇒
exp_alpha (Letrec funs e1) (Letrec funs' e2))
[~Letrec_Alpha:]
(∀funs1 funs2 x y e e1.
x ≠ y ∧
y ∉ freevars(Letrec (funs1 ++ (x,e)::funs2) e1)
⇒
exp_alpha (Letrec (funs1 ++ (x,e)::funs2) e1)
(Letrec
(MAP (perm1 x y ## perm_exp x y) funs1 ++
(y,perm_exp x y e)::MAP (perm1 x y ## perm_exp x y) funs2)
(perm_exp x y e1)))
[~Letrec_Vacuous1:]
(∀funs1 funs2 x y e e1.
x ≠ y ∧
MEM x (MAP FST funs2) ∧
y ∉ freevars(Letrec (funs1 ++ (x,e)::funs2) e1) ∧
¬MEM y (MAP FST funs1) ∧
¬MEM y (MAP FST funs2)
⇒
exp_alpha (Letrec (funs1 ++ (x,e)::funs2) e1)
(Letrec (funs1 ++ (y,perm_exp x y e)::funs2) e1))
[~Letrec_Vacuous2:]
(∀funs1 funs2 x y e e1.
x ≠ y ∧
x ∉ freevars(Letrec (funs1 ++ funs2) e1) ∧
¬MEM x (MAP FST funs1) ∧
¬MEM x (MAP FST funs2) ∧
MEM y (MAP FST funs2) ∧
y ∉ freevars e
⇒
exp_alpha (Letrec (funs1 ++ (x,e)::funs2) e1)
(Letrec (funs1 ++ (y,perm_exp x y e)::funs2) e1))
End
Triviality MAP_PAIR_MAP':
MAP (λ(x,y). h x) (MAP (f ## g) l) = MAP h (MAP f (MAP FST l)) ∧
MAP (λ(x,y). h y) (MAP (f ## g) l) = MAP h (MAP g (MAP SND l))
Proof
rw[MAP_MAP_o,combinTheory.o_DEF,MAP_EQ_f,ELIM_UNCURRY]
QED
Theorem exp_alpha_refl:
x = y ⇒ exp_alpha x y
Proof
metis_tac[exp_alpha_Refl]
QED
Theorem perm1_right:
perm1 x y z = h ⇔ z = perm1 x y h
Proof
rw[perm1_def] >> metis_tac[]
QED
Theorem MAP_MAP_perm_lemma:
∀f x y l.
MAP (λz. MAP (perm1 x y) (f z)) l =
MAP (MAP (perm1 x y)) (MAP f l)
Proof
Induct_on ‘l’ >> rw[]
QED
Theorem perm1_simps:
perm1 x y x = y ∧
perm1 x x y = y ∧
perm1 y x x = y
Proof
rw[perm1_def]
QED
Theorem exp_alpha_subst_closed':
∀s e s'.
(∀e. e ∈ FRANGE s ⇒ closed e) ∧
(∀e. e ∈ FRANGE s' ⇒ closed e) ∧
fmap_rel exp_alpha s s'
⇒
exp_alpha (subst s e) (subst s' e)
Proof
ho_match_mp_tac subst_ind >>
rw[subst_def,exp_alpha_Refl]
>- (TOP_CASE_TAC >>
imp_res_tac fmap_rel_FLOOKUP_imp >>
simp[exp_alpha_Refl])
>- (match_mp_tac exp_alpha_Prim >>
simp[MAP_MAP_o,combinTheory.o_DEF,EVERY2_MAP] >>
match_mp_tac EVERY2_refl >>
rw[])
>- (match_mp_tac exp_alpha_App >> metis_tac[])
>- (match_mp_tac exp_alpha_Lam >> simp[] >>
first_x_assum(match_mp_tac o MP_CANON) >>
simp[] >>
conj_tac >- metis_tac[IN_FRANGE_DOMSUB_suff] >>
conj_tac >- metis_tac[IN_FRANGE_DOMSUB_suff] >>
gvs[fmap_rel_def,DOMSUB_FAPPLY_THM])
>- (match_mp_tac exp_alpha_Letrec >>
simp[MAP_EQ_f] >>
rw[MAP_MAP_o,combinTheory.o_DEF,ELIM_UNCURRY]
>- (first_x_assum (match_mp_tac o MP_CANON) >>
conj_tac >- metis_tac[FDIFF_def,IN_FRANGE_DRESTRICT_suff] >>
conj_tac >- metis_tac[FDIFF_def,IN_FRANGE_DRESTRICT_suff] >>
gvs[fmap_rel_def,FDIFF_def,FDOM_DRESTRICT] >>
simp[DRESTRICT_DEF]) >>
simp[EVERY2_MAP] >>
match_mp_tac EVERY2_refl >>
Cases >> rw[] >>
first_x_assum (drule_then match_mp_tac) >>
conj_tac >- metis_tac[FDIFF_def,IN_FRANGE_DRESTRICT_suff] >>
conj_tac >- metis_tac[FDIFF_def,IN_FRANGE_DRESTRICT_suff] >>
gvs[fmap_rel_def,FDIFF_def,FDOM_DRESTRICT] >>
simp[DRESTRICT_DEF])
QED
Theorem exp_alpha_subst_closed'_strong:
∀s e s'.
(∀e. e ∈ FRANGE s ⇒ closed e) ∧
(∀e. e ∈ FRANGE s' ⇒ closed e) ∧
fmap_rel exp_alpha (DRESTRICT s (freevars e)) (DRESTRICT s' (freevars e))
⇒
exp_alpha (subst s e) (subst s' e)
Proof
rw[] >>
PURE_ONCE_REWRITE_TAC[subst_FDIFF] >>
match_mp_tac exp_alpha_subst_closed' >>
simp[] >>
gvs[IN_FRANGE_FLOOKUP,FLOOKUP_DRESTRICT,PULL_EXISTS] >> metis_tac[]
QED
Theorem exp_alpha_subst1_closed':
∀x e' e e''.
closed e' ∧ closed e'' ∧ exp_alpha e' e''
⇒
exp_alpha (subst1 x e' e) (subst1 x e'' e)
Proof
rpt strip_tac >>
match_mp_tac exp_alpha_subst_closed' >>
rw[fmap_rel_def]
QED
Triviality APPEND_EQ_IMP:
a = b ∧ c = d ⇒ a ++ c = b ++ d
Proof
rw[]
QED
Theorem MEM_PERM_IMP:
MEM x l ⇒
MEM y (MAP (perm1 x y) l)
Proof
Induct_on ‘l’ >> rw[perm1_def]
QED
Theorem MEM_PERM_EQ:
(MEM x (MAP (perm1 x y) l) ⇔ MEM y l) ∧
(MEM x (MAP (perm1 y x) l) ⇔ MEM y l)
Proof
conj_tac >> Induct_on ‘l’ >> rw[perm1_def,EQ_IMP_THM] >> simp[]
QED
Theorem MEM_PERM_EQ_GEN:
(MEM x (MAP (perm1 y z) l) ⇔ MEM (perm1 y z x) l)
Proof
Induct_on ‘l’ >> rw[perm1_def,EQ_IMP_THM] >> simp[]
QED
Theorem exp_alpha_freevars_l:
∀e e'.
exp_alpha e e' ⇒ freevars_l e = freevars_l e'
Proof
Induct_on ‘exp_alpha’ >>
rw[] >> gvs[freevars_equiv] >>
simp[GSYM perm_exp_eqvt,FILTER_MAP,combinTheory.o_DEF]
>- (rename1 ‘FILTER _ l’ >>
Induct_on ‘l’ >>
rw[] >> gvs[] >>
gvs[perm1_def] >> PURE_FULL_CASE_TAC >> gvs[])
>- (AP_TERM_TAC >>
pop_assum mp_tac >>
MAP_EVERY qid_spec_tac [‘es'’,‘es’] >>
ho_match_mp_tac LIST_REL_ind >>
rw[])
>- (ntac 3 AP_TERM_TAC >>
gvs[EVERY2_MAP] >>
pop_assum mp_tac >>
MAP_EVERY qid_spec_tac [‘funs'’,‘funs’] >>
rpt(pop_assum kall_tac) >>
ho_match_mp_tac LIST_REL_ind >>
rw[] >> rpt(pairarg_tac >> gvs[]))
>- (qmatch_goalsub_abbrev_tac ‘FILTER _ a1 = FILTER _ a2’ >>
‘a2 = MAP (perm1 x y) a1’
by(rw[Abbr ‘a2’,Abbr‘a1’] >>
rpt(match_mp_tac APPEND_EQ_IMP >> conj_tac) >>
rw[MAP_FLAT,MAP_MAP_o,combinTheory.o_DEF,PAIR_MAP,ELIM_UNCURRY,
GSYM perm_exp_eqvt]) >>
pop_assum SUBST_ALL_TAC >>
‘¬MEM y a1’
by(unabbrev_all_tac >>
rw[MEM_FLAT,MEM_MAP] >>
gvs[MEM_MAP,ELIM_UNCURRY] >>
metis_tac[MEM_MAP]) >>
pop_assum mp_tac >>
qpat_x_assum ‘x ≠ y’ mp_tac >>
rpt(pop_assum kall_tac) >>
Induct_on ‘a1’ >- rw[] >>
rw[] >- rw[perm1_def] >>
rw[perm1_def] >>
gvs[] >>
rw[DISJ_EQ_IMP] >>
gvs[perm1_def,MEM_MAP,MEM_FILTER,PAIR_MAP] >>
metis_tac[perm1_def,FST,SND,PAIR])
>- (gvs[FILTER_APPEND] >>
rpt(match_mp_tac APPEND_EQ_IMP >> conj_tac) >>
rw[FILTER_EQ,EQ_IMP_THM]
>- (rename1 ‘FILTER _ l’ >>
Induct_on ‘l’ >>
rw[] >>
gvs[MAP_PAIR_MAP,MEM_PERM_EQ_GEN] >>
rw[perm1_def] >> gvs[perm1_def,AllCaseEqs()])
>- (simp[MAP_PAIR_MAP,MEM_PERM_EQ_GEN] >>
simp[MAP_MAP_o,combinTheory.o_DEF,ELIM_UNCURRY,GSYM perm_exp_eqvt] >>
qspec_then ‘λx. freevars_l(SND x)’
(simp o single o SIMP_RULE std_ss []) MAP_MAP_perm_lemma >>
simp[GSYM MAP_FLAT] >>
simp[FILTER_MAP,combinTheory.o_DEF,perm1_right,perm1_simps] >>
dep_rewrite.DEP_ONCE_REWRITE_TAC[MAP_ID_ON] >>
rw[MEM_FILTER,MEM_FLAT,MEM_MAP] >>
rw[perm1_def] >>
gvs[MEM_MAP,PULL_EXISTS] >>
metis_tac[FST,SND,PAIR])
>- (simp[MAP_PAIR_MAP,MEM_PERM_EQ_GEN,FILTER_MAP,combinTheory.o_DEF,
perm1_right,perm1_simps] >>
dep_rewrite.DEP_ONCE_REWRITE_TAC[MAP_ID_ON] >>