Copied code over from lric project.

Author: billota

src/kla.lfe

@@ -1,5 +1,44 @@
 (defmodule kla
   (export all))
 
-(defun my-adder (x y)
-  (+ x (+ y 1)))
+(defun -replace-dash (item)
+  (re:replace item "-" "_" '(global #(return list))))
+
+(defun replace-dash
+  ((item) (when (is_list item))
+    (-replace-dash item))
+  ((item) (when (is_atom item))
+    (list_to_atom (-replace-dash (atom_to_list item)))))
+
+(defun -append-integer (item integer)
+  (++ item (integer_to_list integer)))
+
+(defun append-integer
+  ((item integer) (when (is_list item))
+    (-append-integer item integer))
+  ((item integer) (when (is_atom item))
+    (list_to_atom (-append-integer (atom_to_list item) integer)))
+  ((item integer) (when (is_integer item))
+    (-append-integer (integer_to_list item) integer)))
+
+(defun make-args
+  ((arity) (when (== arity 0))
+    '())
+  ((arity)
+    (lists:map
+      (lambda (x)
+        (append-integer 'arg- x))
+      (lists:seq 1 arity))))
+
+(defun make-func
+  ((`(,lfe-func-name ,func-arity) mod)
+    (let ((erlang-func-name (replace-dash lfe-func-name))
+          (func-args (make-args func-arity)))
+      `(defun ,lfe-func-name ,func-args
+        (apply ',mod ',erlang-func-name (list ,@func-args))))))
+
+(defun make-funcs (func-list mod)
+  (lists:map
+    (lambda (x)
+      (make-func x mod))
+    func-list))

test/unit-kla-tests.lfe

@@ -1,12 +1,71 @@
 (defmodule unit-kla-tests
   (behaviour ltest-unit)
-  (export all)
-  (import
-    (from ltest
-      (check-failed-assert 2)
-      (check-wrong-assert-exception 2))))
+  (export all))
 
 (include-lib "ltest/include/ltest-macros.lfe")
 
-(deftest my-adder
-  (is-equal 4 (: kla my-adder 2 2)))
+(deftest -replace-dash
+  (is-equal "has_dash" (kla:-replace-dash "has-dash"))
+  (is-equal "has_underscore" (kla:-replace-dash "has_underscore"))
+  (is-equal "neither" (kla:-replace-dash "neither")))
+
+(deftest replace-dash-string
+  (is-equal "has_dash" (kla:replace-dash "has-dash"))
+  (is-equal "has_underscore" (kla:replace-dash "has_underscore"))
+  (is-equal "neither" (kla:replace-dash "neither")))
+
+(deftest replace-dash-atom
+  (is-equal 'has_dash (kla:replace-dash 'has-dash))
+  (is-equal 'has_underscore (kla:replace-dash 'has_underscore))
+  (is-equal 'neither (kla:replace-dash 'neither)))
+
+(deftest append-integer-string
+  (is-equal "a1" (kla:append-integer "a" 1))
+  (is-equal "abc1" (kla:append-integer "abc" 1))
+  (is-equal "abc100" (kla:append-integer "abc" 100))
+  (is-equal "abc1001" (kla:append-integer "abc" 1001))
+  (is-equal "abc1" (kla:append-integer "abc" 001)))
+
+(deftest append-integer-atom
+  (is-equal 'a1 (kla:append-integer 'a 1))
+  (is-equal 'abc1 (kla:append-integer 'abc 1))
+  (is-equal 'abc100 (kla:append-integer 'abc 100))
+  (is-equal 'abc1001 (kla:append-integer 'abc 1001))
+  (is-equal 'abc1 (kla:append-integer 'abc 001)))
+
+(deftest append-integer-integer
+  (is-equal "11" (kla:append-integer 1 1))
+  (is-equal "2001" (kla:append-integer 200 1))
+  (is-equal "200100" (kla:append-integer 200 100))
+  (is-equal "2001001" (kla:append-integer 200 1001))
+  (is-equal "21" (kla:append-integer 002 001)))
+
+(deftest make-args
+  (is-equal '() (kla:make-args 0))
+  (is-equal '(arg-1) (kla:make-args 1))
+  (is-equal '(arg-1 arg-2) (kla:make-args 2))
+  (is-equal '(arg-1 arg-2 arg-3 arg-4) (kla:make-args 4)))
+
+(deftest make-func
+  (is-equal
+    '(defun my-func-name ()
+      (apply 'mod-1 'my_func_name (list )))
+    (kla:make-func '(my-func-name 0) 'mod-1))
+  (is-equal
+    '(defun my-func-name (arg-1)
+      (apply 'mod-2 'my_func_name (list arg-1)))
+    (kla:make-func '(my-func-name 1) 'mod-2))
+  (is-equal
+    '(defun my-func-name (arg-1 arg-2)
+      (apply 'mod-3 'my_func_name (list arg-1 arg-2)))
+    (kla:make-func '(my-func-name 2) 'mod-3)))
+
+(deftest make-funcs
+  (is-equal
+    '((defun func-y ()
+        (apply 'my-mod 'func_y (list)))
+      (defun func-y (arg-1)
+        (apply 'my-mod 'func_y (list arg-1)))
+      (defun func-y (arg-1 arg-2)
+        (apply 'my-mod 'func_y (list arg-1 arg-2))))
+    (kla:make-funcs '((func-y 0) (func-y 1) (func-y 2)) 'my-mod)))