-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathw3iorsmd.F90
1513 lines (1502 loc) · 54.9 KB
/
w3iorsmd.F90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!> @file
!> @brief Read/write restart files.
!>
!> @author H. L. Tolman @date 22-Mar-2021
!>
#include "w3macros.h"
!/ ------------------------------------------------------------------- /
!>
!> @brief Read/write restart files.
!>
!> @author H. L. Tolman @date 22-Mar-2021
!>
MODULE W3IORSMD
!/
!/ +-----------------------------------+
!/ | WAVEWATCH III NOAA/NCEP |
!/ | H. L. Tolman |
!/ | FORTRAN 2003 |
!/ | Last update : 22-Mar-2021 |
!/ +-----------------------------------+
!/
!/ See subroutine for update log.
!/
! 1. Purpose :
!
! Read/write restart files.
!
! 2. Variables and types :
!
! Name Type Scope Description
! ----------------------------------------------------------------
! VERINI C*10 Private Restart file version number.
! IDSTR C*26 Private Restart file UD string.
! ----------------------------------------------------------------
!
! 3. Subroutines and functions :
!
! Name Type Scope Description
! ----------------------------------------------------------------
! W3IORS Subr. Public Read/write restart files.
! ----------------------------------------------------------------
!
! 4. Subroutines and functions used :
!
! Name Type Module Description
! ----------------------------------------------------------------
! W3SETO, W3SETG, W3SETW, W3DIMW
! Subr. W3xDATMD Manage data structures.
! STRACE Subr. W3SERVMD Subroutine tracing. (!/S)
! EXTCDE Subr. W3SERVMD Abort program with exit code.
! MPI_STARTALL, MPI_WAITALL (!/MPI)
! Subr. MPI persistent communication routines
! ----------------------------------------------------------------
!
! 5. Remarks :
!
! 6. Switches :
!
! See also routine.
!
! 7. Source code :
!
!/ ------------------------------------------------------------------- /
!module default
IMPLICIT NONE
PUBLIC
!/
! Add fields needed for OASIS coupling in restart
LOGICAL :: OARST
!/
!/ Private parameter statements (ID strings)
!/
CHARACTER(LEN=10), PARAMETER, PRIVATE :: VERINI = '2021-05-28'
CHARACTER(LEN=26), PARAMETER, PRIVATE :: &
IDSTR = 'WAVEWATCH III RESTART FILE'
!/
CONTAINS
!/ ------------------------------------------------------------------- /
!>
!> @brief Reads/writes restart files.
!>
!> @details
!> @verbatim
!> The file is opened within the routine, the name is pre-defined
!> and the unit number is given in the parameter list. The restart
!> file is written using UNFORMATTED write statements. The routine
!> generates new names when called more than once. File names are :
!>
!> restart000.FILEXT
!> restart001.FILEXT
!> restart002.FILEXT etc.
!>
!> Optionally, a second stream of restart files is generated given
!> a secondary stride definad by an additional start/end time line
!> triggered by an optional argument added to the end of the stan-
!> dard restart request line (a sixth argument flag set to T). File
!> names include a time-tag prefix:
!>
!> YYYYMMDD.HHMMSS.restart.FILEXT
!>
!> The file to be read thus always is unnumbered, whereas all
!> written files are automatically numbered.
!> @endverbatim
!>
!> @param[in] INXOUT Test string for read/write.
!> @param[inout] NDSR File unit number.
!> @param[in] DUMFPI Dummy values for FPIS for cold start.
!> @param[in] IMOD Optional grid number, defaults to 1.
!> @param[in] FLRSTRT A second request for restart files (optional TRUE).
!>
!> @author H. L. Tolman @date 22-Mar-2021
!>
SUBROUTINE W3IORS ( INXOUT, NDSR, DUMFPI, IMOD, FLRSTRT , filename)
!/
!/ +-----------------------------------+
!/ | WAVEWATCH III NOAA/NCEP |
!/ | H. L. Tolman |
!/ | FORTRAN 90 |
!/ | Last update : 22-Mar-2021 |
!/ +-----------------------------------+
!/
!/ 12-Jan-1999 : Final FORTRAN 77 ( version 1.18 )
!/ 27-Dec-1999 : Upgrade to FORTRAN 90 ( version 2.00 )
!/ 30-Apr-2002 : Add ice for transparencies. ( version 2.20 )
!/ 13-Nov-2002 : Add stress as vector. ( version 3.00 )
!/ 19-Aug-2003 : Output server options added. ( version 3.04 )
!/ 09-Dec-2004 : Multiple grid version. ( version 3.06 )
!/ 24-Jun-2005 : Adding MAPST2. ( version 3.07 )
!/ 27-Jun-2006 : Adding file name preamble. ( version 3.09 )
!/ 05-Jul-2006 : Consolidate stress arrays. ( version 3.09 )
!/ 08-May-2007 : Starting from calm as an option. ( version 3.11 )
!/ 17-May-2007 : Adding NTPROC/NAPROC separation. ( version 3.11 )
!/ 22-Jun-2007 : Dedicated output processes. ( version 3.11 )
!/ 15-Apr-2008 : Clean up for distribution. ( version 3.14 )
!/ 21-Apr-2008 : Remove PGI bug internal files. ( version 3.14 )
!/ 29-May-2009 : Preparing distribution version. ( version 3.14 )
!/ 30-Oct-2009 : Output file name with 3 digit id. ( version 3.14 )
!/ (W. E. Rogers, NRL)
!/ 14-Nov-2013 : Remove cold start init. UST(DIR). ( version 4.13 )
!/ 31-May-2016 : Optimize restart file size for un- ( version 5.10 )
!/ structured grid and restart read.
!/ (M. Ward, NCI, S. Zieger, BOM)
!/ 10-Mar-2017 : File access mode changed to 'STREAM'( version 6.02 )
!/ (S. Zieger, BOM)
!/ 09-Aug-2017 : Bug fix for MPI restart read issue ( version 6.02 )
!/ (T. Campbell, NRL)
!/ 05-Jun-2018 : Add PDLIB/TIMINGS/DEBUGIO ( version 6.04 )
!/ DEBUGINIT/MPI
!/ 19-Dec-2019 : Optional second stream of ( version 7.00 )
!/ restart files
!/ (Roberto Padilla-Hernandez & J.H. Alves)
!/ 25-Sep-2020 : Extra fields for coupled restart ( version 7.10 )
!/ 22-Mar-2021 : Add new coupling fields in restart ( version 7.13 )
!/ 18-May-2021 : Read by default all extra restart ( version 7.13 )
!/
!/ Copyright 2009-2013 National Weather Service (NWS),
!/ National Oceanic and Atmospheric Administration. All rights
!/ reserved. WAVEWATCH III is a trademark of the NWS.
!/ No unauthorized use without permission.
!/
! 1. Purpose :
!
! Reads/writes restart files.
!
! 2. Method :
!
! The file is opened within the routine, the name is pre-defined
! and the unit number is given in the parameter list. The restart
! file is written using UNFORMATTED write statements. The routine
! generates new names when called more than once. File names are :
!
! restart000.FILEXT
! restart001.FILEXT
! restart002.FILEXT etc.
!
! Optionally, a second stream of restart files is generated given
! a secondary stride definad by an additional start/end time line
! triggered by an optional argument added to the end of the stan-
! dard restart request line (a sixth argument flag set to T). File
! names include a time-tag prefix:
!
! YYYYMMDD.HHMMSS.restart.FILEXT
!
! The file to be read thus always is unnumbered, whereas all
! written files are automatically numbered.
!
! 3. Parameters :
!
! Parameter list
! ----------------------------------------------------------------
! INXOUT C*(*) I Test string for read/write, valid are:
! 'READ' Reading of a restart file.
! 'HOT' Writing a full restart from the model.
! 'COLD' Writing a cold start file.
! 'WIND' Initialize fields using first wind
! field.
! 'CALM' Starting from calm conditions.
! NDSR Int. I/O File unit number.
! DUMFPI Real I Dummy values for FPIS for cold start.
! RSTYPE Int. O Type of input field,
! 0 : cold start,
! 1 : cold start with fetch-limited spectra,
! 2 : full restart,
! 3 : for writing file.
! 4 : starting from calm.
! IMOD Int. I Optional grid number, defaults to 1.
! FLRSTRT LOGIC I OTIONAL TRUE: A second request for restart files
! ----------------------------------------------------------------
!
! 4. Subroutines used :
!
! See module documentation.
!
! 5. Called by :
!
! Name Type Module Description
! ----------------------------------------------------------------
! W3INIT Subr. W3INITMD Wave model initialization routine.
! W3WAVE Subr. W3WAVEMD Actual wave model routine.
! WW3_STRT Prog. N/A Initial conditions program.
! ----------------------------------------------------------------
!
! 6. Error messages :
!
! Tests on INXOUT, file status and on array dimensions.
!
! 7. Remarks :
!
! - MAPSTA is dumped as it contains information on inactive points.
! Note that the original MAPSTA is dumped in the model def. file
! for use in the initial conditions (and output) programs.
! - Note that MAPSTA and MAPST2 data is combinded in the file.
! - The depth is recalculated in a write to avoid floating point
! errors in W3STRT.
! - Fields and field info read by all, written by las processor
! only.
! - The MPP version of the model will perform a gather here to
! maximize hiding of communication with IO.
!
! 8. Structure :
!
! +---------------------------------------------------------------+
! | initialisations |
! | test INXOUT |
! | open file |
! +---------------------------------------------------------------|
! | WRITE ? |
! | Y N |
! |-------------------------------|-------------------------------|
! | Write identifiers and | Write identifiers and |
! | dimensions. | dimensions. |
! | | Check ident. and dimensions. |
! +-------------------------------+-------------------------------|
! | Full restart ? |
! | Y N |
! |-------------------------------|-------------------------------|
! | read/write/test time | |
! +-------------------------------+-------------------------------|
! | WRITE ? |
! | Y N |
! |-------------------------------|-------------------------------|
! | TYPE = 'WIND' ? | TYPE = 'WIND' ? |
! | Y N | Y N |
! |---------------|---------------|---------------|---------------|
! | close file | write spectra | gen. fetch-l. | read spectra |
! | RETURN | | spectra. | |
! |---------------+---------------+---------------+---------------|
! | WRITE ? |
! | Y N |
! |-------------------------------|-------------------------------|
! | TYPE = 'FULL' ? | TYPE = 'FULL' ? |
! | Y N | Y N |
! |---------------|---------------|---------------|---------------|
! | write level & | ( prep. level | read level & | initalize l.& |
! | (ice) map & | for test | (ice) map.& | times |
! | times | output ) | times | ( no ice ) |
! +---------------+---------------+---------------+-------------- +
!
! 9. Switches :
!
! !/SEED Linear input / seeding option.
! !/LNx
!
! !/SHRD Switch for shared / distributed memory architecture.
! !/DIST Id.
! !/MPI Id.
!
! !/S Enable subroutine tracing.
! !/T Enable test output
!
! 10. Source code :
!
!/ ------------------------------------------------------------------- /
USE W3GDATMD, ONLY: W3SETG, W3SETREF, RSTYPE
USE W3ODATMD, ONLY: W3SETO
USE W3WDATMD, only: W3SETW, W3DIMW
USE W3ADATMD, ONLY: W3SETA, W3XETA, NSEALM
USE W3ADATMD, ONLY: CX, CY, HS, WLM, T0M1, T01, FP0, THM, CHARN,&
TAUWIX, TAUWIY, TWS, TAUOX, TAUOY, BHD, &
PHIOC, TUSX, TUSY, USSX, USSY, TAUICE, &
UBA, UBD, PHIBBL, TAUBBL, TAUOCX, TAUOCY, &
WNMEAN
!/
USE W3GDATMD, ONLY: NX, NY, NSEA, NSEAL, NSPEC, MAPSTA, MAPST2, &
GNAME, FILEXT, GTYPE, UNGTYPE
USE W3TRIAMD, ONLY: SET_UG_IOBP
USE W3WDATMD, only : DINIT, VA, TIME, TLEV, TICE, TRHO, ICE, UST
USE W3WDATMD, only : USTDIR, ASF, FPIS, ICEF, TIC1, TIC5, WLV
#ifdef W3_WRST
USE W3IDATMD, ONLY: WXN, WYN, W3SETI
USE W3IDATMD, ONLY: WXNwrst, WYNwrst
#endif
USE W3ODATMD, ONLY: NDSE, NDST, IAPROC, NAPROC, NAPERR, NAPRST, &
IFILE => IFILE4, FNMPRE, NTPROC, IOSTYP, &
FLOGRR, NOGRP, NGRPP, SCREEN
#ifdef W3_MPI
USE W3ODATMD, ONLY: NRQRS, NBLKRS, RSBLKS, IRQRS, IRQRSS, &
VAAUX
USE W3ADATMD, ONLY: MPI_COMM_WCMP
#endif
!/
USE W3SERVMD, ONLY: EXTCDE
USE CONSTANTS, only: LPDLIB, file_endian
USE W3PARALL, ONLY: INIT_GET_ISEA, INIT_GET_JSEA_ISPROC
USE W3GDATMD, ONLY: NK, NTH
#ifdef W3_TIMINGS
USE W3PARALL, ONLY: PRINT_MY_TIME
#endif
USE w3odatmd, ONLY : RUNTYPE, INITFILE
USE w3adatmd, ONLY : USSHX, USSHY
#ifdef W3_PDLIB
USE PDLIB_FIELD_VEC
#endif
#ifdef W3_S
USE W3SERVMD, ONLY: STRACE
#endif
!
#ifdef W3_MPI
INCLUDE "mpif.h"
#endif
!/
!/ ------------------------------------------------------------------- /
!/ Parameter list
!/
INTEGER :: NDSR
! INTEGER, INTENT(IN) :: NDSR
INTEGER, INTENT(IN), OPTIONAL :: IMOD
REAL, INTENT(INOUT) :: DUMFPI
CHARACTER, INTENT(IN) :: INXOUT*(*)
LOGICAL, INTENT(IN),OPTIONAL :: FLRSTRT
character(len=*), intent(in), optional :: filename
!/
!/ ------------------------------------------------------------------- /
!/ Local parameters
!/
INTEGER, PARAMETER :: LRB = 4
!
INTEGER :: IGRD, I, J, LRECL, NSIZE, IERR, &
NSEAT, MSPEC, TTIME(2), ISEA, JSEA, &
NREC, NPART, IPART, IX, IY, IXL, IP, &
NPRTX2, NPRTY2, IYL, ITMP
INTEGER, ALLOCATABLE :: MAPTMP(:,:)
#ifdef W3_S
INTEGER, SAVE :: IENT = 0
#endif
#ifdef W3_MPI
INTEGER :: IERR_MPI, IH, IB, ISEA0, ISEAN, &
NRQ, NSEAL_MIN
#endif
INTEGER(KIND=8) :: RPOS
#ifdef W3_MPI
INTEGER, ALLOCATABLE :: STAT1(:,:), STAT2(:,:)
REAL, ALLOCATABLE :: VGBUFF(:), VLBUFF(:)
#endif
REAL(KIND=LRB), ALLOCATABLE :: WRITEBUFF(:), TMP(:), TMP2(:)
LOGICAL :: WRITE, IOSFLG
LOGICAL :: FLOGOA(NOGRP,NGRPP)
LOGICAL :: NDSROPN
CHARACTER(LEN=4) :: TYPE
CHARACTER(LEN=10) :: VERTST
CHARACTER(LEN=512) :: FNAME
CHARACTER(LEN=26) :: IDTST
CHARACTER(LEN=30) :: TNAME
CHARACTER(LEN=15) :: TIMETAG
character(len=16) :: user_timestring !YYYY-MM-DD-SSSSS
logical :: exists
!/
!/ ------------------------------------------------------------------- /
!/
#ifdef W3_S
CALL STRACE (IENT, 'W3IORS')
#endif
!
!
! Constant NDSR for using mpiifort in ZEUS ... paralell runs crashing
! because compiler doesn't accept reciclyng of UNIT for FORMATTED or
! UNFORMATTED files in OPEN
!
! NDSR = 525
IOSFLG = IOSTYP .GT. 0
!
! test parameter list input ------------------------------------------ *
!
IF ( PRESENT(IMOD) ) THEN
IGRD = IMOD
ELSE
IGRD = 1
END IF
!
CALL W3SETO ( IGRD, NDSE, NDST )
CALL W3SETG ( IGRD, NDSE, NDST )
CALL W3SETW ( IGRD, NDSE, NDST )
#ifdef W3_WRST
CALL W3SETI ( IGRD, NDSE, NDST )
#endif
!
IF (INXOUT.NE.'READ' .AND. INXOUT.NE.'HOT' .AND. &
INXOUT.NE.'COLD' .AND. INXOUT.NE.'WIND' .AND. &
INXOUT.NE.'CALM' ) THEN
IF ( IAPROC .EQ. NAPERR ) WRITE (NDSE,900) INXOUT
CALL EXTCDE ( 1 )
END IF
!
WRITE = INXOUT .NE. 'READ'
IF ( INXOUT .EQ. 'HOT' ) THEN
TYPE = 'FULL'
ELSE
TYPE = INXOUT
END IF
!
#ifdef W3_T
WRITE (NDST,9000) INXOUT, WRITE, NTPROC, NAPROC, IAPROC, NAPRST
#endif
!
! initializations ---------------------------------------------------- *
!
IF ( .NOT.DINIT ) THEN
IF ( IAPROC .LE. NAPROC ) THEN
CALL W3DIMW ( IMOD, NDSE, NDST )
ELSE
CALL W3DIMW ( IMOD, NDSE, NDST, .FALSE. )
END IF
END IF
!
IF ( IAPROC .LE. NAPROC ) VA(:,0) = 0.
!
LRECL = MAX ( LRB*NSPEC , &
LRB*(6+(25/LRB)+(9/LRB)+(29/LRB)+(3/LRB)) )
NSIZE = LRECL / LRB
! --- Allocate buffer array with zeros (used to
! fill bytes up to size LRECL). ---
ALLOCATE(WRITEBUFF(NSIZE))
WRITEBUFF(:) = 0.
!
! Allocate memory to receive fields needed for coupling
IF (OARST) THEN
ALLOCATE(TMP(NSEA))
ALLOCATE(TMP2(NSEA))
ENDIF
!
! open file ---------------------------------------------------------- *
!
if (present(filename)) then ! only when restart_nc and restart_from_binary=true
open (ndsr,file=trim(filename),form='unformatted', convert=file_endian, &
access='stream',err=800,iostat=ierr, status='old',action='read')
else
I = LEN_TRIM(FILEXT)
J = LEN_TRIM(FNMPRE)
!
!CHECKPOINT RESTART FILE
ITMP=0
IF ( PRESENT(FLRSTRT) ) THEN
IF (FLRSTRT) THEN
WRITE(TIMETAG,"(i8.8,'.'i6.6)")TIME(1),TIME(2)
FNAME=TIMETAG//'.restart.'//FILEXT(:I)
ITMP=1
END IF
END IF
IF(ITMP.NE.1)THEN ! FNAME is not set above, so do it here
IF ( IFILE.EQ.0 ) THEN
FNAME = 'restart.'//FILEXT(:I)
ELSE
FNAME = 'restartNNN.'//FILEXT(:I)
IF ( WRITE .AND. IAPROC.EQ.NAPRST ) &
WRITE (FNAME(8:10),'(I3.3)') IFILE
END IF
END IF
IFILE = IFILE + 1
!
#ifdef W3_T
WRITE (NDST,9001) trim(FNAME), LRECL
#endif
!
IF(NDST.EQ.NDSR)THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE(NDSE,'(A,I8)')'UNIT NUMBERS OF RESTART FILE AND '&
//'TEST OUTPUT ARE THE SAME : ',NDST
CALL EXTCDE ( 15 )
ENDIF
IF ( WRITE ) THEN
IF ( .NOT.IOSFLG .OR. IAPROC.EQ.NAPRST ) &
OPEN (NDSR,FILE=FNMPRE(:J)//trim(FNAME),form='UNFORMATTED', convert=file_endian, &
ACCESS='STREAM',ERR=800,IOSTAT=IERR)
ELSE
OPEN (NDSR,FILE=FNMPRE(:J)//trim(FNAME),form='UNFORMATTED', convert=file_endian, &
ACCESS='STREAM',ERR=800,IOSTAT=IERR, &
STATUS='OLD',ACTION='READ')
END IF
end if ! if (present(filename))
!
! test info ---------------------------------------------------------- *
!
IF ( WRITE ) THEN
!
IF ( IAPROC .EQ. NAPRST ) THEN
! Because data has mixed data types we do not know how many
! bytes remain to fill up to LRECL. ---
! --- Make the entire record zero ---
WRITEBUFF(:) = 0.
WRITE (NDSR,POS=1) WRITEBUFF
! --- Replace zeros with data ---
WRITE (NDSR,POS=1) IDSTR, VERINI, GNAME, TYPE, NSEA, &
NSPEC, FLOGRR
END IF
RSTYPE = 3
!
ELSE
READ (NDSR,POS=1,ERR=802,IOSTAT=IERR) &
IDTST, VERTST, TNAME, TYPE, NSEAT, MSPEC, FLOGOA
!
IF ( IDTST .NE. IDSTR ) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,901) IDTST, IDSTR
CALL EXTCDE ( 10 )
END IF
IF ( VERTST .NE. VERINI ) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,902) VERTST, VERINI
CALL EXTCDE ( 11 )
END IF
IF ( TNAME .NE. GNAME ) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,903) TNAME, GNAME
END IF
IF (TYPE.NE.'FULL' .AND. TYPE.NE.'COLD' .AND. &
TYPE.NE.'WIND' .AND. TYPE.NE.'CALM' ) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,904) TYPE
CALL EXTCDE ( 12 )
END IF
IF (NSEAT.NE.NSEA .OR. NSPEC.NE.MSPEC) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,905) MSPEC, NSEAT, NSPEC, NSEA
CALL EXTCDE ( 13 )
END IF
IF (TYPE.EQ.'FULL') THEN
RSTYPE = 2
ELSE IF (TYPE.EQ.'WIND') THEN
RSTYPE = 1
ELSE IF (TYPE.EQ.'CALM') THEN
RSTYPE = 4
ELSE
RSTYPE = 0
END IF
IF (.NOT. WRITE .AND. OARST .AND. IAPROC .EQ. NAPROC) THEN
DO I=1, NOGRP
DO J=1, NGRPP
IF (FLOGRR(I,J) .AND. .NOT. FLOGOA(I,J)) THEN
WRITE(SCREEN,1000) I, J
ENDIF
ENDDO
ENDDO
ENDIF
!
END IF
!
100 CONTINUE
!
#ifdef W3_T
WRITE (NDST,9002) IDSTR, VERINI, GNAME, TYPE, &
NSEA, NSEAL, NSPEC
#endif
!
! TIME if required --------------------------------------------------- *
!
IF (TYPE.EQ.'FULL') THEN
RPOS = 1_8 + LRECL*(2-1_8)
IF ( WRITE ) THEN
IF ( IAPROC .EQ. NAPRST ) THEN
WRITEBUFF(:) = 0.
WRITE (NDSR,POS=RPOS) WRITEBUFF
WRITE (NDSR,POS=RPOS) TIME
END IF
ELSE
READ (NDSR,POS=RPOS,ERR=802,IOSTAT=IERR) TTIME
!TODO: can this be removed?
#ifdef W3_CESMCOUPLED
if (runtype == 'branch' .or. runtype == 'continue') then
IF (TIME(1).NE.TTIME(1) .OR. TIME(2).NE.TTIME(2)) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,906) TTIME, TIME
CALL EXTCDE ( 20 )
END IF
end if
#else
IF (TIME(1).NE.TTIME(1) .OR. TIME(2).NE.TTIME(2)) THEN
IF ( IAPROC .EQ. NAPERR ) &
WRITE (NDSE,906) TTIME, TIME
CALL EXTCDE ( 20 )
END IF
#endif
END IF
!
#ifdef W3_T
WRITE (NDST,9003) TIME
ELSE
WRITE (NDST,9004)
#endif
!
END IF
!
! Spectra ------------------------------------------------------------ *
! ( Bail out if write for TYPE.EQ.'WIND' )
!
IF ( WRITE ) THEN
IF ( TYPE.EQ.'WIND' .OR. TYPE.EQ.'CALM' ) THEN
IF ( .NOT.IOSFLG .OR. IAPROC.EQ.NAPRST ) THEN
CLOSE ( NDSR )
END IF
#ifdef W3_T
WRITE (NDST,9005) TYPE
#endif
! Clean up file handles and allocated arrays
INQUIRE (UNIT=NDSR, OPENED=NDSROPN)
IF (NDSROPN) CLOSE(NDSR)
IF (ALLOCATED(WRITEBUFF)) DEALLOCATE(WRITEBUFF)
IF (ALLOCATED(TMP)) DEALLOCATE(TMP)
IF (ALLOCATED(TMP2)) DEALLOCATE(TMP2)
RETURN
ELSE IF ( IAPROC.LE.NAPROC .OR. IAPROC.EQ. NAPRST ) THEN
!
! Original non-server version writing of spectra
!
IF ( .NOT.IOSFLG .OR. (NAPROC.EQ.1.AND.NAPRST.EQ.1) ) THEN
#ifdef W3_MPI
DO JSEA=1, NSEAL
CALL INIT_GET_ISEA(ISEA, JSEA)
NREC = ISEA + 2
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITEBUFF(:) = 0.
WRITEBUFF(1:NSPEC) = VA(1:NSPEC,JSEA)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
END DO
#else
DO JSEA=1, NSEA
ISEA = JSEA
NREC = ISEA + 2
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITEBUFF(:) = 0.
WRITEBUFF(1:NSPEC) = VA(1:NSPEC,JSEA)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
END DO
#endif
!
! I/O server version writing of spectra ( !/MPI )
!
#ifdef W3_MPI
ELSE
!
IF (LPDLIB) THEN
#endif
#ifdef W3_TIMINGS
CALL PRINT_MY_TIME("Before UNST_PDLIB_WRITE_TO_FILE")
#endif
#ifdef W3_PDLIB
CALL UNST_PDLIB_WRITE_TO_FILE(NDSR)
#endif
#ifdef W3_TIMINGS
CALL PRINT_MY_TIME("After UNST_PDLIB_WRITE_TO_FILE")
#endif
#ifdef W3_MPI
ELSE
IF ( IAPROC .NE. NAPRST ) THEN
NRQ = 1
ELSE IF ( NAPRST .LE. NAPROC ) THEN
NRQ = NAPROC - 1
ELSE
NRQ = NAPROC
END IF
!
ALLOCATE ( STAT1(MPI_STATUS_SIZE,NRQ) )
IF ( IAPROC .EQ. NAPRST ) CALL MPI_STARTALL &
( NRQ, IRQRSS, IERR_MPI )
!
DO IB=1, NBLKRS
ISEA0 = 1 + (IB-1)*RSBLKS*NAPROC
ISEAN = MIN ( NSEA , IB*RSBLKS*NAPROC )
!
IF ( IAPROC .EQ. NAPRST ) THEN
!
IH = 1 + NRQ * (IB-1)
CALL MPI_WAITALL &
( NRQ, IRQRSS(IH), STAT1, IERR_MPI )
IF ( IB .LT. NBLKRS ) THEN
IH = 1 + NRQ * IB
CALL MPI_STARTALL &
( NRQ, IRQRSS(IH), IERR_MPI )
END IF
!
DO ISEA=ISEA0, ISEAN
NREC = ISEA + 2
CALL INIT_GET_JSEA_ISPROC(ISEA, JSEA, IP)
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITEBUFF(:) = 0.
IF ( IP .EQ. NAPRST ) THEN
WRITEBUFF(1:NSPEC) = VA(1:NSPEC,JSEA)
ELSE
JSEA = JSEA - 2*((IB-1)/2)*RSBLKS
WRITEBUFF(1:NSPEC) = VAAUX(1:NSPEC,JSEA,IP)
END IF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
WRITEBUFF
END DO
!
ELSE
!
CALL MPI_STARTALL &
( 1, IRQRSS(IB), IERR_MPI )
CALL MPI_WAITALL &
( 1, IRQRSS(IB), STAT1, IERR_MPI )
!
END IF
END DO
!
DEALLOCATE ( STAT1 )
END IF
#endif
!
END IF
!
END IF
ELSE
!
! Reading spectra
!
IF ( TYPE.EQ.'WIND' .OR. TYPE.EQ.'CALM' ) THEN
#ifdef W3_T
WRITE (NDST,9020) TYPE
#endif
ELSE
IF (LPDLIB) THEN
#ifdef W3_TIMINGS
CALL PRINT_MY_TIME("Before UNST_PDLIB_READ_FROM_FILE")
#endif
#ifdef W3_PDLIB
CALL UNST_PDLIB_READ_FROM_FILE(NDSR)
#endif
#ifdef W3_TIMINGS
CALL PRINT_MY_TIME("After UNST_PDLIB_READ_FROM_FILE")
#endif
ELSE
#ifdef W3_MPI
NSEAL_MIN = 1 + (NSEA-NAPROC)/NAPROC
IF ( NAPROC.GT.1 ) THEN
!/ ----------- Large number of small-sized record reads will tend ---- *
!/ to perform badly on most file systems. We read this part
!/ using streams and scatter the results using MPI.
!/ ( M. WARD, NCI )
!
! Begin computational proc. only section ---------------- *
IF ( IAPROC.LE.NAPROC ) THEN
!
! Main loop --------------------------------------------- *
ALLOCATE( VGBUFF( NSIZE * NAPROC ) )
ALLOCATE( VLBUFF( NSIZE ) )
!
DO JSEA = 1, NSEAL_MIN
! Read NAPROC records into buffer VGBUFF. ------------- *
IF ( IAPROC .EQ. NAPROC ) THEN
RPOS = 1_8 + (2 + (JSEA - 1_8) * NAPROC) * LRECL
READ(NDSR, POS=RPOS,ERR=802,IOSTAT=IERR) VGBUFF(:)
ELSE
VGBUFF(:) = 0.
END IF
! Distribute one record to each rank.
CALL MPI_SCATTER(VGBUFF, NSIZE, MPI_REAL, &
VLBUFF, NSIZE, MPI_REAL, &
NAPROC-1, MPI_COMM_WCMP, IERR )
! Transfer the spectral content of VLBUFF to VA. ------ *
VA(1:NSPEC,JSEA) = VLBUFF(1:NSPEC)
END DO
!
! Include remainder values (switch to record format) ---- *
JSEA = NSEAL_MIN + 1
IF ( JSEA.EQ.NSEAL ) THEN
CALL INIT_GET_ISEA(ISEA, JSEA)
NREC = ISEA + 2
RPOS = 1_8 + LRECL*(NREC-1_8)
READ (NDSR, POS=RPOS, ERR=802, IOSTAT=IERR) &
(VA(I,JSEA), I=1,NSPEC)
END IF
!
DEALLOCATE( VGBUFF )
DEALLOCATE( VLBUFF )
!
! End computational proc. only section ------------------ *
END IF
!
ELSE
#endif
VA = 0.
DO JSEA=1, NSEA
CALL INIT_GET_ISEA(ISEA, JSEA)
NREC = ISEA + 2
RPOS = 1_8 + LRECL*(NREC-1_8)
READ (NDSR,POS=RPOS,ERR=802,IOSTAT=IERR) &
(VA(I,JSEA),I=1,NSPEC)
ENDDO
#ifdef W3_MPI
END IF
#endif
END IF
END IF
END IF
VA = MAX(0.,VA)
!
#ifdef W3_T
WRITE (NDST,9006)
#endif
!
! Water level etc. if required --------------------------------------- *
! ( For cold start write test output and cold start initialize
! water levels. Note that MAPSTA overwrites the one read from the
! model definition file, so that it need not be initialized. )
!
NREC = NSEA + 3
NPART = 1 + (NSEA-1)/NSIZE
NPRTX2 = 1 + (NX-1)/NSIZE
NPRTY2 = 1 + (NY-1)/NSIZE
!
IF ( WRITE ) THEN
!
IF (TYPE.EQ.'FULL') THEN
!
IF ( IAPROC .EQ. NAPRST ) THEN
!
#ifdef W3_MPI
if (associated(irqrs)) then
ALLOCATE ( STAT2(MPI_STATUS_SIZE,NRQRS) )
CALL MPI_WAITALL &
( NRQRS, IRQRS , STAT2, IERR_MPI )
DEALLOCATE ( STAT2 )
end if
#endif
!
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITEBUFF(:) = 0.
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
TLEV, TICE, TRHO
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(WLV(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(ICE(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
#ifdef W3_WRST
! The WRST switch saves the values of wind in the
! restart file and then uses the wind for the first
! time step here. This is needed when coupling with
! an atm model that does not have 10m wind speeds at
! initialization. If there is no restart, wind is zero
#endif
#ifdef W3_WRST
DO IX=1, NX
DO IPART=1,NPRTY2
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(WXN(IX,IYL),IYL=1+(IPART-1)*NSIZE, &
MIN(NY,IPART*NSIZE))
END DO
END DO
DO IX=1, NX
DO IPART=1,NPRTY2
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(WYN(IX,IYL),IYL=1+(IPART-1)*NSIZE, &
MIN(NY,IPART*NSIZE))
END DO
END DO
#endif
ALLOCATE ( MAPTMP(NY,NX) )
MAPTMP = MAPSTA + 8*MAPST2
DO IY=1, NY
DO IPART=1,NPRTX2
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(MAPTMP(IY,IXL),IXL=1+(IPART-1)*NSIZE, &
MIN(NX,IPART*NSIZE))
END DO
END DO
DEALLOCATE ( MAPTMP )
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(UST(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(USTDIR(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(ASF(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
DO IPART=1,NPART
NREC = NREC + 1
RPOS = 1_8 + LRECL*(NREC-1_8)
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) WRITEBUFF
WRITE (NDSR,POS=RPOS,ERR=803,IOSTAT=IERR) &
(FPIS(ISEA),ISEA=1+(IPART-1)*NSIZE, &
MIN(NSEA,IPART*NSIZE))
END DO
IF (OARST) THEN
#ifdef W3_MPI
CALL W3XETA ( IGRD, NDSE, NDST )
#endif
!
IF ( FLOGRR(1,2) ) THEN
WRITE(NDSR,ERR=803,IOSTAT=IERR) CX(1:NSEA)
WRITE(NDSR,ERR=803,IOSTAT=IERR) CY(1:NSEA)
ENDIF
IF ( FLOGRR(1,12) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) ICEF(1:NSEA)
IF ( FLOGRR(2,1) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) HS(1:NSEA)
IF ( FLOGRR(2,2) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) WLM(1:NSEA)
IF ( FLOGRR(2,4) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) T0M1(1:NSEA)
IF ( FLOGRR(2,5) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) T01(1:NSEA)
IF ( FLOGRR(2,6) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) FP0(1:NSEA)
IF ( FLOGRR(2,7) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) THM(1:NSEA)
IF ( FLOGRR(2,19) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) WNMEAN(1:NSEA)
IF ( FLOGRR(5,2) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) CHARN(1:NSEA)
IF ( FLOGRR(5,5) ) THEN
WRITE(NDSR,ERR=803,IOSTAT=IERR) TAUWIX(1:NSEA)
WRITE(NDSR,ERR=803,IOSTAT=IERR) TAUWIY(1:NSEA)
ENDIF
IF ( FLOGRR(5,11) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) TWS(1:NSEA)
IF ( FLOGRR(6,2) ) THEN
WRITE(NDSR,ERR=803,IOSTAT=IERR) TAUOX(1:NSEA)
WRITE(NDSR,ERR=803,IOSTAT=IERR) TAUOY(1:NSEA)
ENDIF
IF ( FLOGRR(6,3) ) &
WRITE(NDSR,ERR=803,IOSTAT=IERR) BHD(1:NSEA)