-
Notifications
You must be signed in to change notification settings - Fork 5
/
Copy pathchmsgsvc.prg
3808 lines (3212 loc) · 103 KB
/
chmsgsvc.prg
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
*
* Note: This is a modified version of MsgSvc tailored for ChilkatVFP.
* I needed a bit more than MsgSvc - the ability to translate the field
* to be converted is contained in public domain INTL.PRG, but it also
* brings much more than I needed.
*
* I added a somewhat kludgey 4th parameter to MsgSvc. That parameter
* will hold the ChilkatVFP object. For what it was worth, I coded
* it as backward compatibile as possible to MsgSvc but I haven't
* checked to see if it really worked.
*
* There's a new MsgSvc array property to hold the supported languages.
*
* The MsgSvc function has some code to support the new parameter
* and a variable to hold the language from the ChilkatVFP object.
*
* If the passed language is in the array, then the correct field is
* swapped into the SCATTER ARRAY loMsgSpec.cOriginal field,
* and everything gets processed as normal.
*
* The real work is done by the authors below, I'm just
* standing on the shoulders of giants. WAA 02/18/2024
*
* Program...........: MSGSVC.PRG
*************************************************************************
* Public Domain Edition
*************************************************************************
* Version...........: 7.03 August 4 2004
#DEFINE MSGSVCVERSION "7.03 August 4 2004"
* Latest Version....: Check http://www.stevenblack.com/SBCPublicDomain.asp
* Description.......: Central Square for Messages.
* Author............: Steven M. Black - email: [email protected]
* Special thanks to.: Albert Ballanger
* Art Bergquist
* Frank Cazabon
* Steve Dingle
* Mike and Toni Feltman
* Sebastien Fluke
* Kirsten Frießnegg
* Mark Giesen
* John Harbour
* Rick Hodder
* Dale Kiefling
* Ken Levy
* Andrew MacNeill
* Kevin McNeish
* Gene Pasquini
* Barbara Peisch
* Alan Schwartz
* Paul Slate
* Steve Smith
* Drew Speedie
* Trish Swift
* Anthony L. Testi
* John Vahlberg
* ...and many other great folks too.
*
*} Project...........: INTL
* Created...........: 09/22/93
* Copyright.........: None (Public Domain)
*)
*] Dependencies......: Assumes that if MsgSvc.DBF is open, it is
*] ORDER()'d properly
*
* Calling Samples
* Typical...: msgsvc( "Some Key Expression")
* : msgsvc( "This is a new message|This on line 2|This on line 3") (multiline)
* String Swaps...: msgvvc( "SomeKey", "Two~three~ain't bad"]
* Thermometer bar...: msgsvc( "in-bar message", "Therm", 30)
*
* Parameter List....: tcMessageKey
* txVariable
* tnHowFar
* Returns...........: Either Character, Numeric, or Logical depending
* on the cRetType field in MSGSVC.DBF
*
#DEFINE ccCr_Lf CHR( 13) + CHR( 10)
#DEFINE ccParseDelim "~"
#DEFINE ccTABLE "MsgSvc.DBF"
#DEFINE ccALIAS JUSTSTEM( ccTABLE) && See proc JUSTSTEM() below for pre-VFP 5 versions
#DEFINE cnSideMargin 18
#DEFINE ccForceTextReturn "((TEXT))"
* These define the delimiters for dynamic substitition
#DEFINE ccMERGEOPEN "{{"
#DEFINE ccMERGECLOSE "}}"
*==============================================================
* If your development language is NOT English, then modify
* the lines below and specify your own native language terms
* for OK, Cancel, Yes, No, etc...
#DEFINE ccOK "Ok"
#DEFINE ccCANCEL "Cancel"
#DEFINE ccABORT "Abort"
#DEFINE ccRETRY "Retry"
#DEFINE ccIGNORE "Ignore"
#DEFINE ccYES "Yes"
#DEFINE ccNO "No"
*-- Tip of the day localizations
#DEFINE ccDIDYOUKNOW "Did you know..."
#DEFINE ccSHOWTIPS "\<Show Tips at Startup"
#DEFINE ccHELP "\<Help"
#DEFINE ccMORETIPS "\<More Tips"
#DEFINE ccNEXTTIP "\<Next Tip..."
#DEFINE ccTOD "Tip Of The Day"
*-- This is new in Version 6: Default title is _SCREEN.Caption
#DEFINE ccDEFAULTDIALOGCAPTION _SCREEN.Caption
*-- Used to reckon system colors (new in Version 6)
#DEFINE COLOR_SCROLLBAR 0
#DEFINE COLOR_BACKGROUND 1
#DEFINE COLOR_ACTIVECAPTION 2
#DEFINE COLOR_INACTIVECAPTION 3
#DEFINE COLOR_MENU 4
#DEFINE COLOR_WINDOW 5
#DEFINE COLOR_WINDOWFRAME 6
#DEFINE COLOR_MENUTEXT 7
#DEFINE COLOR_WINDOWTEXT 8
#DEFINE COLOR_CAPTIONTEXT 9
#DEFINE COLOR_ACTIVEBORDER 10
#DEFINE COLOR_INACTIVEBORDER 11
#DEFINE COLOR_APPWORKSPACE 12
#DEFINE COLOR_HIGHLIGHT 13
#DEFINE COLOR_HIGHLIGHTTEXT 14
#DEFINE COLOR_BTNFACE 15
#DEFINE COLOR_BTNSHADOW 16
#DEFINE COLOR_GRAYTEXT 17
#DEFINE COLOR_BTNTEXT 18
#DEFINE COLOR_INACTIVECAPTIONTEXT 19
#DEFINE COLOR_BTNHIGHLIGHT 20
#DEFINE COLOR_3DDKSHADOW 21
#DEFINE COLOR_3DLIGHT 22
#DEFINE COLOR_INFOTEXT 23
#DEFINE COLOR_INFOBK 24
#DEFINE COLOR_DESKTOP COLOR_BACKGROUND
#DEFINE COLOR_3DFACE COLOR_BTNFACE
#DEFINE COLOR_3DSHADOW COLOR_BTNSHADOW
#DEFINE COLOR_3DHIGHLIGHT COLOR_BTNHIGHLIGHT
#DEFINE COLOR_3DHILIGHT COLOR_BTNHIGHLIGHT
#DEFINE COLOR_BTNHILIGHT COLOR_BTNHIGHLIGHT
*== E N T E R H E R E ========================================
LPARAMETERS txPara1, txPara2, txPara3, txPara4)
PRIVATE lcSystemFont, lxRetValm, loMsgSvc
** No fourth parameter (i.e. prior MsgSvc behavior) test
IF PCOUNT() < 4
lcSystemFont= GetSystemFont()
IF TYPE("_Screen.oMsgSvc")="U"
_SCREEN.AddObject("oMsgSvc", "cMsgSvc")
ENDIF
*-- Take Note! If there is a problem, we return .F.
IF TYPE("_Screen.oMsgSvc.Name")<> "C"
lxRetVal= .F.
ELSE
lxRetVal= _Screen.oMsgSvc.MsgSvc( txPara1, txPara2, txPara3)
IF ! _Screen.oMsgSvc.lPersist
_Screen.oMsgSvc.Release()
ENDIF
ENDIF
ELSE
lxRetVal = .F.
loMsgSvc = NEWOBJECT([cMsgSvc])
** Have an object test
IF TYPE([loMsgSvc.Name]) = [C]
lxRetVal = loMsgSvc.MsgSvc(txPara1, txPara2, txPara3, txPara4)
ENDIF TYPE([loMsgSvc.Name]) = [C]
** End have an object test
loMsgSvc = NULL
ENDIF PCOUNT() < 4
** End no fourth parameter (i.e. prior MsgSvc behavior) test
RETURN lxRetVal
*== E X I T H E R E ==========================================
*//////////////////////////////////////////////////////////////////////////////
* CLASS....: c A b s t r a c t D i r e c t o r
* Version..: February 27 1997
*-- Roles of the message "director"
*-- Created by client
*-- Creates/Maintains builders
*-- Notifies builders
*-- Retrieves results from builder and displays the result
*//////////////////////////////////////////////////////////////////////////////
DEFINE CLASS cAbstractDirector AS LightweightCustom
cDefaultBuilder = .NULL.
*-- Supported sorts of PROPER(message ID) and the dialog builder class
DIMENSION aBuilders[1,2]
aBuilders[1,1]= "Unknown Index"
aBuilders[1,2]= "Unknown Class"
*====================================
*-- cAbstractDirector::GetBuilder()
*====================================
* Retrieve items from the aBuilders array
*
FUNCTION GetBuilder( tcID)
IF ISNULL( tcID)
RETURN .NULL.
ENDIF
LOCAL lcFunction, lnHit, lcRetVal
lcRetVal= This.cDefaultBuilder
IF TYPE( "tcID") <> "C"
RETURN lcRetVal
ENDIF
tcID= tokennum(tcID,1)
lcFunction= PROPER( ALLTRIM( tcID))
lnHit= ASCAN( This.aBuilders, lcFunction)
IF lnHit> 0
RETURN This.aBuilders[ lnHit+1]
ELSE
lnHit= ASCAN( This.aBuilders, "Default")
IF lnHit> 0
RETURN This.aBuilders[ lnHit+1]
ELSE
RETURN lcRetVal
ENDIF
ENDIF
*====================================
*-- cAbstractDirector::SetBuilder
*====================================
* Add items to the aBuilders array
*
FUNCTION SetBuilder( tcID, tcClass)
IF ISNULL( tcID) OR ISNULL( tcClass)
RETURN .NULL.
ENDIF
LOCAL llRetVAal
llRetVal= .F.
IF EMPTY( tcID) OR ;
EMPTY( tcClass) OR ;
TYPE( "tcId") <> "C" OR ;
TYPE( "tcClass") <> "C"
RETURN llRetVal
ENDIF
llRetVal= .T.
LOCAL lnFound, lntemp
lnFound=ASCAN( This.aBuilders, tcID)
IF lnFound > 0
This.aBuilders( lnFound+1)= ALLTRIM(tcClass)
ELSE
lntemp= ALEN(This.aBuilders)
DIMENSION This.aBuilders[ lnTemp+ 2]
This.aBuilders[ lnTemp+ 1]= PROPER( tcID)
This.aBuilders[ lnTemp+ 2]= PROPER( tcClass)
ENDIF
RETURN llRetVal
*====================================
*-- cAbstractDirector::Release()
*====================================
* Release this object
*
FUNCTION RELEASE
Release THIS
ENDDEFINE
*//////////////////////////////////////////////////////////////////////////////
* CLASS....: c M e s s a g e D i r e c t o r
* Version..: March 31 1996
*//////////////////////////////////////////////////////////////////////////////
DEFINE CLASS cMessageDirector AS cAbstractDirector
cDefaultBuilder= "cDialogBuilder"
*-- The name of the message resource file.
cTable= ccTABLE
*-- The alias of the message resource file
cAlias= ccALIAS
*-- The index tag to make active
cTag= "cKey"
*-- Global switch for optional icon animation on slower systems.
*-- Set to .F. to disable all animation
lAnimateIcons= .T.
*-- The return value from the message or dialog we will build.
ReturnValue= ''
*-- Supported sorts of PROPER(message ID) and the dialog builder class
DIMENSION aBuilders[1,2]
aBuilders[1,1]= "Default"
aBuilders[1,2]= "cDialogBuilder"
*-- Array of currently active dialogs. Messages get put on this
*-- stack so more than one message can be up at one time.
DIMENSION aDialogs[1]
aDialogs[1]= .NULL.
*-- Do you want the director object to persist between hits?
lPersist= .T.
*-- Do you want the director object to update the MscSvc table when faced with new messages?
lUpdateTable= .T.
*-- For ChilkatVFP - property to hold the language to use for displays.
cLanguage = [cOriginal]
*-- For ChilkatVFP - Array to hold the supported languages (outside of "Original")
DIMENSION aLanguages[4,1]
aLanguages[1,1] = [French]
aLanguages[2,1] = [German]
aLanguages[3,1] = [Spanish]
aLanguages[4,1] = [Test]
*-- Abstract Methods of this class
FUNCTION GetDialogHandle(c)
FUNCTION MsgSvc( x1, x2, x3, x4)
FUNCTION OpenTable
FUNCTION CloseTable
*====================================
*-- cAbstractDirector::cdx_msgsvc()
*====================================
* Reindex the resource file.
*
FUNCTION cdx_msgsvc
LOCAL lnOldArea, lcOldError, lnError
lnError= 0
lcOldError= ON("Error")
ON ERROR lnError=1
lnOldArea = SELECT(0)
IF ! USED( This.cAlias)
USE (This.cTable) IN 0 EXCLUSIVE ALIAS (This.cAlias)
ELSE
SELECT ( This.cAlias)
ENDIF
IF lnError= 0
DELETE TAG ALL
INDEX ON UPPER( cKey) TAG (This.cTag)
ENDIF
SELECT (lnOldArea)
ON ERROR &lcOldError
RETURN lnError==0
*====================================
*-- cAbstractDirector::GetDialogHandle(c)
*====================================
* Retrieve the LIFO dialog of a given type
* from the dialog stack
*
FUNCTION GetDialogHandle( tcType)
LOCAL loRetVal, lnI
loRetVal= .NULL.
IF TYPE( "tcType")= "C"
FOR lnI= ALEN( This.aDialogs) TO 1 STEP -1
IF TYPE( "This.aDialogs[ lnI]") = "O" AND ;
! ISNULL( This.aDialogs[ lnI])
IF UPPER( ALLTRIM( This.aDialogs[ lni].Type))== UPPER( ALLTRIM( tcType))
loRetVal= This.aDialogs[ lni]
ENDIF
ENDIF
ENDFOR
ENDIF
RETURN loRetVal
*====================================
*-- cAbstractDirector::Init()
*====================================
*
FUNCTION INIT
*-- Used to reckon system colors
DECLARE INTEGER GetSysColor in User32.dll Integer
*-- Used to reckon fonts
DECLARE INTEGER SystemParametersInfo IN Win32API ;
INTEGER, INTEGER, STRING @, INTEGER
RETURN
*====================================
*-- cAbstractDirector::Destroy()
*====================================
*
FUNCTION Destroy
This.GarbageCollect()
DODEFAULT()
RETURN
*====================================
*-- cAbstractDirector::Release()
*====================================
*
FUNCTION Release()
This.GarbageCollect()
DODEFAULT()
RETURN
*====================================
*-- cAbstractDirector::Garbagecollect()
*====================================
*
FUNCTION GarbageCollect()
This.aDialogs= .NULL.
THIS.aLanguages = NULL
RETURN
ENDDEFINE
*//////////////////////////////////////////////////////////////////////////////
* CLASS....: c M s g S v c ( class cMessageDirector)
* : Concrete implementation of the abstract message director.
* Version..: March 31 1996
*//////////////////////////////////////////////////////////////////////////////
DEFINE CLASS cMsgSvc AS cMessageDirector
*-- Horizontal and vertical offsets
nOffsetHorizontal= 0
nOffsetVertical = 0
*===========================================
*-- cMsgSvc::CookieSwap(tcText,tcCookieText)
* (e.g. tcText = "almost done, %C1%")
* (e.g. tcCookieText = "Louise")
*===========================================
FUNCTION CookieSwap(tcText,tcCookieText)
LOCAL lcWorkPiece, lnNumToSwap, lcCounter, lcVariable
lcWorkPiece = tcText
DO CASE
CASE TYPE( [tcCookieText]) = [C]
*-- We may have more than one string to swap-in
lnNumToSwap = tokens( tcCookieText, ccParseDelim, .T.)
FOR lnCounter = 1 TO lnNumToSwap
lcCounter = STR(lnCounter,1)
*-- What's our variable "word"?
lcVariable = tokennum( tcCookieText, lnCounter, ccParseDelim, .T.)
*-- Accept n occurrences of %C% and %Cn% for first (perhaps only) swap
DO CASE
*-- uppercase
CASE [%C]+lcCounter+[%] $ lcWorkPiece
lcWorkPiece = STRTRANC( lcWorkPiece, ;
[%c]+lcCounter+[%], ;
lcVariable)
*-- lowercase
CASE [%c]+lcCounter+[%] $ lcWorkPiece
lcWorkPiece = STRTRANC( lcWorkPiece, ;
[%c]+lcCounter+[%], ;
lcVariable)
*-- uppercase
CASE "%C%" $ UPPER(lcWorkPiece)
lcWorkPiece = STRTRANC( lcWorkPiece, [%C%], lcVariable, 1)
*-- lowercase
CASE "%c%" $ UPPER(lcWorkPiece)
lcWorkPiece = STRTRANC( lcWorkPiece, [%c%], lcVariable, 1)
ENDCASE
ENDFOR
IF "%C" $ UPPER(lcWorkPiece)
*-- Here we've stripped all tokens except unfulfilled suffix ones. Cleanup.
FOR lnCounter = 1 TO 9
lcCounter = STR(lnCounter,1)
IF !"%C" $ UPPER(lcWorkPiece)
EXIT
ENDIF
DO CASE
*-- uppercase
CASE [%C]+lcCounter+[%] $ lcWorkPiece
lcWorkPiece = STRTRANC( lcWorkPiece, ;
[%c]+lcCounter+[%], '')
*-- lowercase
CASE [%c]+lcCounter+[%] $ lcWorkPiece
lcWorkPiece = STRTRANC( lcWorkPiece, ;
[%c]+lcCounter+[%], '')
*-- uppercase
CASE "%C%" $ UPPER(lcWorkPiece)
lcWorkPiece = STRTRANC( lcWorkPiece, [%C%], '' )
*-- lowercase
CASE "%c%" $ UPPER(lcWorkPiece)
lcWorkPiece = STRTRANC( lcWorkPiece, [%c%], '')
ENDCASE
ENDFOR
ENDIF
ENDCASE
RETURN lcWorkPiece
*===========================================
*-- cMsgSvc::Init()
*===========================================
FUNCTION INIT()
DoDefault()
*-- Stock builder ID's and builders
This.SetBuilder( "Default", "cDialogBuilder")
This.SetBuilder( "Ok", "cDialogBuilder")
This.SetBuilder( "Ync", "cDialogBuilder")
This.SetBuilder( "Nyc", "cDialogBuilder")
This.SetBuilder( "Ari", "cDialogBuilder")
This.SetBuilder( "Yn", "cDialogBuilder")
This.SetBuilder( "Ny", "cDialogBuilder")
This.SetBuilder( "Text", "cTextBuilder")
This.SetBuilder( "Oc", "cDialogBuilder")
This.SetBuilder( "Rc", "cDialogBuilder")
This.SetBuilder( "Cancel", "cDialogBuilder")
This.SetBuilder( "Therm", "cThermBuilder")
This.SetBuilder( "Wait", "cWaitWindBuilder")
This.SetBuilder( "Nowait", "cWaitWindBuilder")
This.SetBuilder( "Working", "cWorkingDialogBuilder")
This.SetBuilder( "Tip", "cTipBuilder")
*====================================
*-- cMsgSvc::MsgSvc
*====================================
* Workhorse function -- message "director"
*
* Interface notes (by type)
* CLL - Lookup in MsgSvc
*
* CCL - Lookup with cookie substitution
*
* CCN - Text substitution with thermometer update
*
* CNL - Lookup [IF therm THEN setPercent(n)
*
* NCC - Text substitution with thermometer update
*
* NLL - IF EXIST( Therm) THEN LIFO therm update
* ELSE QuickTherm+update
*
* NCL - IF EXIST( Therm )THEN LIFO therm/message update
* ELSE QuickTherm+update+message
*
* LLL - IF EXIST( Working) THEN LIFO Working.Release()
*
*
FUNCTION MsgSvc( txPassed1, txPassed2, txPassed3, txPassed4)
LOCAL ;
lcLangField, ;
lcRetVal, ;
llSwap, ;
lcFunction, ;
lcWaitTime, ;
llForceTextReturn, ;
llTherm, ;
llWaitWind, ;
llWorking, ;
loParameterPackage, ;
loSpecPackage, ;
loSetExact, ;
lcPTypes, ;
lnI, ;
lcI, ;
lxPassed1, ;
lxPassed2, ;
lxPassed3, ;
loDialog, ;
lxPassed4, ; && added for ChilkatVFP
lcLanguage && added for ChilkatVFP
lxPassed1= txPassed1
lxPassed2= txPassed2
lxPassed3= txPassed3
lxPassed4= txPassed4
*-- We release "working" dialogs with empty calls, like this: MsgSvc()
loDialog = This.GetDialogHandle("Working")
IF !ISNULL(loDialog) AND TYPE("lxPassed1")="L" AND ! lxPassed1
loDialog.Release()
ELSE
IF EMPTY(lxPassed1)
WAIT CLEAR && We may have a WAIT WINDOW UP
RETURN
ENDIF
ENDIF
loSetExact= CREATE("SetExact", "OFF")
*-- Process case where the call requests a
*-- text string returned rather than a dialog.
llForceTextReturn= .F.
IF TYPE( "lxPassed1")= "C" AND ;
ccForceTextReturn $ UPPER( lxPassed1)
llForceTextReturn= .T.
lxPassed1= STRTRAN(UPPER(lxPassed1), ccForceTextReturn)
ENDIF
*-- Create a spec package to pass around as a parameter
loSpecPackage= CREATE( "cPackage")
*-- Package the parameters
loParameterPackage= CREATE( "cPackage")
loSpecPackage.AddItem("Call parameters", loParameterPackage)
*-- Place the call parameters in the package
FOR lnI= 1 TO 3
lcI=STR( lnI,1)
loParameterPackage.AddItem( "Parameter"+lcI, lxPassed&lcI.)
ENDFOR
*-- loParameterPackage is already stored within loSpecPackage
*-- so delete it now... it's no longer needed.
loParameterPackage=.NULL.
lcPTypes= TYPE("lxPassed1")+ ;
TYPE("lxPassed2")+ ;
TYPE("lxPassed3")
*##########################################
* Parameter pre-processing and dispatching
*##########################################
LOCAL loDialog
DO CASE
*-- If there is a number in the call, assume we are
*-- dealing with a thermometer.
CASE "N" $ lcPTypes
*-- Assume a thermometer
llTherm= .T.
*-- Text substitution required?
IF (lcPTypes = "CCN") OR (lcPTypes = "NCC")
llSwap = .T.
ENDIF
*-- If the numeric value is non-zero, then update
*-- an existing therm.
LOCAL lcZeroPos
lcZeroPos= STR(AT("N", lcPTypes),1)
IF lxPassed&lcZeroPos > 0
*-- Is there a therm on the stack? If so,
*-- update it and we're done.
loDialog= This.GetDialogHandle("Therm")
IF ! ISNULL( loDialog)
LOCAL lnI, lcI, lxTest
*-- Due to predicate dependency on nPercent,
*-- process for percentage first
FOR lnI= 1 to 3
lcI= STR( lnI,1)
lxTest= lxPassed&lcI
IF TYPE( "lxtest")= "N"
loDialog.SetPercent( lxTest)
*-- ... which might kill loDialog...
EXIT
ENDIF
ENDFOR
LOCAL lxText
*-- Process for Text next
IF ! ISNULL( loDialog)
FOR lnI= 1 to 3
lcI= STR( lnI,1)
lxTest= lxPassed&lcI
IF TYPE( "lxtest")= "C"
IF !(UPPER( lxTest)=="THERM")
loDialog.SetText( lxTest)
ENDIF
ENDIF
ENDFOR
ENDIF
*-- Done
loSpecPackage.release( ) &&-- Added by Anthony L. Testi July-29-2004
RETURN
ENDIF
ENDIF
*-- If we get here, then we're talking of
*-- a new Dialog... Proceed as normal, except...
IF lcPTypes= "NLL"
lxPassed2= lxPassed1
lxPassed1= "Therm Default"
ENDIF
*-- Swap the order if the numeric is first
IF lcPTypes= "NC"
LOCAL lx
lx= lxPassed2
lxPassed2= lxPassed1
lxPassed1= lx
ENDIF
*-- Text substitution with thermometer
IF lcPTypes= "NCC"
lxPassed2= lxPassed3
ENDIF
*-- Embedded cookie swapping
CASE lcPTypes= "CC"
llSwap = .T.
CASE lcPTypes= "LLL"
*-- Dismissing a Working message
loDialog= This.GetDialogHandle("Working")
IF ! ISNULL( loDialog)
loDialog.Release( )
ENDIF
*-- A desired side effect, allowing msgsvc().
*-- Open resource table.
loSpecPackage.release( ) &&-- Added by Anthony L. Testi July-29-2004
RETURN This.OpenTable()
ENDCASE
*-- Open MsgSvc
IF ! This.OpenTable()
loSpecPackage.release( ) &&-- Added by Anthony L. Testi July-29-2004
RETURN ''
ENDIF
LOCAL lcOrig
lcOrig= lxPassed1
*-- Change to allow for Length
IF TYPE("lxPassed1")= "C"
LOCAL lcTestAlias
lcTestAlias= This.cAlias
lxPassed1= UPPER( LEFT( lxPassed1, LEN(&lcTestAlias..cKey)))
ENDIF
*-- Default return is blank string
lcRetVal= ''
*-- Seek the cookie in the table
IF NOT SEEK( lxPassed1, (This.cAlias))
IF EMPTY( lxPassed2)
lxPassed2= ''
ENDIF
IF This.lUpdateTable AND ok2insert( This.cAlias)
INSERT INTO (This.cAlias) ( cKey, cfunction, cOriginal) ;
VALUES ( lcOrig, ;
IIF(llTherm,"THERM","Ok"), ;
lcOrig)
ENDIF
ENDIF
*-- Scatter to an object
LOCAL loMsgSpec, lcOldAlias
lcOldAlias=Alias()
SELECT (This.cAlias)
SCATTER NAME loMsgSpec MEMO
loSpecPackage.AddItem( "Message spec", loMsgSpec)
IF ! EMPTY(lcOldAlias)
SELECT (lcOldAlias)
ENDIF
** ChilkatVFP object as fourth parameter test
IF TYPE([lxPassed4.Name]) == [C] ;
AND PEMSTATUS(lxPassed4, [cMsgSvcLanguage], 5)
m.lcLanguage = lxPassed4.cMsgSvcLanguage
** If the cMsgSvcLanguage is set to "Original", there's nothing to do.
** If it's set to one of the suppported languages, we'll swap that
** field into the loMsgSpec.cOriginal variable.
** Something to do test
IF NOT (EMPTY(m.lcLanguage) OR UPPER(m.lcLanguage) == [ORIGINAL])
** Matched on the supported languages test
IF ASCAN(THIS.aLanguages, m.lcLanguage, -1, -1, 1, 7) > 0
** Swap the field...
loMsgSpec.cOriginal = EVALUATE([loMsgSpec.c] + m.lcLanguage)
ENDIF ASCAN(THIS.aLanguages, m.lcLanguage, -1, -1, 1, 7) > 0
** End matched on the supported languages test
ENDIF NOT (EMPTY(m.lcLanguage) OR UPPER(m.lcLanguage) == [ORIGINAL])
** End something to do test
ENDIF TYPE([lxPassed4.Name]) == [C] ;
AND PEMSTATUS(lxPassed4, [cMsgSvcLanguage], 5)
** End ChilkatVFP object as fourth parameter test
loMsgSpec.cOriginal= MsgEvlTXT( loMsgSpec.cOriginal)
*-- Cookie substitution
IF llSwap
LOCAL lcWorkPiece
lcWorkPiece= loMsgSpec.cOriginal
*[eg] 12/11/1998 12:55:46 PM New function CookieSwap() called
lcWorkPiece = This.CookieSwap(lcWorkPiece,lxPassed2)
loMsgSpec.cOriginal= MsgEvlTXT(lcWorkPiece)
DO CASE
CASE TYPE( [lxPassed2]) = [N]
loMsgSpec.cOriginal = STRTRAN( loMsgSpec.cOriginal, [%N%], ALLTRIM( STR( lxPassed2)))
CASE TYPE( [lxPassed2]) = [D]
loMsgSpec.cOriginal = STRTRAN( loMsgSpec.cOriginal, [%D%], DTOC( lxPassed2))
ENDCASE
ENDIF
*-- A pipe symbol is akin to CR+LF
loMsgSpec.cOriginal = STRTRAN( loMsgSpec.cOriginal, "|", ccCr_Lf)
*-- Mangle the animation if globally required
IF !EMPTY(loMsgSpec.cGuiVisual) AND ;
! This.lAnimateIcons AND ;
ATC("Animate",loMsgSpec.cGuiVisual )> 0
loMsgSpec.cGuiVisual= LEFT(loMsgSpec.cGuiVisual, ;
ATC("Animate",loMsgSpec.cGuiVisual )-1)
ENDIF
*-- Pass Object to an appropriate builder
LOCAL loMsg, lcBuilderName, lcBuilderCookie
loMsg= .NULL.
lcBuilderCookie= MsgEvlTXT(loMsgSpec.cfunction)
*-- Hook for TEXT return values
IF UPPER( lcBuilderCookie)= "TEXT" OR ;
llForceTextReturn
loSpecPackage.release( ) &&-- Added by Anthony L. Testi July-29-2004
RETURN ALLTRIM( loMsgSpec.cOriginal)
ENDIF
lcBuilderName= This.GetBuilder( lcBuilderCookie)
loBuilder = CREATE( lcBuilderName)
************!!!!!!!!!!!!*****************
loBuilder.Build( @loMsg, loSpecPackage)
************!!!!!!!!!!!!*****************
*-- Place MessageObject in aDialogs array
IF !ISNULL( loMsg) AND TYPE( "loMsg")= "O"
LOCAL lnThisDialog
IF ALEN( This.aDialogs)= 1 AND ISNULL( This.aDialogs[1])
lnThisDialog= 1
ELSE
DIMENSION This.aDialogs( ALEN( This.aDialogs)+ 1)
lnThisDialog= ALEN( This.aDialogs)
ENDIF
This.aDialogs[ lnThisDialog]= loMsg
This.aDialogs[ lnThisDialog].oReturnPointer= THIS
LOCAL lcAlias
lcAlias= This.cAlias
IF EMPTY( &lcAlias..cRow + &lcAlias..cCol)
This.aDialogs[ lnThisDialog].AutoCenter= .T.
ENDIF
*-- Add Horizontal and Vertical Offset properties (Kevin McNeish request)
IF This.nOffsetHorizontal!=0 AND;
This.nOffsetVertical!=0
This.aDialogs[ lnThisDialog].TOP = This.aDialogs[ lnThisDialog].top+This.nOffsetHorizontal
This.aDialogs[ lnThisDialog].Left= This.aDialogs[ lnThisDialog].left+This.nOffsetVertical
This.aDialogs[ lnThisDialog].AutoCenter= .F.
ENDIF
*-------------------------------------------------------------------
*-- This next line of code brought here because SetFocus() is
*-- triggering premature visibility in VFP 5
loBuilder.SetButtonFocus( This.aDialogs[ lnThisDialog], @loSpecPackage)
*----------------------------------------------------------------
*-- Release unneeded object references
loBuilder.Release()
Release loMsgSpec
loSpecPackage.Release()
*-- With thanks to Gene Pasquini
IF upper(alltrim(&lcAlias..cBell)) = "Y"
?? chr(7)
ENDIF
This.aDialogs[ lnThisDialog].SHOW()
*-- IF the dialog was modal, it's gone
*-- so clean up the stack
LOCAL lnMaxDialog
lnMaxDialog= ALEN( This.aDialogs)
DO WHILE lnMaxDialog > 1 AND ISNULL( This.aDialogs[ lnMaxDialog])
lnMaxDialog= lnMaxDialog-1
DIMENSION This.aDialogs[ lnMaxDialog]
ENDDO
ELSE
loSpecPackage.release( ) &&-- Added by Anthony L. Testi July-29-2004
RETURN This.ReturnValue
ENDIF
RETURN IIF( lnThisDialog <= ALEN(This.aDialogs) AND ;
! ISNULL(This.aDialogs[lnThisDialog]) AND ;
TYPE( "This.aDialogs[lnThisDialog]")="O" , ;
This.aDialogs[lnThisDialog],;
This.ReturnValue)
*====================================
*-- cMsgSvc::CloseTable
*====================================
* Close the class's resource table
*
FUNCTION CloseTable
USE IN (This.cAlias)
RETURN
*====================================
*-- cMsgSvc::OpenTable
*====================================
* Open the class's resource table
*
FUNCTION OpenTable
LOCAL lcOldError, lnError
lcOldError= ON( "Error")
lnError= 0
ON ERROR lnError= -1
*-- make sure the table's open
IF ! USED( This.cAlias)
LOCAL lcTable
lcTable= LOCFILE( This.cTable, [DBF], [Where is ]+ This.cTable+[?] )
IF FILE(lcTable)
USE (lcTable) ORDER TAG (This.cTag) ALIAS (This.cAlias)IN 0
ELSE
WAIT WINDOW "No table selected!"
RETURN .F.
ENDIF
ENDIF
IF EMPTY( ORDER( This.cAlias))
SET ORDER TO TAG (This.cTag) IN (This.cAlias)
ENDIF
IF lnError= -1
WAIT WINDOW "Cannot open "+ This.cAlias+ " table!"
ENDIF
ON ERROR &lcOldError
RETURN USED( This.cAlias)
*====================================
*-- cMsgSvc::Version(n)
*====================================
* MsgSvc Version()
*
FUNCTION Version(n)
RETURN MSGSVCVERSION
ENDDEFINE
*//////////////////////////////////////////////////////////////////////////////
* CLASS....: S E T E X A C T
*//////////////////////////////////////////////////////////////////////////////
DEFINE CLASS SetExact AS Relation
cOldExact= .NULL.
*====================================
*-- SetExact::Init( c)
*====================================
* Save and set SET EXACT
*
FUNCTION Init( tcNew)
This.cOldExact= SET("Exact")
IF TYPE( "tcNew")= "C"
SET EXACT &tcNew
ENDIF
*====================================
*-- SetExact::Init( c)
*====================================
* Reset SET EXACT
*
FUNCTION Destroy
LOCAL lcString
lcString= This.cOldExact
SET EXACT &lcString