build.gradle

apply plugin: 'com.android.application'
// Realm support
apply plugin: 'realm-android'

android {
    compileSdkVersion 26
    buildToolsVersion '26.0.0'

    defaultConfig {
        applicationId "io.github.marktony.espresso"
        minSdkVersion 21
        targetSdkVersion 26
        versionCode 1
        versionName "1.0"
        testInstrumentationRunner "android.support.test.runner.AndroidJUnitRunner"
        multiDexEnabled true
    }

    buildTypes {
        release {
            minifyEnabled true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        debug {
            minifyEnabled false
            versionNameSuffix "debug"
        }
    }

    lintOptions {
        abortOnError false
    }

}

ext {
    supportLibVersion = '26.0.0-beta2'
    rxjavaVersion = '2.0.1'
    retrofitVersion = '2.2.0'
    zxingLibVersion = '3.3.0'
    datetimePickerVersion = '3.1.3'
    circleimageviewVersion = '2.1.0'
    espressoVersion = '2.2.2'
    runnerRulesVersion = '0.5'
    junitVersion = '4.12'
    mockitoVersion = '2.0.2-beta'
}

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')

    // Support libraries
    compile "com.android.support:appcompat-v7:$supportLibVersion"
    compile "com.android.support:support-v4:$supportLibVersion"
    compile "com.android.support:design:$supportLibVersion"
    compile "com.android.support:cardview-v7:$supportLibVersion"
    compile "com.android.support:preference-v14:$supportLibVersion"
    compile "com.android.support:customtabs:$supportLibVersion"

    // ReactiveX series
    compile "io.reactivex.rxjava2:rxjava:$rxjavaVersion"
    compile "io.reactivex.rxjava2:rxandroid:$rxjavaVersion"
    // Retrofit series
    compile "com.squareup.retrofit2:retrofit:$retrofitVersion"
    compile "com.squareup.retrofit2:adapter-rxjava2:$retrofitVersion"
    compile "com.squareup.retrofit2:converter-gson:$retrofitVersion"
    // Zxing
    compile "com.google.zxing:core:$zxingLibVersion"
    // Material date time picker
    compile("com.wdullaer:materialdatetimepicker:$datetimePickerVersion"){
        exclude group:'com.android.support'
    }
    // CircleImageView
    compile("de.hdodenhof:circleimageview:$circleimageviewVersion"){
        exclude group:'com.android.support'
    }

    testCompile "junit:junit:$junitVersion"

    // Espresso
    androidTestCompile "com.android.support:support-annotations:$supportLibVersion"
    androidTestCompile "com.android.support.test.espresso:espresso-core:$espressoVersion"
    androidTestCompile("com.android.support.test.espresso:espresso-contrib:$espressoVersion") {
        exclude group: 'com.android.support'
    }
    androidTestCompile("com.android.support.test.espresso:espresso-intents:$espressoVersion") {
        exclude group: 'com.android.support'
    }

    // Runner and rules
    androidTestCompile "com.android.support.test:runner:$runnerRulesVersion"
    androidTestCompile "com.android.support.test:rules:$runnerRulesVersion"
}