forked from Ixiko/AHK-libs-and-classes-collection
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathClass_CStruct.ahk
1351 lines (1256 loc) · 42.4 KB
/
Class_CStruct.ahk
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/******************************************************************************
; ahk forum : http://www.autohotkey.com/community/viewtopic.php?f=2&t=84054
; StructClass Make Helper : http://www.autohotkey.net/~chaidy/Ahk%20Source/CStruct/CStruct_ScriptMaker.rar
< CStruct_Base class - AHK_L (32bit & 64bit) >
ver 5.8 - last update 2012.05.07 : add 'm_struct.tCls" - refer to m_template[this.__class]
<Properties>
struct.member : set or get struct member's value.
(ex. var := rect.right , rect.top := 1 , struct.rect := new CRect(0,0,100,100) )
struct.member["count"] : get struct member array count. normaly 1 return.
struct.member["type"] : get struct member type.
struct.member["size"] : get struct member type size. its same "sizeof(type)"
struct.member["Ptr"] or [""] : get struct member address. (ex. Numget(rect.top["Ptr"],0,"Uint") )
struct.Ptr or struct[""] : get struct starting address. (ex. GetWindowRect(hwnd, rect.ptr) )
struct.size or struct["size"] : get struct size. (ex. cbSize := struct.size )
struct.stringArrayMember := "hello." : set string to struct character array member. ( possable array type: CHAR,TCHAR,WCHAR )
struct.LPSTRtypeMember["bufferSize"] : set or get capacity for include string buffer. (its need for receive string data from win api)
struct.LPSTRtypeMember := stringVar : set include string from stringVar. (auto capacity allocate for string buffer.)
struct.LPSTRtypeMember := "String" : set include string from "String". but exclude number data in thease "42344", "330", ...
struct.LPSTRtypeMember := &var : not include string. only save variable address value.
<Method>
- AddStructVar(varName, varType, arrayCount, unionState)
ex1. use window api variable type (byte, int, char, LPSTR, HICON, ...)
AddStructVar("width", "int") AddStructVar("winName", "wchar", 32)
ex2. use defined CStruct class type (CPoint, CRect, ...)
AddStructVar("pt", "CPoint") AddStructVar("ptArray", "CPoint", 10)
ex3. define union member
AddStructVar("a" , "Byte" , "union_start")
AddStructVar("b" , "Word")
AddStructVar("c" , "DWord" , "union_end")
ex4. define bitfield type member
AddStructVar("b" , "Word" , "bit:4")
<Caution>
- It's best not to use arrayCountVar if possable. i strongly recommend use a numeric constant instead of variable.
good : AddStructVar("a" , "Word" , 10)
not good : count := 10 , AddStructVar("a" , "Word" , count)
- why not good : struct class can't make from template if AddStructVar(.. ) has arrayCountVar variable.
perfomance bad as a result of not use numeric constant.
- but why need : it's use last AddStructVar line if variable size of the required buffer for end of the struct.
it's example - structure : http://msdn.microsoft.com/en-us/library/dd162755(v=VS.85).aspx
- CStruct : http://www.autohotkey.com/community/viewtopic.php?f=2&t=84054#p534383
- SetStructCapacity() : allocate memory for added struct var.
- CopyFrom(Ptr or CStructObj) : copy from 'Same struct' address or same CStruct object.
- ToString() : get struct member normaly infomation.
- TreeView() : Show Structure Object on TreeView.(CStruct_Base.TreeView() - show class template)
- Clone() : get clone object.
- CheckName(name) : check struct member name validation. use in inherit class.
- GetData(name, n) : get struct member data. use in inherit class. (n: arrayNumber, "ptr", "type", "count")
- SizeOf(varType) : get varType size. 0 return if undefined type.
- Encoding(name, type, mode) : get default encoding. possable override in inherit class. (mode : get or set)
<method overridding model>
__Get(name, arryNum=0) ; struct has array member and access to array member in __Get() method .
{ ; in inherit class then must insert second parameter 'arryNum=0'
}
__Set(name, ByRef param1, param2*) ; must need 'ByRef' param1
{
}
<structure class making sample>
class CSample extends CStruct_Base ; must write "extends CStruct_Base"
{
__New() ; or __New(param*)
{
this.AddStructVar("a", "int") ; <- int a;
this.AddStructVar("b", "int", 3) ; <- int b[3]
this.AddStructVar("c", "int", "bit:3") ; <- int c :3;
this.AddStructVar("d", "dword", "union_start") ; <- union { dword d;
this.AddStructVar("e", "CRect") ; <- RECT e;
this.AddStructVar("f", "char", 2, "union_end") ; <- char f[2]; }
this.SetStructCapacity() ; allocate struct memory
}
}
*/
;******************************************************************************
;0 : not exit after error msg.
;1 : exit after error msg
CStruct_Base__Flag_ExitAppAfterErrorMsg := 1
class CStruct_Base
{
static m_template := {}
__New()
{
if (this.__class="CStruct_Base")
this.__ErrorMsg("error_basenew", this.__class)
}
__Initialize()
{
tCls := this.m_template[this.__class]
this.m_struct := (!tCls.sizeVariable and tCls.dummy)? tCls.dummy : {"addr":0, "data":"", child:{}}
if tCls.dummy
this.m_useDummy := 1 , tCls.dummy := ""
if this.m_useDummy
return
if !tCls.sizeVariable and this.__MakeThisClassFromTemplate()
this.m_useTemplate := 1
if !this.m_useTemplate
{
this.m_union := {"state":0, "state_old":0, "offset":0, "size":0}
this.m_bitField := {"bitCount":0, "size_old":0, "offset_old":0}
}
if !tCls or (tCls.sizeVariable and tCls.created)
this.m_template[this.__class] := {"varList":{}, "varOrder":{}}
}
__Delete()
{
tCls := this.m_struct.tCls
if !tCls.sizeVariable and !tCls.dummy
tCls.dummy := this.m_struct
}
__Get(name, number=0)
{
if ("m_"<>SubStr(name, 1, 2)) and (name<>"__class")
return this.GetData(name, number, 1)
}
GetData(name, number=0, callFrom__Get=0)
{
mObj := this.m_struct
tCls := mObj.tCls
if (name="ptr") or (name="")
return mObj.addr
else if (name="__base")
return "CStruct_Base"
else if (name="size")
return mObj.addr? tCls.size : this.__GetNextVarOffset()
if vObj := tCls.varList[name]
{
name_exist = 1
if (number="ptr") or (number="")
return mObj.addr + vObj.o
if (number="count")
return vObj.c
if (number="type")
return vObj.org
if (number="size")
return vObj.s
if (number="bufferSize")
return ObjGetCapacity(mObj.string, name)
if (number=0)
{
orgType := vObj.org
encoding := this.Encoding(name, vObj.org, "get")
if (vObj.c = 1)
{
if callFrom__Get and InStr(orgType, "STR")
{
if encoding
return StrGet(NumGet(mObj.addr, vObj.o, vObj.t), encoding)
else
return StrGet(NumGet(mObj.addr, vObj.o, vObj.t))
}
number := 1
}
else
{
if orgType in CHAR,TCHAR,WCHAR
if encoding
return StrGet(mObj.addr+vObj.o, vObj.c, encoding)
else
return StrGet(mObj.addr+vObj.o, vObj.c)
return Object("error", 1)
}
}
if (vObj.t="CStruct_Base")
return mObj.child[name][number]
else
{
if (number<=vObj.c)
{
if !mObj.addr
return this.__ErrorMsg("error_addr", this.__Class "." A_ThisFunc)
if !vObj.bc
return NumGet(mObj.addr, vObj.o + vObj.s * (number-1), vObj.t)
;bitfield get
if (number=1)
{
field := NumGet(mObj.addr, vObj.o, vObj.t)
mask = 0x
loop % vObj.s
mask .= "ff"
mask >>= vObj.s*8 - vObj.bc , mask <<= vObj.bo , field &= mask
return field >> vObj.bo
}
}
}
}
if !name_exist
return this.__ErrorMsg("error_notexistname", this.__Class "." A_thisFunc, name)
}
__Set(name, ByRef first, second*)
{
if ("m_"<>SubStr(name, 1, 2))
{
mObj := this.m_struct
tCls := mObj.tCls
if vObj := tCls.varList[name]
{
name_exist = 1
if !mObj.addr
return this.__ErrorMsg("error_addr", this.__Class "." A_ThisFunc)
if !ObjHasKey(second, 1)
{
if (vObj.t="CStruct_Base")
{
if (mObj.child[name][1].__class=first.__class)
{
mObj.child[name][1].CopyFrom(first)
return first
}
}
else
{
orgType := vObj.org
if first is not Integer
strValue := 1
if (vObj.c>1) and InStr(",CHAR,TCHAR,WCHAR,", "," orgType ",")
{
if encoding := this.Encoding(name, vObj.org, "set")
{
codeSize := this.__GetEncodingSize(encoding)
size := StrPut(first, encoding) * codeSize
if (size <= vObj.c * vObj.s)
result := StrPut(first, mObj.addr+vObj.o, vObj.c, encoding)
}
else
result := StrPut(first, mObj.addr+vObj.o, vObj.c-1)
if result
return first
}
else if (vObj.c=1) and InStr(orgType, "STR") and (strValue or IsByRef(first))
{
if addr := this.__StringInclude(name, orgType, first)
return first , NumPut(addr, mObj.addr, vObj.o, vObj.t)
}
else if !vObj.bc
{
NumPut(first+0, mObj.addr, vObj.o, vObj.t)
return first
}
else
{
;bitfield set
field := NumGet(mObj.addr, vObj.o, vObj.t)
maskAll = 0x
loop % vObj.s
maskAll .= "ff"
mask1 := maskAll
mask2 := mask1 >>= vObj.s*8 - vObj.bc , mask1 <<= vObj.bo , mask1 ^= maskAll
field &= mask1 , mask2 &= first+0 , mask2 <<= vObj.bo , field |= mask2
NumPut(field, mObj.addr, vObj.o, vObj.t)
return first
}
return
}
}
else ;if ObjHasKey(second, 1)
{
if (first="bufferSize") and (vObj.c=1) and InStr(vObj.org, "STR") and (second[1]>=0)
return second[1] , this.__SetSizeForIncludeString(name, second[1])
if (first<1) or (first>vObj.c)
return
if (vObj.t="CStruct_Base")
{
obj := mObj.child[name][first]
if (obj.__class=second[1].__class)
{
obj.CopyFrom(second[1])
return second[1]
}
}
else
{
NumPut(second[1]+0, mObj.addr, vObj.o + vObj.s * (first-1), vObj.t)
return second[1]
}
}
}
if !name_exist
return this.__ErrorMsg("error_notexistname", this.__Class "." A_thisFunc, name)
}
}
;------------------------------------------------------------
AddStructVar(ByRef name, orgType, ByRef arrayCount=1, unionState="")
{
if !this.m_struct
this.__Initialize()
if this.m_useDummy or this.m_useTemplate
return
tCls := this.m_struct.tCls := this.m_template[this.__class]
if IsByRef(name) or IsByRef(arrayCount)
{
tCls.sizeVariable := 1
if (arrayCount=0)
return
}
count := arrayCount
orgCount := count , orgUState := unionState
if count is not Integer
{
StringReplace, bitCount, count, % " ",, All
bitCount := RegExReplace(bitCount, "i)bit:")
}
if bitCount is Integer
count := 0
else
bitCount := 0
if count is not Integer
if (unionState="")
unionState := count , count := 1
uObj := this.m_union
uObj.state_old := uObj.state
if (unionState="union_start")
uObj.state := 1 , uObj.state_old := 0
else if (unionState="union_end")
uObj.state := 2
else if (unionState<>"")
{
msg = `"%unionState%`" : sentence error.
return this.__ErrorMsg("error_addvar", A_ThisFunc, name, orgType, orgCount, orgUState, msg)
}
if (uObj.state=0)
uObj.offset := uObj.size := 0
if (uObj.state=3)
uObj.state := 0
if count is not integer
countInvalid := 1
if (count<0)
countInvalid := 1
if !name or !orgType or countInvalid or (!goodName:=this.CheckName(name, 1))
or (badType:=RegExMatch(RegExReplace(orgType, "\."), "\W")) or (badType:=RegExMatch(orgType, "\.\."))
or (badBit := !count and (bitCount<=0))
{
msg := (!orgType or badType)? "invalid varType." : !name? "Invalid varName." : goodName=0? """" name """ can't use this varName."
: goodName=""? """" name """ : already exist this varName." : countInvalid? """" count """ invalid array count."
: badBit? """bit:" bitCount """ invalid bit field count": ""
return this.__ErrorMsg("error_addvar", A_ThisFunc, name, orgType, orgCount, orgUState, msg)
}
count := count<1 ? 1 : count
size := 0
if !InStr(orgType, ".") and (size := this.sizeof( type := this.wintype(orgType) ))
{
allSize := size * count
if bitCount and (size*8<bitCount)
return this.__ErrorMsg("error_addvar", A_ThisFunc, name, orgType, orgCount, orgUState
, """bit:" bitCount """ type of bit field too small for number of bits")
}
else
{
cls := this.__MakeClass(orgType)
if (badType:=(cls.__base<>"CStruct_Base")) or bitCount
{
msg := badType? """" orgType """ : invalid this varType." : bitCount? """bit:" bitCount
. """ bit field can't use with a struct class type" : ""
return this.__ErrorMsg("error_addvar", A_ThisFunc, name, orgType, orgCount, orgUState, msg)
}
type := "CStruct_Base"
size := cls.size
allSize := size * count
child := this.m_struct.child
if !IsObject(child[name])
child[name] := {}
child[name].Insert(cls)
loop % count-1
child[name].Insert(this.__MakeClass(orgType))
}
;Get varList obj from class template object
vList := tCls.varList
if !tCls.size
tCls.size := 0
if !IsObject(vList[name])
vList[name] := {}
sizeBackup := tCls.size
if (uObj.state=1)and(uObj.state_old=0) or (uObj.state=0)and(uObj.state_old=3)
unionStateChange := 1
if ((uObj.state=2)and(uObj.state_old=1)) or ((uObj.state=1)and(uObj.state_old=1))
{
if (uObj.state=2)
uObj.state := 3
vList[name].o := uObj.offset
uObj.size := uObj.size<allSize? allSize:uObj.size
tCls.size := uObj.offset + uObj.size
union := 1
}
else
{
vList[name].o := this.__GetNextVarOffset((type="CStruct_Base")? pack:=this.m_template[orgType].pack : size)
tCls.size := vList[name].o + uObj.size := allSize
if (uObj.state=1)
uObj.offset := vList[name].o
}
if bitCount
{
tCls.size := sizeBackup
bitObj := this.__GetNextVarBitObj(bitCount, size, unionStateChange, union)
vList[name].o := bitObj.offset
vList[name].bo := bitObj.bitOffset
vList[name].bc := bitCount
tCls.size += bitObj.addSize
}
vList[name].t := type
vList[name].s := size
vList[name].c := count
vList[name].org := orgType
pack := (type="CStruct_Base")? pack : size
if !tCls.pack
tCls.pack := pack
else
tCls.pack := (tCls.pack>pack)? tCls.pack : pack
tCls.varOrder.Insert(name)
if (type="CStruct_Base")
{
if !tCls.child
tCls.child := {}
tCls.child.Insert(name, orgType)
}
this.m_bitField.offset_old := vList[name].o
this.m_bitField.size_old := bitCount? size : 0
}
;------------------------------------------------------------
SetStructCapacity(ParentPutAddress=0)
{
mObj := this.m_struct
tCls := mObj.tCls
if this.m_useDummy
{
DllCall("RtlZeroMemory", "Ptr",mObj.addr, "UInt",tCls.size)
return
}
if !ParentPutAddress and !this.m_useTemplate
{
tCls.size := this.__GetNextVarOffset()
if this.m_union
this.m_union := ""
if this.m_bitField
this.m_bitField := ""
tCls.created := 1
}
if (mObj.addr<>0)
ObjSetCapacity(mObj, "data", mObj.addr := 0)
if ParentPutAddress
mObj.addr := ParentPutAddress
else
{
ObjSetCapacity(mObj, "data", tCls.size)
mObj.addr := ObjGetAddress(mObj, "data")
DllCall("RtlZeroMemory", "Ptr",mObj.addr, "UInt",tCls.size)
}
;child struct starting address put.
;tCls:templateObj, vObj:varObj , mObj:memberObj, cArray:sameNameArray
vList := tCls.varList
for cName, cArray in mObj.child
{
vObj := vList[cName]
for number, obj in cArray
obj.SetStructCapacity(mObj.addr + (vObj.o + vObj.s * (number-1)))
}
}
Clone()
{
cls := this.__MakeClass(this.__class)
cls.CopyFrom(this)
return cls
}
CopyFrom(from)
{
fObj := from.m_struct
mObj := this.m_struct
tCls := mObj.tCls
if !mObj.addr
return this.__ErrorMsg("error_addr", this.__Class "." A_ThisFunc)
if !IsObject(from)
{
DllCall("RtlMoveMemory", "Ptr",mObj.addr, "Ptr",from , "UInt",tCls.size)
return
}
if (this.__class<>from.__class)
return
DllCall("RtlMoveMemory", "Ptr",mObj.addr, "Ptr",fObj.addr , "UInt",tCls.size<fObj.tCls.size? tCls.size : fObj.tCls.size)
for name in fObj.string
{
vObj := tCls.varList[name]
mObj.string[name] := ""
size := ObjSetCapacity(mObj.string, name, ObjGetCapacity(fObj.string, name))
DllCall("RtlMoveMemory", "Ptr", addr := ObjGetAddress(mObj.string, name), "Ptr", ObjGetAddress(fObj.string, name), "UInt", size)
NumPut(addr, mObj.addr, vObj.o, vObj.t)
}
}
; 1 return : ok
; 0 return : invalid var name
;"" return : exist var name
CheckName(name, check_duplication=0)
{
if name in count,type,ptr,size,__base,__class
return 0
if ("m_"=SubStr(name, 1, 2))
return 0
tCls := this.m_struct.tCls
if ObjHasKey(tCls.varList, name)
return (check_duplication and !tCls.created)? "" : 1
else
return check_duplication? 1 : 0
}
;------------------------------------------------------------
;kind of string type : CHAR,TCHAR,WCHAR , STR,LPSTR,TSTR,LPTSTR,LPCTSTR,WSTR,LPWSTR,LPCWSTR
;mode = get or set
Encoding(name="", type="", mode="")
{
static uni := "UTF-16"
static ansi := "CP0"
if A_IsUnicode
{
if type in CHAR,STR,LPSTR,LPCSTR
return ansi
}
else
{
IfInString, type, W
return uni
}
return ""
}
;STR type data copy and encoding then its address return
;return : address=sucess , 0=fail
__StringInclude(name, type, string)
{
if !this.m_struct.string
this.m_struct.string := {}
sObj := this.m_struct.string
encoding := this.Encoding(name, type, "set")
codeSize := this.__GetEncodingSize(encoding)
length := encoding? StrPut(string, encoding) : StrPut(string)
size := this.__SetSizeForIncludeString(name, length * codeSize + 2)
DllCall("RtlZeroMemory" , "Ptr",addr:=ObjGetAddress(sObj, name) , "UInt",size)
if encoding
result := StrPut(string, addr, length, encoding)
else
result := StrPut(string, addr)
if result
return addr
return 0
}
__SetSizeForIncludeString(name, size)
{
if !hasObj := this.m_struct.string
this.m_struct.string := {}
vObj := this.m_struct.tCls.varList[name]
sObj := this.m_struct.string
if !hasObj or !ObjHasKey(sObj, name)
{
sObj[name] := ""
result := ObjSetCapacity(sObj, name, size)
}
else
{
result := size_old := ObjGetCapacity(sObj, name)
if (size>size_old)
{
VarSetCapacity(str_old, size_old)
DllCall("RtlMoveMemory", "Ptr", &str_old, "Ptr", ObjGetAddress(sObj, name), "UInt", size_old)
result := ObjSetCapacity(sObj, name, size)
DllCall("RtlMoveMemory", "Ptr", ObjGetAddress(sObj, name), "Ptr", &str_old, "UInt", size_old)
}
}
return result
}
__GetEncodingSize(encoding)
{
if !encoding
return A_IsUnicode? 2 : 1
if encoding=CP0
return 1
if encoding in UTF-16,CP1200
return 2
if encoding in UTF-8
return 4 ;UTF-8 maximum size = 4
return A_IsUnicode? 2 : 1
}
;------------------------------------------------------------
;structure memory packing
__GetNextVarOffset(nextVarSize=0)
{
tCls := this.m_template[this.__class]
if !nextVarSize
nextVarSize := tCls.pack? tCls.pack : 1
;nextVarSize : 1,2,4,8,...
if (tCls.size=0) or (nextVarSize<=1)
return tCls.size
shareSize := tCls.size//8 * 8
restSize := tCls.size - shareSize
if !restSize
return tCls.size
if (nextVarSize>=8)
return shareSize+8
if (restSize<=nextVarSize)
return shareSize+nextVarSize
else
{
s := restSize//nextVarSize * nextVarSize
r := restSize - s
return r? shareSize+s+nextVarSize : shareSize+s
}
}
;bitfield make
__GetNextVarBitObj(bitCount, size, stateChange, union)
{
tCls := this.m_template[this.__class]
mObj := this.m_struct
bObj := this.m_bitField
rObj := {}
nextOffset := this.__GetNextVarOffset(size)
if (bObj.size_old=0) or (bObj.size_old<>size) or stateChange
{
rObj.offset := nextOffset , rObj.bitOffset := 0 , rObj.addSize := size
bObj.bitCount := bitCount
}
else if union
rObj.Offset := bObj.offset_old , rObj.bitOffset := 0 , rObj.addSize := 0
else
{
bitOver := (bObj.bitCount+bitCount) // (size*8) and Mod(bObj.bitCount+bitCount, size*8)
rObj.offset := bitOver? nextOffset : bObj.offset_old
rObj.bitOffset := bitOver? 0 : bObj.bitCount
rObj.addSize := bitOver? size : 0
bObj.bitCount := bitOver? bitCount : bObj.bitCount+bitCount
}
return rObj
}
__MakeClass(name)
{
loop Parse, name, .
cls := (A_Index = 1 ? %A_LoopField% : cls[A_LoopField])
return new cls
}
; class template use
__MakeThisClassFromTemplate()
{
if !IsObject(this.m_template[clsName := this.__class])
return 0
tCls := this.m_struct.tCls := this.m_template[clsName]
child := this.m_struct.child
for vName, clsName in tCls.child
{
if !child[vName]
child[vName] := {}
loop % tCls.varList[vName].c
child[vName].Insert(this.__MakeClass(clsName))
}
return 1
}
__ErrorMsg(error_id, from, v*)
{
if (error_id="error_addr")
MsgBox,, Error, % "event from: " from "()`n`nnot allocated struct memory.`n`n"
. """this.SetStructCapacity()"" insert to """ this.__class ".__New()"""
if (error_id="error_addvar")
MsgBox,, Error, % this.__Class "." from "(varName`, varType`, arrayCount, unionState)`n`nvarName = """ v[1]
. """`nvarType = """ v[2] """" . "`narrayCount = " v[3] . "`nunionState = " v[4]
. ((v.MaxIndex()=5)and(v[5])? "`n`n" v[5] : "")
if (error_id="error_notexistname")
MsgBox,, Error, % "from: " from "()`n`n""" v[1] """ is not a member this Struct."
if (error_id="error_basenew")
MsgBox,, Error, % "from: " from "()`n`ndon't make ""CStruct_Base"" instance.`n`n"
. "this class only use base class."
global CStruct_Base__Flag_ExitAppAfterErrorMsg
if CStruct_Base__Flag_ExitAppAfterErrorMsg
ExitApp
}
sizeof(type_name)
{
if (type_name="")
return 0
; http://l.autohotkey.net/docs/commands/DllCall.htm#types
static Ptr:=A_PtrSize,UPtr:=A_PtrSize,Int64:=8,UInt64:=8,Int:=4,UInt:=4,Short:=2,UShort:=2,Char:=1,UChar:=1,Float:=4,Double:=8
type_match := (%type_name%)
if !type_match
type_name := this.wintype(type_name)
if !type_name
return 0
return (%type_name%)
}
wintype(type_name)
{
; http://msdn.microsoft.com/en-us/library/aa383751(v=vs.85).aspx
static ATOM:="UShort",BOOL:="Int",BOOLEAN:="UChar",BSTR:="UPtr",BYTE:="UChar",CHAR:="Char",COLORREF:="UInt",DOUBLE:="Double",DWORD32:="UInt"
,DWORD64:="UInt64",DWORD:="UInt",DWORD_PTR:="UPtr",DWORDLONG:="UInt64",FLOAT:="Float",HACCEL:="UPtr",HALF_PTR:=A_PtrSize=8?"Int":"Short"
,HANDLE:="UPtr",HBITMAP:="UPtr",HBRUSH:="UPtr",HCOLORSPACE:="UPtr",HCONV:="UPtr",HCONVLIST:="UPtr",HCURSOR:="UPtr",HDC:="UPtr"
,HDDEDATA:="UPtr",HDESK:="UPtr",HDROP:="UPtr",HDWP:="UPtr",HENHMETAFILE:="UPtr",HFILE:="Int",HFONT:="UPtr",HGDIOBJ:="UPtr",HGLOBAL:="UPtr"
,HHOOK:="UPtr",HICON:="UPtr",HINSTANCE:="UPtr",HKEY:="UPtr",HKL:="UPtr",HLOCAL:="UPtr",HMENU:="UPtr",HMETAFILE:="UPtr",HMODULE:="UPtr"
,HMONITOR:="UPtr",HPALETTE:="UPtr",HPEN:="UPtr",HRESULT:="Int",HRGN:="UPtr",HRSRC:="UPtr",HSZ:="UPtr",HWINSTA:="UPtr",HWND:="UPtr"
,INT32:="Int",INT64:="Int64",INT:="Int",INT_PTR:="Ptr",LANGID:="UShort",LCID:="UInt",LCTYPE:="UInt",LGRPID:="UInt",LONG32:="Int"
,LONG64:="Int64",LONG:="Int",LONG_PTR:="Ptr",LONGLONG:="Int64",LPARAM:="Ptr",LPBOOL:="UPtr",LPBYTE:="UPtr",LPCOLORREF:="UPtr"
,LPCSTR:="UPtr",LPCTSTR:="UPtr",LPCVOID:="UPtr",LPCWSTR:="UPtr",LPDWORD:="UPtr",LPHANDLE:="UPtr",LPINT:="UPtr",LPLONG:="UPtr"
,LPSTR:="UPtr",LPTSTR:="UPtr",LPVOID:="UPtr",LPWORD:="UPtr",LPWSTR:="UPtr",LRESULT:="Ptr",PBOOL:="Ptr",PBOOLEAN:="Ptr",PBYTE:="Ptr"
,PCHAR:="Ptr",PCSTR:="Ptr",PCTSTR:="Ptr",PCWSTR:="Ptr",PDWORD32:="Ptr",PDWORD64:="Ptr",PDWORD:="Ptr",PDWORD_PTR:="Ptr",PDWORDLONG:="Ptr"
,PFLOAT:="Ptr",PHALF_PTR:="Ptr",PHANDLE:="UPtr",PHKEY:="UPtr",PINT32:="UPtr",PINT64:="UPtr",PINT:="UPtr",PINT_PTR:="UPtr",PLCID:="UPtr"
,PLONG32:="UPtr",PLONG64:="UPtr",PLONG:="UPtr",PLONG_PTR:="UPtr",PLONGLONG:="UPtr",POINTER_32:="UInt",POINTER_64:="Ptr"
,POINTER_SIGNED:="Ptr",POINTER_UNSIGNED:="UPtr",PSHORT:="UPtr",PSIZE_T:="UPtr",PSSIZE_T:="UPtr",PSTR:="UPtr",PTBYTE:="UPtr",PTCHAR:="UPtr"
,PTR:="Ptr",PTSTR:="UPtr",PUCHAR:="UPtr",PUHALF_PTR:="UPtr",PUINT32:="UPtr",PUINT64:="UPtr",PUINT:="UPtr",PUINT_PTR:="UPtr"
,PULONG32:="UPtr",PULONG64:="UPtr",PULONG:="UPtr",PULONG_PTR:="UPtr",PULONGLONG:="UPtr",PUSHORT:="UPtr",PVOID:="UPtr",PWCHAR:="UPtr"
,PWORD:="UPtr",PWSTR:="UPtr",SC_HANDLE:="UPtr",SC_LOCK:="UPtr",SERVICE_STATUS_HANDLE:="UPtr",SHORT:="Short",SIZE_T:="UPtr",SSIZE_T:="Ptr"
,TBYTE:=A_IsUnicode?"UShort":"UChar",TCHAR:=A_IsUnicode?"UShort":"UChar",UCHAR:="UChar",UHALF_PTR:=A_PtrSize=8?"UInt":"UShort"
,UINT32:="UInt",UINT64:="UInt64",UINT:="UInt",UINT_PTR:="UPtr",ULONG32:="UInt",ULONG64:="UInt64",ULONG:="UInt",ULONG_PTR:="UPtr"
,ULONGLONG:="UInt64",UPTR:="UPtr",USHORT:="UShort",USN:="Int64",VOID:="Ptr",WCHAR:="UShort",WNDPROC:="UPtr",WORD:="UShort",WPARAM:="UPtr"
return (%type_name%)
}
ToString(t="")
{
mObj := this.m_struct
tCls := mObj.tCls
if !mObj.addr
return this.__ErrorMsg("error_addr", this.__Class "." A_ThisFunc)
tab := " "
for order, name in tCls.varOrder
{
vObj := tCls.varList[name]
if (vObj.t="CStruct_Base")
{
for i, v in mObj.child[name]
{
str .= "`n" t name " { " v.ToString(t tab)
StringRight, chr, str, 1
str .= (chr="`n")? t "}`n" : " }`n"
}
}
else
{
nArr := this[name] ; => this.__Get(name,0)
if (nArr.error)
{
nArr =
loop % vObj.c
nArr .= ", " this.GetData(name, A_index)
StringReplace, nArr, nArr, % ", "
nArr = { %nArr% }
}
else if (vObj.c>1) or ((vObj.c=1) and InStr(vObj.org, "STR"))
nArr = `"%nArr%`"
StringRight, chr, str, 1
str .= (chr="`n")? ("`, " t name "=" nArr ) : ("`, " name "=" nArr)
}
}
StringReplace, str, str, % "`n`n", `n, all
StringReplace, str, str, % "`n`, ", `n, all
if (SubStr(str, 1, 2)="`, ")
StringReplace, str, str, % "`, "
return str
}
TreeView(Obj="", Option="", hParent="", r="", tObj="")
{
global CStruct_Base_hTreeView
if (r = "")
{
if (!IsObject(Obj))
{
if (obj)
guiTitle := Obj
if (this.__class="CStruct_Base")
{
Obj := this.m_template , r := "template"
guiTitle := (!guiTitle)? "Structure Class template" : guiTitle
}
else
Obj := this
}
iFormat := A_FormatInteger
SetFormat, integer, D
Gui +LastFound
hWnd := WinExist()
loop 99
Gui % (nDefaultGui := A_Index) ":+LastFoundExist"
until (WinExist() = hWnd)
loop 70
Gui % (nGui := A_index+29) ":+LastFoundExist"
until (hwnd:=WinExist() = 0)
if !hwnd
{
SetFormat, integer, % iFormat
return
}
Gui % nGui ":Default"
Gui +ToolWindow +Resize +LabelCStruct_Base_TreeView
Gui Margin, -1, -1
Gui Add, TreeView, w500 r18 hWndhWnd
global CStruct_Base_hTreeView
CStruct_Base_hTreeView := CStruct_Base_hTreeView? CStruct_Base_hTreeView : object()
CStruct_Base_hTreeView.Insert(nGui, hWnd)
Gui Show, x0 y0, % "[" (A_PtrSize=8? "64bit ":"") (A_IsUnicode? "Uni Ver":"Ansi Ver")
. "] No. " nGui-29 (guiTitle? " - " guiTitle : "")
if 0
{
CStruct_Base_TreeViewEscape:
CStruct_Base_TreeViewClose:
Gui % A_Gui ":Destroy"
return
CStruct_Base_TreeViewSize:
CStruct_Base.__Anchor(CStruct_Base_hTreeView[A_Gui], "wh")
return
}
}
if (Obj.__base="CStruct_Base")
{
if (tObj = "")
tObj := {}
tCls := Obj.m_struct.tCls
vList := tCls.varList
mObj := Obj.m_struct
tObj.Insert("*" Obj.__class, "size = " tCls.size " , address = " mObj.addr)
for order, name in tCls.varOrder
{
vObj := vList[name]
prop := vObj.s (vObj.c>1? " , count : " vObj.c : "")
if (vObj.t="CStruct_Base")
{
for array, cObj in mObj.child[name]
{
scnt := strlen(tCls.size) - strlen(offset := vObj.o+vObj.s*(array-1))
loop % scnt
offset := "0" offset
data := InStr(data:=cObj.ToString(), "`n")? "{ ... }" : "{ " data " }"
tObj.Insert(fullName := "[" offset "] " name (vObj.c>1? "[" array "]":"") " = " data, Object())
this.TreeView(cObj, "", "", -1, tObj[fullName])
}
}
else
{
scnt := strlen(tCls.size) - strlen(offset := vObj.o)
loop % scnt
offset := "0" offset
data := Obj[name]
str =
loop % vObj.c
{
if !data.error
hex := this.__Dec2Base(NumGet(mObj.addr+vObj.o+vObj.s*(A_index-1)
, 0, vObj.s=1? "UCHAR": vObj.s=2? "USHORT": vObj.s=4? "UINT": vObj.t), 16)
str .= ", " (data.error? Obj.GetData(name, A_index) : hex)
}
StringReplace, str, str, % ", "
if data.error
data = { %str% }
else if (vObj.c>1)
prop .= " , hex={ " str " }"
else if (vObj.c=1) and ObjHasKey(mObj.string, name)
{
ptr := Obj.GetData(name)
prop .= " , Pointer : " ptr ((ptr=ObjGetAddress(mObj.string, name))? " , Pointed include buffer : "
. Obj.GetData(name, "buffersize") " byte" : "")
}
else if (vObj.c=1) and InStr(vObj.org, "STR")
prop .= " , Pointer : " Obj.GetData(name)
if vObj.bc
{
scnt := strlen(vObj.s*8) - strlen(bitOffset := vObj.bo)
Loop % scnt
bitOffset := "0" bitOffset
offset .= "][" bitOffset
prop .= " , " vObj.bc "bit : 0~" 2**vObj.bc-1
scnt := vObj.bc - strlen(bin := this.__Dec2Base(data, 2))
loop % scnt
bin := "0" bin
data .= " [b]:" bin
}
tObj.Insert("[" offset "] " name (strlen(data)? " = " data:""), Object(vObj.org, prop))
}
}
if (r = -1)
return
r := ""
SetFormat, integer, % iFormat
Obj := tObj
}
if (IsObject(Obj))
{
if (r = "")
r := 1
for k, v in Obj
{
if (IsObject(v))
if (r = "template") and (k = "dummy")
TV_Add(k " : [object]", hParent, Option)
else
this.TreeView(v, Option, TV_Add(k, hParent, Option), r)
else
TV_Add(k (strlen(v)? " : " v : ""), hParent, Option)
}
}
if (nDefaultGui)
Gui % nDefaultGui ":Default"
}
__Anchor(i, a = "", r = false)
{
static c, cs = 12, cx = 255, cl = 0, g, gs = 8, gl = 0, gpi, gw, gh, z = 0, k = 0xffff
If z = 0
VarSetCapacity(g, gs * 99, 0), VarSetCapacity(c, cs * cx, 0), z := true
If (!WinExist("ahk_id" . i)) {
GuiControlGet, t, Hwnd, %i%
If ErrorLevel = 0
i := t
Else ControlGet, i, Hwnd, , %i%
}
VarSetCapacity(gi, 68, 0), DllCall("GetWindowInfo", "UInt", gp := DllCall("GetParent", "UInt", i), "UInt", &gi)
, giw := NumGet(gi, 28, "Int") - NumGet(gi, 20, "Int"), gih := NumGet(gi, 32, "Int") - NumGet(gi, 24, "Int")
If (gp != gpi) {
gpi := gp
Loop, %gl%
If (NumGet(g, cb := gs * (A_Index - 1), "Int") == gp) {
gw := NumGet(g, cb + 4, "Short"), gh := NumGet(g, cb + 6, "Short"), gf := 1
Break
}
If (!gf)
NumPut(gp, g, gl, "Int"), NumPut(gw := giw, g, gl + 4, "Short"), NumPut(gh := gih, g, gl + 6, "Short"), gl += gs
}
ControlGetPos, dx, dy, dw, dh, , ahk_id %i%
Loop, %cl%
If (NumGet(c, cb := cs * (A_Index - 1), "Int") == i) {
If a =
{
cf = 1
Break
}
giw -= gw, gih -= gh, as := 1, dx := NumGet(c, cb + 4, "Short"), dy := NumGet(c, cb + 6, "Short")
, cw := dw, dw := NumGet(c, cb + 8, "Short"), ch := dh, dh := NumGet(c, cb + 10, "Short")
Loop, Parse, a, xywh
If A_Index > 1
av := SubStr(a, as, 1), as += 1 + StrLen(A_LoopField)
, d%av% += (InStr("yh", av) ? gih : giw) * (A_LoopField + 0 ? A_LoopField : 1)
DllCall("SetWindowPos", "UInt", i, "Int", 0, "Int", dx, "Int", dy
, "Int", InStr(a, "w") ? dw : cw, "Int", InStr(a, "h") ? dh : ch, "Int", 4)
If r != 0
DllCall("RedrawWindow", "UInt", i, "UInt", 0, "UInt", 0, "UInt", 0x0101) ; RDW_UPDATENOW | RDW_INVALIDATE
Return
}
If cf != 1
cb := cl, cl += cs
bx := NumGet(gi, 48, "Int"), by := NumGet(gi, 16, "Int") - NumGet(gi, 8, "Int") - gih - NumGet(gi, 52, "Int")
If cf = 1
dw -= giw - gw, dh -= gih - gh
NumPut(i, c, cb, "Int"), NumPut(dx - bx, c, cb + 4, "Short"), NumPut(dy - by, c, cb + 6, "Short")