build.gradle

plugins {
    id 'java'
    id 'application'
    id 'org.javamodularity.moduleplugin' version '1.8.12'
    id 'org.openjfx.javafxplugin' version '0.0.13'
    id 'org.beryx.jlink' version '2.25.0'
    id 'com.github.node-gradle.node' version '7.1.0'
}

group 'com.example'
version '1.0-SNAPSHOT'

repositories {
    mavenCentral()
}

ext {
    junitVersion = '5.10.2'
}

sourceCompatibility = '21'
targetCompatibility = '21'

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8'
}

application {
    mainModule = 'com.example.templatesjavafx'
    mainClass = 'com.example.templatesjavafx.HelloApplication'
}

javafx {
    version = '17.0.6'
    modules = ['javafx.controls', 'javafx.fxml']
}

dependencies {

    testImplementation("org.junit.jupiter:junit-jupiter-api:${junitVersion}")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:${junitVersion}")
}

test {
    useJUnitPlatform()
}

jlink {
    imageZip = project.file("${buildDir}/distributions/app-${javafx.platform.classifier}.zip")
    options = ['--strip-debug', '--compress', '2', '--no-header-files', '--no-man-pages']
    launcher {
        name = 'app'
    }
}

jlinkZip {
    group = 'distribution'
}

node {
    nodeProjectDir = file("templates-react")
}

tasks.register('buildReactApp', NpmTask) {
    dependsOn npmInstall
    group = "build"
    description = "Builds the React application."
    args = ['run', 'build']

    // Specify the files to monitor for changes
    inputs.dir(file("templates-react")).withPropertyName("reactSource")
            .optional(false) // Ensure this directory must exist

    // Specify the output of the build
    outputs.dir(file("templates-react/dist")).withPropertyName("reactBuildOutput")
}

build.dependsOn('buildReactApp')

tasks.register('copyReactBuild', Copy) {
    group = "build"
    description = "Copies the React build output to the JavaFX resources folder."
    from file("templates-react/dist") // Default React output folder
    into file("src/main/resources/webapp") // Where JxBrowser can load it
}

buildReactApp.finalizedBy(copyReactBuild)

// FIXME: because `copyReactBuild` is copying to the resource folder
processResources.dependsOn('copyReactBuild')