build.gradle

plugins {
    id 'java'
    id 'maven-publish'
    id 'net.minecraftforge.gradle' version '5.1.+'
    id 'com.github.johnrengelman.shadow' version '7.1.2'
}

group = 'io.github.steelwoolmc'
version = version + '+' + minecraft_version

java {
    withSourcesJar()
}

minecraft {
    mappings channel: 'official', version: minecraft_version
}

configurations {
    shadedImplementation { transitive = false }
    fabricMixin { transitive = false }
    implementation.extendsFrom(shadedImplementation, fabricMixin)
}

repositories {
    maven {
        name = 'Fabric'
        url = 'https://maven.fabricmc.net/'
    }
    maven {
        name = 'Sinytra'
        url = 'https://maven.su5ed.dev/releases/'
    }
    mavenLocal()
}

dependencies {
    minecraft "net.minecraftforge:forge:${minecraft_version}-${forge_version}"
    fabricMixin "org.sinytra:sponge-mixin:${mixin_version}"
}

jar {
    archiveClassifier = "slim"
}

shadowJar {
    from("licenses") {
        into "META-INF/"
    }
    from("LICENSE.txt") {
        into "META-INF/"
    }
    // Exclude dependency licenses since we include them ourselves
    exclude "**/LICENSE*"
    exclude "**/NOTICE*"
    exclude "META-INF/maven/**"
    exclude "META-INF/versions/**"

    archiveClassifier = "shadow"
    configurations = [project.configurations.shadedImplementation]
}

tasks.register("fullJar", org.gradle.jvm.tasks.Jar) {
    dependsOn(shadowJar)
    manifest.from(jar.manifest)
    from(zipTree(shadowJar.archiveFile))
    from(provider { configurations.fabricMixin.singleFile }) {
        rename { "fabric-mixin.jar" }
    }
    archiveClassifier = ""
}

assemble.dependsOn fullJar

// Replace published jar artifact with shadowJar 
configurations {
    [runtimeElements, apiElements].each {
        it.outgoing {
            artifacts.clear()
            artifact(fullJar)
        }
    }
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            from components.java
            // Remove forge dependency from pom, disable gradle module metadata
            fg.component it
        }
    }
    def ENV = System.getenv()
    if (ENV.MAVEN_URL) {
        repositories.maven {
            url ENV.MAVEN_URL
            if (ENV.MAVEN_USERNAME) {
                credentials {
                    username ENV.MAVEN_USERNAME
                    password ENV.MAVEN_PASSWORD
                }
            }
        }
    }
}