Very poor GC memory utilization due to fragmentation

[dlangBugzillaToGithub]

Vladimir Panteleev (@CyberShadow) reported this on 2024-01-11T10:07:12Z

Transferred from https://issues.dlang.org/show_bug.cgi?id=24328

Description

This program seems to be able to utilize only 2% of memory available to it - the rest seems to be wasted by fragmentation:

///////////////////////////////// test.d ////////////////////////////////
import core.stdc.stdio;
import core.stdc.stdlib;

enum size_t memoryLimit = 1UL * 1024 * 1024 * 1024;
enum size_t allocationSize = 64;

void main()
{
    {
        import core.sys.posix.sys.resource :
            rlimit, RLIMIT_AS, getrlimit, setrlimit;
        rlimit lim;
        getrlimit(RLIMIT_AS, &lim);
        lim.rlim_cur = memoryLimit;
        setrlimit(RLIMIT_AS, &lim);
    }

    // Size of reachable data created by this function
    size_t utilizedSize;

    scope(exit) printf("Utilized size: %zu (%zd%%)
",
        utilizedSize, utilizedSize * 100 / memoryLimit);

    ubyte[][] pinned;
    int n;
    while (true)
    {
        ubyte[] arr;
        {
            scope(failure) printf("Failed to allocate %zu
",
                allocationSize);
            arr = new ubyte[allocationSize];
        }
        bool keep = n++ % 2 == 0;
        if (keep)
        {
            {
                scope(failure) printf("Failed to reallocate %zu bytes
",
                    (pinned.length + 1) * pinned[0].sizeof);
                pinned ~= arr;
            }
            utilizedSize += allocationSize + pinned[0].sizeof;
        }
    }
}
/////////////////////////////////////////////////////////////////////////

[dlangBugzillaToGithub]

dlang-bugzilla (@CyberShadow) commented on 2024-01-11T10:24:16Z

If I modify the program to use C malloc/free instead of the D GC, I get 81% utilization:

////////////////////////// test_c.d //////////////////////////
import core.stdc.stdio;
import core.stdc.stdlib;

enum size_t memoryLimit = 1UL * 1024 * 1024 * 1024;
enum size_t allocationSize = 64;

@nogc
void main()
{
    {
        import core.sys.posix.sys.resource :
            rlimit, RLIMIT_AS, getrlimit, setrlimit;
        rlimit lim;
        getrlimit(RLIMIT_AS, &lim);
        lim.rlim_cur = memoryLimit;
        setrlimit(RLIMIT_AS, &lim);
    }

    // Size of reachable data created by this function
    size_t utilizedSize;

    scope(exit) printf("Utilized size: %zu (%zd%%)\n",
        utilizedSize, utilizedSize * 100 / memoryLimit);

    void** pinned; size_t numPinned;
    int n;
    while (true)
    {
        void* arr = malloc(allocationSize);
        if (!arr)
        {
            printf("Failed to allocate %zu\n",
                allocationSize);
            return;
        }
        bool keep = n++ % 2 == 0;
        if (keep)
        {
            auto newSize = (numPinned + 1) * pinned[0].sizeof;
            pinned = cast(void**)realloc(pinned, newSize);
            if (!pinned)
            {
                printf("Failed to reallocate %zu bytes\n",
                    (numPinned + 1) * pinned[0].sizeof);
                return;
            }
            pinned[numPinned++] = arr;
            utilizedSize += allocationSize + pinned[0].sizeof;
        }
        else
            free(arr);
    }
}
//////////////////////////////////////////////////////////////