build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
}



apply plugin: 'java'
apply plugin: 'maven-publish'

version = "1.0.0"

if(project.hasProperty("craftTweakerVersion")){
version = ext.craftTweakerVersion
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8


//Shuts up javadoc failures
if (JavaVersion.current().isJava8Compatible()) {

    allprojects {

        tasks.withType(Javadoc) {

            options.addStringOption('Xdoclint:none', '-quiet')
        }
    }
}
repositories {
    mavenCentral()
    maven {
        name = "sonatype"
        url = "https://oss.sonatype.org/content/repositories/snapshots/"
    }
}

dependencies {
    compile group: 'org.ow2.asm', name: 'asm-debug-all', version: '5.2'
    compile group: 'com.google.code.gson', name: 'gson', version: '2.7'


//    compile 'org.ow2.asm:asm-debug-all:6.0_BETA'

    testCompile(
            'org.junit.jupiter:junit-jupiter-api:5.0.1'
    )

    testRuntime(
            'org.junit.jupiter:junit-jupiter-engine:5.0.1',
            'org.junit.vintage:junit-vintage-engine:4.12.1',
            'org.junit.platform:junit-platform-launcher:1.0.1',
            'org.junit.platform:junit-platform-runner:1.0.1'
    )
    //compile files("${System.properties['java.home']}/../lib/tools.jar")
    //compile files("libs/tools.jar")
}

task sourcesJar(type: Jar, dependsOn: classes) {

    description = 'Creates a JAR containing the source code.'
    from sourceSets.main.allSource
    classifier = 'sources'
}
task javadocJar(type: Jar, dependsOn: javadoc) {

    description = 'Creates a JAR containing the JavaDocs.'
    from javadoc.destinationDir
    classifier = 'javadoc'
}
task deobfJar(type: Jar) {

    description = 'Creates a JAR containing the non-obfuscated compiled code.'
    from sourceSets.main.output
    classifier = "deobf"
}

//Adds the artifact types added by this script to the actual artifacts list.
artifacts {

    archives sourcesJar
    archives javadocJar
    archives deobfJar
}

test {
    useJUnitPlatform()
    testLogging{
        events "PASSED", "FAILED", "SKIPPED"
    }
}

publishing {

    publications {

        mavenJava(MavenPublication) {

            groupId project.group
            artifactId project.archivesBaseName
            version project.version
            from components.java

            // Adds the various artifacts
            artifact sourcesJar {

                classifier 'sources'
            }
            artifact javadocJar {

                classifier 'javadoc'
            }
            artifact deobfJar {

                classifier 'deobf'
            }
        }
    }

    repositories {

        maven {

            url "file://" + System.getenv("local_maven")
        }
    }
}