vimrc.symlink

syntax on

set laststatus=2
set noshowmode
set encoding=utf-8
" AirLine symbols
let g:airline_symbols = {}
let g:airline_left_sep = '▶'
let g:airline_right_sep = '◀'
let g:airline_symbols.linenr = '␤ '
let g:airline_symbols.branch = '⎇ '
" Control which sections get truncated and at what width
let g:airline#extensions#default#section_truncate_width = {
    \ 'b': 60,
    \ 'x': 70,
    \ 'y': 70,
    \ 'z': 40,
    \ }

set statusline+=%#warningmsg#
set statusline+=%{SyntasticStatuslineFlag()}
set statusline+=%*

" Pass some arguments to syntax_checkers
let g:syntastic_always_populate_loc_list = 1
let g:syntastic_check_on_wq = 0
let g:syntastic_check_on_open = 0
let g:syntastic_auto_loc_list = 1
let g:syntastic_haskell_checkers = ['hdevtools', 'hlint']
let g:syntastic_python_checkers = ['python3', 'flake8', 'pylint']
" https://github.com/vim-syntastic/syntastic/issues/1759#issuecomment-398639522
"let g:syntastic_go_checkers = ['golint', 'govet', 'gometalinter', 'gofmt']
"let g:syntastic_go_gometalinter_args = ['--disable-all', '--enable=errcheck']
let g:syntastic_c_gcc_args = ' -Wall -Wextra '
" https://github.com/fatih/vim-go/wiki/Tutorial#check-it
let g:go_metalinter_command = "golangci-lint"
let g:go_metalinter_enabled = ['errcheck', 'gosimple', 'govet', 'ineffassign', 'staticcheck', 'unused']
let g:go_metalinter_autosave = 1
let g:go_metalinter_deadline = "5s"

" Disable specific bundle
"let g:pathogen_disabled = ["syntastic"]
execute pathogen#infect()

set guifont=Source\ Code\ Pro
set t_Co=256
set background=dark
color molokai

set showcmd  " display incomplete commands
" Enabled file type detection and file-type specific plugins.
filetype plugin indent on

" Prefer ISO8859-7 over ISO8859-1:
set fileencodings-=latin1
set fileencodings+=greek
" Path setting for finding files
"
set path+=**,

" swap/backup files
set backupdir=~/.vim-tmp,~/.tmp,~/tmp,/var/tmp,/tmp
set directory=~/.vim-tmp,~/.tmp,~/tmp,/var/tmp,/tmp

" -----------------------------------------------------------------------------
"  Text Format
" -----------------------------------------------------------------------------
set noautoindent
" this enables visual wrapping
set wrap
" this turns off physical line wrapping (ie: auto insertion of newlines)
set textwidth=0
" no margin at the end of the line
set nolist " do not show $ at EOL
set wrapmargin=0
set softtabstop=2   " tab space
set tabstop=2
set shiftwidth=2
set expandtab
set nojoinspaces
set formatoptions+=n " support for numbered/bullet lists

function SetupWrapping()
  set textwidth=80
  "set linebreak
  set wrapmargin=1
  set formatoptions+=t
endfunction

" -----------------------------------------------------------------------------
"  User Interface
" -----------------------------------------------------------------------------
set showcmd
set wildmenu " way cooler command line mode completion
set wildmode=list:longest " complete like shell
set wildignore+=*.o,+=*.obj,+=*.bak,+=*.exe,+=*~,+=*.hi
set backspace=eol,start,indent " allow backspacing over everything in insert mode
set showmatch " brackets/braces that is
set mat=1 " duration to show matching brace (1/10 sec)
set scrolloff=3 " lines to always seeable when scrolling
set magic


" -----------------------------------------------------------------------------
"  Searching
" -----------------------------------------------------------------------------
set incsearch  " do incremental searching
set ignorecase " make this default, turn on case in search with /<search>\C/
" type small case will search case independent, type mixed case will use exact
set smartcase


" -----------------------------------------------------------------------------
"  Specail File Cases
" -----------------------------------------------------------------------------
if has("autocmd")
" FIXME: This is probably to much.. Maybe {python,yml}
  au Filetype * set indentkeys-=<:> indentkeys-=: indentkeys-=<-> indentkeys-=-
" In Makefiles, use real tabs, not tabs expanded to spaces
  au FileType {make,c,cpp,conf,go} set noexpandtab softtabstop=4 tabstop=4 shiftwidth=4

" Make sure all mardown files have the correct filetype set and setup wrapping
  au BufRead,BufNewFile *.{md,markdown,mdown,mkd,mkdn,txt,rst} setf markdown | call SetupWrapping()

" Treat JSON files like JavaScript
  au BufNewFile,BufRead *.json set ft=javascript

" make Python follow PEP8 ( http://www.python.org/dev/peps/pep-0008/ )
  au FileType python set expandtab softtabstop=2 tabstop=2 shiftwidth=2 textwidth=79

" yaml rules
  au FileType yaml set expandtab softtabstop=2 tabstop=2 shiftwidth=2

" bash rules
  au FileType sh set noexpandtab softtabstop=8 tabstop=8 shiftwidth=2

" rEST rules
  au FileType rst set expandtab softtabstop=3 tabstop=3 shiftwidth=3 spell

" Markdown rules
  au FileType md set expandtab softtabstop=3 tabstop=3 shiftwidth=3 spell

" Remember last location in file, but not for commit messages.
" see :help last-position-jump
  au BufReadPost * if &filetype !~ '^git\c' && line("'\"") > 0 && line("'\"") <= line("$")
    \| exe "normal! g`\"" | endif
endif


" -----------------------------------------------------------------------------
"  Mapping
" -----------------------------------------------------------------------------
"set langmap=ΑA,ΒB,ΨC,ΔD,ΕE,ΦF,ΓG,ΗH,ΙI,ΞJ,ΚK,ΛL,ΜM,ΝN,ΟO,ΠP,QQ,ΡR
"set langmap+=ΣS,ΤT,ΘU,ΩV,WW,ΧX,ΥY,ΖZ,αa,βb,ψc,δd,εe,φf,γg,ηh,ιi,ξj
"set langmap+=κk,λl,μm,νn,οo,πp,qq,ρr,σs,τt,θu,ωv,ςw,χx,υy,ζz

" setup mapleader
let mapleader=","

map <silent> bb :ToggleBookmark<CR>
map <silent> bn :NextBookmark<CR>
map <silent> bp :PreviousBookmark<CR>

" map - to end of line, _ to start
noremap - ^
noremap _ $

" Convenient command to see the difference between the current buffer and the
" file it was loaded from, thus the changes you made.
command! DiffOrig vert new | set bt=nofile | r # | 0d_ | diffthis
\ | wincmd p | diffthis

" Better way to enter command line (get rid of pointless shift)
" In order to :wq when in greek use ;ς; (qwq) or shift+;;+w+q
nnoremap ; :
"cnoremap ς w
"cnoremap ; q
"nnoremap ¨ :

"Go to first line in location list (useful for synstastic errors)
nnoremap <tab> :ll<CR>

"""---------------------
"""# New Movement Keys #
"""---------------------

"" normally nothing
noremap <C-k> 2<C-Y>
noremap <C-j> 2<C-E>

"""-------------------------------------
"""# File/Window/Buffer Managment Keys #
"""-------------------------------------

"" quick file browse mapping
map <Leader>e :e %:p:h<CR>
map <Leader>E :lcd %:p:h<CR>

"" new tab
""nmap <Leader>t :tabe %:p:h<CR>
nmap <Leader>T :tabe .<CR>
nmap <Leader>n :tabnew<CR>

"" Give tab cycling nicer keys (normally these just do same as j & k)
map <Leader><Tab> :tabnext<CR>
map <Leader><S-Tab> :tabprevious<CR>

"" close window
map <Leader>q :q<CR>
"" quit vim
map <Leader>Q :qall!<CR>


" -----------------------------------------------------------------------------
"  Whitespace
" -----------------------------------------------------------------------------

highlight ExtraWhitespace ctermbg=red guibg=red
match ExtraWhitespace /\s\+$/
autocmd BufWinEnter * match ExtraWhitespace /\s\+$/
autocmd InsertEnter * match ExtraWhitespace /\s\+\%#\@<!$/
autocmd InsertLeave * match ExtraWhitespace /\s\+$/
autocmd BufWinLeave * call clearmatches()

"Highlight more than 80 chars
au BufWinEnter * let w:m2=matchadd('ErrorMsg', '\%>80v.\+', -1)

function StripTrailingWhitespace()
  if !&binary && &filetype != 'diff'
    normal mz
    normal Hmy
    %s/\s\+$//e
    normal 'yz<CR>
    normal `z
  endif
endfunction


"autocmd BufWritePost *.py call Flake8()
autocmd Filetype gitcommit,mail set expandtab textwidth=72 spell
map j gj
map k gk
"map <space> /
map 0 ^

" Delete trailing white space on save, useful for Python and CoffeeScript ;)
func! DeleteTrailingWS()
  exe "normal mz"
  %s/\s\+$//ge
  exe "normal `z"
endfunc
autocmd BufWrite *.py :call DeleteTrailingWS()

" Toggle paste mode on and off
set pastetoggle=<leader><leader>
inoremap jk <Esc>
inoremap jj <Esc>
inoremap ξξ <Esc>

"vnoremap γ; gq

" Similar format with the date command
" # dimara, Mon Jan  5 20:15:11 EET 2015
nnoremap <Leader>d "=strftime("# dimara, %a %b %e %k:%M:%S %Z %Y")<CR>pA
inoremap <Leader>d <C-R>=strftime("# dimara, %a %b %e %k:%M:%S %Z %Y")<CR>

set spelllang=en,el
nnoremap <Leader>s :setlocal spell!<CR>
inoremap <Leader>s <C-o>:setlocal spell!<CR>

"Allow yank more than 50 line
set viminfo='20,<1000,s10,h

autocmd FileType mail set tw=72

"Spell auto correction
imap <c-f> <c-g>u<Esc>[s1z=`]a<c-g>u
nmap <c-f> [s1z=<c-o>

"Shortcut for using named buffer a
map <Leader>y "ayy<CR>
map <Leader>p "ap<CR>

" Macros to help with reviews
" See https://wiki.samba.org/index.php/CodeReview
let g:git_ci_msg_user = substitute(system("git config --get user.name"), '\n$', '', '')
let g:git_ci_msg_email = substitute(system("git config --get user.email"), '\n$', '', '')
nnoremap <Leader>r "=printf("Reviewed-by: %s <%s>", g:git_ci_msg_user, g:git_ci_msg_email)<CR>pA
inoremap <Leader>r <C-R>=printf("Reviewed-by: %s <%s>", g:git_ci_msg_user, g:git_ci_msg_email)<CR>

let g:date = substitute(system("date --rfc-3339=date"), '\n$', '', '')
nnoremap <Leader>c "=printf("%s  %s  <%s>", g:date, g:git_ci_msg_user, g:git_ci_msg_email)<CR>pA
inoremap <Leader>c <C-R>=printf("%s  %s  <%s>", g:date, g:git_ci_msg_user, g:git_ci_msg_email)<CR>

function XKBLayoutGetUS()
  call XKBLayoutBackup()
  let g:xkb_layout_cnt = system("xkblayout-state print %C")
  let c = 0
  while c < g:xkb_layout_cnt
    call system("xkblayout-state set " . c)
    call system("xkblayout-state print %s | grep us")
    if !v:shell_error
      let g:xkb_layout_num_us = c
      break
    endif
    let c += 1
  endwhile
  call XKBLayoutRestore()
endfunction

function XKBLayoutGetCurrent()
  let g:xkb_layout_num_current = system("xkblayout-state print %c")
  let g:xkb_layout_sym_current = system("xkblayout-state print %s")
endfunction

function XKBLayoutBackup()
  call XKBLayoutGetCurrent()
  let g:xkb_layout_num_backup = g:xkb_layout_num_current
  let g:xkb_layout_sym_backup = g:xkb_layout_sym_current
endfunction

function XKBLayoutSwitch()
  call XKBLayoutBackup()
  if exists("g:xkb_layout_num_us")
    call system("xkblayout-state set " . g:xkb_layout_num_us)
    echo "Switched to 'us' keyboard layout"
  endif
endfunction

function XKBLayoutRestore()
  call system("xkblayout-state set " . g:xkb_layout_num_backup)
  "echo "Switched to '" . g:xkb_layout_sym_current . "' keyboard layout"
endfunction

let g:current_display = $DISPLAY

if !empty(g:current_display) && executable("xkblayout-state")
  call XKBLayoutGetUS()
  autocmd InsertLeave * call XKBLayoutSwitch()
  autocmd InsertEnter * call XKBLayoutRestore()
endif

nnoremap ξξ :call XKBLayoutSwitch()<CR>

"Load .bashrc and make :! shell behave like our command prompts (i.e., with aliases)
"set shellcmdflag=-ic

set mouse=