-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathwwm_jacobi.F90
2840 lines (2793 loc) · 108 KB
/
wwm_jacobi.F90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#include "wwm_functions.h"
!**********************************************************************
!* *
!**********************************************************************
!AR:todo: code duplication ... and buggy since boundary pointer are not taken into account
SUBROUTINE COMPUTE_CFL_N_SCHEME_EXPLICIT(CFLadvgeoOutI)
USE DATAPOOL
IMPLICIT NONE
integer,intent(out) :: CFLadvgeoOutI(MNP)
REAL(rkind) C(2,MNP), KELEM(3,MNE)
REAL(rkind) KKSUM(MNP)
REAL(rkind) LAMBDA(2), KTMP(3)
integer I1, I2, I3
real(rkind) DTMAX_EXP
integer IE, IP, I, J, POS
integer IS, ID
REAL(rkind) :: CFLadvgeoOut(MNP)
CFLadvgeoOut=0
DO IS=1,NUMSIG
DO ID=1,NUMDIR
CALL CADVXY(IS,ID,C)
DO IE = 1, MNE
I1 = INE(1,IE)
I2 = INE(2,IE)
I3 = INE(3,IE)
LAMBDA(1) = ONESIXTH *(C(1,I1)+C(1,I2)+C(1,I3))
LAMBDA(2) = ONESIXTH *(C(2,I1)+C(2,I2)+C(2,I3))
KELEM(1,IE) = LAMBDA(1) * IEN(1,IE) + LAMBDA(2) * IEN(2,IE)
KELEM(2,IE) = LAMBDA(1) * IEN(3,IE) + LAMBDA(2) * IEN(4,IE)
KELEM(3,IE) = LAMBDA(1) * IEN(5,IE) + LAMBDA(2) * IEN(6,IE)
KTMP = KELEM(:,IE)
KELEM(:,IE) = MAX(ZERO,KTMP)
END DO
KKSUM = ZERO
J = 0
DO IP = 1, MNP
DO I = 1, CCON(IP)
J = J + 1
IE = IE_CELL(J)
POS = POS_CELL(J)
KKSUM(IP) = KKSUM(IP) + MAX(KELEM(POS,IE),ZERO)
END DO
END DO
DO IP=1,MNP
DTMAX_EXP = SI(IP)/MAX(THR,KKSUM(IP))
CFLadvgeoOut(IP) = MAX(CFLadvgeoOut(IP), DT4A / DTMAX_EXP)
END DO
END DO
END DO
#ifdef MPI_PARALL_GRID
CALL EXCHANGE_P2D(CFLadvgeoOut)
#endif
DO IP=1,MNP
CFLadvgeoOutI(IP) = NINT(CFLadvgeoOut(IP))
END DO
END SUBROUTINE
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE EIMPS_ASPAR_BLOCK(ASPAR)
USE DATAPOOL
IMPLICIT NONE
REAL(rkind), intent(out) :: ASPAR(NUMSIG, NUMDIR, NNZ)
INTEGER :: POS_TRICK(3,2)
REAL(rkind) :: FL11(NUMSIG,NUMDIR), FL12(NUMSIG,NUMDIR), FL21(NUMSIG,NUMDIR), FL22(NUMSIG,NUMDIR), FL31(NUMSIG,NUMDIR), FL32(NUMSIG,NUMDIR)
REAL(rkind) :: CRFS(NUMSIG,NUMDIR,3), K1(NUMSIG,NUMDIR), KM(NUMSIG,NUMDIR,3), K(NUMSIG,NUMDIR,3), TRIA03
REAL(rkind) :: CXY(2,NUMSIG,NUMDIR,3)
REAL(rkind) :: DIFRU, USOC, WVC
REAL(rkind) :: DELTAL(NUMSIG,NUMDIR,3)
REAL(rkind) :: KP(NUMSIG,NUMDIR,3), NM(NUMSIG,NUMDIR)
INTEGER :: I1, I2, I3
INTEGER :: IP, ID, IS, IE
INTEGER :: I, IPGL1
REAL(rkind) :: DTK(NUMSIG,NUMDIR), TMP3(NUMSIG,NUMDIR)
REAL(rkind) :: LAMBDA(2,NUMSIG,NUMDIR)
REAL(rkind) :: CXnorm
REAL(rkind) sumTMP3, sumCXY, sumCG, sumASPARdiag
REAL(rkind) DTeffect
POS_TRICK(1,1) = 2
POS_TRICK(1,2) = 3
POS_TRICK(2,1) = 3
POS_TRICK(2,2) = 1
POS_TRICK(3,1) = 1
POS_TRICK(3,2) = 2
!
! Calculate countour integral quantities ...
!
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'MNP=', MNP
WRITE(STAT%FHNDL,*) 'sum(IOBWB)=', sum(IOBWB)
WRITE(STAT%FHNDL,*) 'sum(IOBPD)=', sum(IOBPD)
WRITE(STAT%FHNDL,*) 'sum(IOBDP)=', sum(IOBDP)
WRITE(STAT%FHNDL,*) 'LSPHE=', LSPHE
sumTMP3=0
sumCXY=0
sumCG=0
#endif
IF (IMPL_GEOADVECT) THEN
DTeffect = DT4A
ELSE
DTeffect = ZERO
END IF
IF (LCFL) THEN
CFLCXY(1,:) = ZERO
CFLCXY(2,:) = ZERO
CFLCXY(3,:) = LARGE
END IF
ASPAR = 0.0_rkind ! Mass matrix ...
DO IE = 1, MNE
DO I=1,3
IP = INE(I,IE)
DO IS=1,NUMSIG
DO ID=1,NUMDIR
IF (LSECU .OR. LSTCU) THEN
CXY(1,IS,ID,I) = CG(IS,IP)*COSTH(ID)+CURTXY(IP,1)
CXY(2,IS,ID,I) = CG(IS,IP)*SINTH(ID)+CURTXY(IP,2)
ELSE
CXY(1,IS,ID,I) = CG(IS,IP)*COSTH(ID)
CXY(2,IS,ID,I) = CG(IS,IP)*SINTH(ID)
END IF
IF (LSPHE) THEN
CXY(1,IS,ID,I) = CXY(1,IS,ID,I)*INVSPHTRANS(IP,1)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I)*INVSPHTRANS(IP,2)
END IF
IF (LDIFR) THEN
CXY(1,IS,ID,I) = CXY(1,IS,ID,I)*DIFRM(IP)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I)*DIFRM(IP)
IF (LSECU .OR. LSTCU) THEN
IF (IDIFFR .GT. 1) THEN
WVC = SPSIG(IS)/WK(IS,IP)
USOC = (COSTH(ID)*CURTXY(IP,1) + SINTH(ID)*CURTXY(IP,2))/WVC
DIFRU = ONE + USOC * (ONE - DIFRM(IP))
ELSE
DIFRU = DIFRM(IP)
END IF
CXY(1,IS,ID,I) = CXY(1,IS,ID,I) + DIFRU*CURTXY(IP,1)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I) + DIFRU*CURTXY(IP,2)
END IF
END IF
IF (LCFL) THEN
CXnorm=SQRT(CXY(1,IS,ID,I)**2 + CXY(2,IS,ID,I)**2)
CFLCXY(1,IP) = MAX(CFLCXY(1,IP), CXnorm)
END IF
END DO
END DO
END DO
#ifdef DEBUG
sumCXY = sumCXY + sum(abs(CXY))
sumCG = sumCG + sum(abs(CG ))
#endif
LAMBDA(:,:,:) = ONESIXTH * (CXY(:,:,:,1) + CXY(:,:,:,2) + CXY(:,:,:,3))
K(:,:,1) = LAMBDA(1,:,:) * IEN(1,IE) + LAMBDA(2,:,:) * IEN(2,IE)
K(:,:,2) = LAMBDA(1,:,:) * IEN(3,IE) + LAMBDA(2,:,:) * IEN(4,IE)
K(:,:,3) = LAMBDA(1,:,:) * IEN(5,IE) + LAMBDA(2,:,:) * IEN(6,IE)
FL11(:,:) = CXY(1,:,:,2)*IEN(1,IE)+CXY(2,:,:,2)*IEN(2,IE)
FL12(:,:) = CXY(1,:,:,3)*IEN(1,IE)+CXY(2,:,:,3)*IEN(2,IE)
FL21(:,:) = CXY(1,:,:,3)*IEN(3,IE)+CXY(2,:,:,3)*IEN(4,IE)
FL22(:,:) = CXY(1,:,:,1)*IEN(3,IE)+CXY(2,:,:,1)*IEN(4,IE)
FL31(:,:) = CXY(1,:,:,1)*IEN(5,IE)+CXY(2,:,:,1)*IEN(6,IE)
FL32(:,:) = CXY(1,:,:,2)*IEN(5,IE)+CXY(2,:,:,2)*IEN(6,IE)
CRFS(:,:,1) = - ONESIXTH * (TWO *FL31(:,:) + FL32(:,:) + FL21(:,:) + TWO * FL22(:,:) )
CRFS(:,:,2) = - ONESIXTH * (TWO *FL32(:,:) + TWO * FL11(:,:) + FL12(:,:) + FL31(:,:) )
CRFS(:,:,3) = - ONESIXTH * (TWO *FL12(:,:) + TWO * FL21(:,:) + FL22(:,:) + FL11(:,:) )
KM = MIN(ZERO,K)
KP(:,:,:) = MAX(ZERO,K)
DELTAL(:,:,:) = CRFS(:,:,:)- KP(:,:,:)
NM(:,:)=ONE/MIN(-THR,KM(:,:,1) + KM(:,:,2) + KM(:,:,3))
TRIA03 = ONETHIRD * TRIA(IE)
DO I=1,3
IP=INE(I,IE)
I1=JA_IE(I,1,IE)
I2=JA_IE(I,2,IE)
I3=JA_IE(I,3,IE)
K1(:,:) = KP(:,:,I)
DO ID=1,NUMDIR
DTK(:,ID) = K1(:,ID) * DTeffect * IOBPD(ID,IP) * IOBWB(IP) * IOBDP(IP)
END DO
TMP3(:,:) = DTK(:,:) * NM(:,:)
#ifdef DEBUG
sumTMP3 = sumTMP3 + sum(abs(TMP3))
#endif
ASPAR(:,:,I1) = TRIA03+DTK(:,:)- TMP3(:,:) * DELTAL(:,:,I ) + ASPAR(:,:,I1)
ASPAR(:,:,I2) = - TMP3(:,:) * DELTAL(:,:,POS_TRICK(I,1)) + ASPAR(:,:,I2)
ASPAR(:,:,I3) = - TMP3(:,:) * DELTAL(:,:,POS_TRICK(I,2)) + ASPAR(:,:,I3)
END DO
END DO
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'sumTMP3=', sumTMP3
WRITE(STAT%FHNDL,*) 'sumCXY=', sumCXY
WRITE(STAT%FHNDL,*) 'sumCG=', sumCG
WRITE(STAT%FHNDL,*) 'LBCWA=', LBCWA
WRITE(STAT%FHNDL,*) 'LBCSP=', LBCSP
WRITE(STAT%FHNDL,*) 'IWBMNP=', IWBMNP
#endif
IF (LBCWA .OR. LBCSP) THEN
DO IP = 1, IWBMNP
IPGL1 = IWBNDLC(IP)
ASPAR(:,:,I_DIAG(IPGL1)) = SI(IPGL1) ! Set boundary on the diagonal
END DO
END IF
#ifdef DEBUG
sumASPARdiag=0
DO IP=1,MNP
sumASPARdiag = sumASPARdiag + sum(abs(ASPAR(:,:,I_DIAG(IP))))
END DO
WRITE(STAT%FHNDL,*) 'sumASPARdiag=', sumASPARdiag
#endif
END SUBROUTINE
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE ADD_FREQ_DIR_TO_ASPAR_COMP_CADS(ASPAR)
USE DATAPOOL
IMPLICIT NONE
REAL(rkind), intent(inout) :: ASPAR(NUMSIG,NUMDIR,NNZ)
REAL(rkind) :: TheVal, eFact
REAL(rkind) :: CASS(0:NUMSIG+1), CP_SIG(0:NUMSIG+1), CM_SIG(0:NUMSIG+1)
REAL(rkind) :: CAD(NUMSIG,NUMDIR), CAS(NUMSIG,NUMDIR)
REAL(rkind) :: CP_THE(NUMSIG,NUMDIR), CM_THE(NUMSIG,NUMDIR)
REAL(rkind) :: B_SIG(NUMSIG)
INTEGER :: IS, ID, IP
IF (REFRACTION_IMPL) THEN
DO IP=1,NP_RES
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LTHBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPTHETA(IP,CAD)
ELSE
CAD=ZERO
END IF
CP_THE = MAX(ZERO,CAD)
CM_THE = MIN(ZERO,CAD)
eFact=(DT4D/DDIR)*SI(IP)
CAD_THE(:,:,IP)=CAD
ASPAR(:,:,I_DIAG(IP)) = ASPAR(:,:,I_DIAG(IP)) + eFact * (CP_THE(:,:) - CM_THE(:,:))
END DO
END IF
IF (FREQ_SHIFT_IMPL) THEN
DO IP=1,NP_RES
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LSIGBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPSIGMA(IP,CAS)
ELSE
CAS=ZERO
END IF
CAS_SIG(:,:,IP)=CAS
eFact=DT4F*SI(IP)
DO ID = 1, NUMDIR
CASS(1:NUMSIG) = CAS(:,ID)
CASS(0) = 0.
CASS(NUMSIG+1) = CASS(NUMSIG)
CP_SIG = MAX(ZERO,CASS)
CM_SIG = MIN(ZERO,CASS)
! Now forming the tridiagonal system
DO IS=1,NUMSIG
B_SIG(IS)=eFact*(CP_SIG(IS)/DS_INCR(IS-1) - CM_SIG(IS) /DS_INCR(IS))
END DO
B_SIG(NUMSIG) = B_SIG(NUMSIG) + eFact*CM_SIG(NUMSIG+1)/DS_INCR(NUMSIG) * TAIL_ARR(5)
ASPAR(:,ID,I_DIAG(IP))=ASPAR(:,ID,I_DIAG(IP)) + B_SIG
END DO
END DO
END IF
END SUBROUTINE
!**********************************************************************
!* *
!* For the refraction, we use the Upwind implicit scheme
!* N^{n+1} = N^n + f(N^(n+1))
!* This solves the differential equation N'=f(N)
!*
!* Courant, R., Isaacson, E., and Rees, M. (1952). "On the Solution of
!* Nonlinear Hyperbolic Differential Equations by Finite Differences",
!* Comm. Pure Appl. Math., 5, 243–255.
!*
!* This gives
!*
!* (1) N_i^(n+1) = N_i^n + (delta t/delta x)
!* (u_(i+1)^n N_(i+1)^(n+1) - u_i^n N_i^(n+1)) if u_i^n > 0
!* (2) N_i^(n+1) = N_i^n + (delta t/delta x)
!* (u_i^n N_i^(n+1) - u_(i-1)^n N_(i-1)^(n+1)) if u_i^n < 0
!*
!* The notations for tridiagonal system are available from
!* http://en.wikipedia.org/wiki/Tridiagonal_matrix
!*
!* For frequency shifting, things are complicated:
!*
!* Boundary condition: For low frequency, energy disappear. For
!* high frequency, we prolongate the energy by using a parametrization
!* of the tail: TAIL_ARR(5).
!*
!* Grid: the gridsize is variable. DS_INCR(IS) is essentially defined
!* as DS_INCR(IS) = SPSIG(IS) - SPSIG(IS-1)
!* Therefore the system that needs to be resolved is for i=1,NUMSIG
!*
!* We write f_{n,+} = 1 if u_i^n > 0
!* 0 otherwise
!* We write f_{n,-} = 0 if u_i^n > 0
!* 1 otherwise
!* We write u_{i,n,+} = u_i f_{n,+} and similarly for other variables.
!*
!* If we continue like that then we eventually get a non-conservative
!* scheme. See below for details.
!*
!* N_i^(n+1) = N_i^n + (delta t) [
!* + { u_(i+1,n,+) N_(i+1)^(n+1) - u_(i,n,+) N_i^(n+1) }/DS_INCR_i+1
!* { u_(i,n,-) N_i^(n+1) - u_(i-1,n,-) N_(i-1)^(n+1) }/DS_INCR_i
!*
!* which after rewrites give us
!* N_i^n = N_i^(n+1) [1 + Delta t { u_(i,n,+)/DS_i+1
!* - u_(i,n,-)/DS_i } ]
!* + N_(i-1)^(n+1) [ Delta t { u_(i-1,n,-)/DS_i } ]
!* + N_(i+1)^(n+1) [ Delta t { -u_(i+1,n,+)/DS_(i+1) } ]
!*
!* Instead, we set u_{i,n,+} = u_{i,+} = max(u_i, 0)
!* u_{i,n,-} = u_{i,-} = min(u_i, 0)
!* and the equations become simpler:
!* N_i^n = N_i^(n+1) [1 + Delta t { u_(i,+)/DS_i+1
!* - u_(i,-)/DS_i } ]
!* + N_(i-1)^(n+1) [ Delta t { u_(i-1,-)/DS_i } ]
!* + N_(i+1)^(n+1) [ Delta t { -u_(i+1,+)/DS_(i+1) } ]
!*
!* The boundary conditions are expressed as
!* N_0^{n+1}=0 and N_{NUMSIG+1}^{n+1} = N_{NUMSIG}^{n+1} TAIL_ARR(5)
!*
!*
!**********************************************************************
SUBROUTINE GET_FREQ_DIR_CONTRIBUTION(IP, ASPAR_DIAG, A_THE, C_THE, A_SIG, C_SIG)
USE DATAPOOL
IMPLICIT NONE
REAL(rkind), intent(inout) :: ASPAR_DIAG(NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: A_THE(NUMSIG,NUMDIR), C_THE(NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: A_SIG(NUMSIG,NUMDIR), C_SIG(NUMSIG,NUMDIR)
REAL(rkind) :: TheVal, eFact
REAL(rkind) :: CP_SIG, CM_SIG
REAL(rkind) :: CP_SIG_ip1, CM_SIG_im1
REAL(rkind) :: FP, FM
REAL(rkind) :: CAD(NUMSIG,NUMDIR), CAS(NUMSIG,NUMDIR)
REAL(rkind) :: CP_THE(NUMSIG,NUMDIR), CM_THE(NUMSIG,NUMDIR)
REAL(rkind) :: B_SIG(NUMSIG)
INTEGER :: ID1, ID2, IS, ID, IP
IF (REFRACTION_IMPL) THEN
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LTHBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPTHETA(IP,CAD)
ELSE
CAD=ZERO
END IF
CP_THE = MAX(ZERO,CAD)
CM_THE = MIN(ZERO,CAD)
eFact=(DT4D/DDIR)*SI(IP)
DO ID=1,NUMDIR
ID1 = ID_PREV(ID)
ID2 = ID_NEXT(ID)
A_THE(:,ID) = - eFact * CP_THE(:,ID1)
C_THE(:,ID) = eFact * CM_THE(:,ID2)
END DO
ASPAR_DIAG=ASPAR_DIAG + eFact * (CP_THE(:,:) - CM_THE(:,:))
END IF
IF (FREQ_SHIFT_IMPL) THEN
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LSIGBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPSIGMA(IP,CAS)
ELSE
CAS=ZERO
END IF
eFact=DT4F*SI(IP)
DO ID = 1, NUMDIR
DO IS=1,NUMSIG
IF (CAS(IS,ID) .gt. 0) THEN
FP=ONE
FM=ZERO
ELSE
FP=ZERO
FM=ONE
END IF
CP_SIG=CAS(IS,ID) * FP
CM_SIG=CAS(IS,ID) * FM
B_SIG(IS)=eFact*(CP_SIG/DS_INCR(IS+1) - CM_SIG/DS_INCR(IS))
IF (IS .eq. NUMSIG) THEN
CP_SIG_ip1=CAS(NUMSIG,ID)*FP*TAIL_ARR(5)
B_SIG(NUMSIG)=B_SIG(NUMSIG) - eFact*CP_SIG_ip1/DS_INCR(IS)
END IF
IF (IS .gt. 1) THEN
CM_SIG_im1=CAS(IS-1,ID)*FM
A_SIG(IS,ID)=eFact*CM_SIG_im1/DS_INCR(IS)
END IF
IF (IS .lt. NUMSIG) THEN
CP_SIG_ip1=CAS(IS+1,ID)*FP
C_SIG(IS,ID)=-eFact*CP_SIG_ip1/DS_INCR(IS+1)
END IF
END DO
ASPAR_DIAG(:,ID)=ASPAR_DIAG(:,ID) + B_SIG
END DO
END IF
END SUBROUTINE
!**********************************************************************
!* *
!**********************************************************************
#ifdef NCDF
SUBROUTINE DEBUG_EIMPS_TOTAL_JACOBI(iPass, iIter, FieldOut1)
USE DATAPOOL
USE NETCDF
IMPLICIT NONE
INTEGER, intent(in) :: iPass, iIter
REAL(rkind), intent(in) :: FieldOut1(MNP)
character (len = *), parameter :: CallFct="DEBUG_EIMPS_TOTAL_JACOBI"
REAL(rkind) :: FieldOutTotal1(np_total)
REAL(rkind), allocatable :: ARRAY_loc(:)
character(len=256) :: FileSave
REAL(rkind) eTimeDay
integer ncid, iret, nbTime, mnp_dims, ntime_dims, var_id
integer fifteen_dims
integer IP, IPloc, IPglob, NP_RESloc
integer iProc
integer, allocatable :: ListFirstMNP(:)
WRITE(FileSave, 10) 'DebugJacobi', iPass
10 FORMAT(a, '_', i4.4,'.nc')
# ifdef MPI_PARALL_GRID
IF (myrank .eq. 0) THEN
allocate(ListFirstMNP(nproc), stat=istat)
IF (istat/=0) CALL WWM_ABORT('wwm_jacobi, allocate error 1')
ListFirstMNP=0
DO iProc=2,nproc
ListFirstMNP(iProc)=ListFirstMNP(iProc-1) + ListMNP(iProc-1)
END DO
DO IP=1,NP_RES
IPglob=iplg(IP)
FieldOutTotal1(IPglob)=FieldOut1(IP)
END DO
DO iPROC=2,nproc
NP_RESloc=ListNP_RES(iPROC)
allocate(ARRAY_loc(NP_RESloc), stat=istat)
IF (istat/=0) CALL WWM_ABORT('wwm_jacobi, allocate error 2')
!
CALL MPI_RECV(ARRAY_loc, NP_RESloc, rtype, iProc-1, 511, comm, istatus, ierr)
DO IPloc=1,NP_RESloc
IPglob=ListIPLG(IPloc + ListFirstMNP(iProc))
FieldOutTotal1(IPglob)=ARRAY_loc(IPloc)
END DO
deallocate(ARRAY_loc)
END DO
deallocate(ListFirstMNP)
ELSE
CALL MPI_SEND(FieldOut1, NP_RES, rtype, 0, 511, comm, ierr)
END IF
# else
FieldOutTotal1 = FieldOut1
# endif
!
! Now writing to netcdf file
!
# ifdef MPI_PARALL_GRID
IF (myrank .eq. 0) THEN
# endif
IF (iIter .eq. 1) THEN
iret = nf90_create(TRIM(FileSave), NF90_CLOBBER, ncid)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 1, iret)
!
iret = nf90_def_dim(ncid, 'fifteen', 15, fifteen_dims)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 2, iret)
!
nbTime=0
CALL WRITE_NETCDF_TIME_HEADER(ncid, nbTime, ntime_dims)
!
iret = nf90_def_dim(ncid, 'mnp', np_total, mnp_dims)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 3, iret)
!
iret=nf90_def_var(ncid,"FieldOut1",NF90_RUNTYPE,(/ mnp_dims, ntime_dims/),var_id)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 4, iret)
!
iret = nf90_close(ncid)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 5, iret)
END IF
!
! Writing data
!
iret = nf90_open(TRIM(FileSave), NF90_WRITE, ncid)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 6, iret)
!
eTimeDay = MAIN%BMJD + MyREAL(iIter-1)*MyREAL(3600)/MyREAL(86400)
CALL WRITE_NETCDF_TIME(ncid, iIter, eTimeDay)
!
iret=nf90_inq_varid(ncid, "FieldOut1", var_id)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 7, iret)
!
iret=nf90_put_var(ncid,var_id,FieldOutTotal1,start=(/1, iIter/), count=(/ np_total, 1 /))
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 8, iret)
!
iret = nf90_close(ncid)
CALL GENERIC_NETCDF_ERROR_WWM(CallFct, 9, iret)
# ifdef MPI_PARALL_GRID
END IF
# endif
END SUBROUTINE DEBUG_EIMPS_TOTAL_JACOBI
#endif
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE EIMPS_TOTAL_JACOBI_ITERATION
USE DATAPOOL
IMPLICIT NONE
REAL(rkind) :: MaxNorm, SumNorm, p_is_converged
REAL(rkind) :: eSum(NUMSIG,NUMDIR)
REAL(rkind) :: BSIDE(NUMSIG,NUMDIR), DIAG(NUMSIG,NUMDIR)
REAL(rkind) :: WALOC(NUMSIG,NUMDIR)
REAL(rkind) :: CAD(NUMSIG,NUMDIR), CAS(NUMSIG,NUMDIR)
REAL(rkind) :: BLOC(NUMSIG,NUMDIR)
REAL(rkind) :: ASPAR_DIAG(NUMSIG,NUMDIR)
REAL(rkind) :: SSLIM(NUMSIG,NUMDIR), SSBRL(NUMSIG,NUMDIR)
LOGICAL :: test=.true., LCONVERGED(MNP)
REAL(rkind) :: ASPAR_LOC(NUMSIG,NUMDIR,MAX_DEG), MAXDAC(NUMSIG)
#ifdef DEBUG_ITERATION_LOOP
integer iIter
integer, save :: iPass = 0
REAL(rkind) :: FieldOut1(MNP)
#endif
#ifdef TIMINGS
REAL(rkind) :: TIME1, TIME2, TIME3, TIME4, TIME5
#endif
REAL(rkind) :: eFact
REAL(rkind) :: Sum_new, DiffNew
INTEGER :: IP, J, idx, nbIter, is_converged(1), itmp(1)
INTEGER :: JDX
LOGICAL, SAVE :: InitCFLadvgeo = .FALSE.
integer nbPassive
#ifdef DEBUG
REAL(rkind) sumESUM
#endif
IF (PrintLOG) THEN
WRITE(STAT%FHNDL,*) 'LCALC=', LCALC
WRITE(STAT%FHNDL,*) 'SOURCE_IMPL=', SOURCE_IMPL
WRITE(STAT%FHNDL,*) 'LNONL=', LNONL
WRITE(STAT%FHNDL,*) 'REFRACTION_IMPL=', REFRACTION_IMPL
WRITE(STAT%FHNDL,*) 'FREQ_SHIFT_IMPL=', FREQ_SHIFT_IMPL
END IF
IF (WAE_JGS_CFL_LIM) THEN
IF (InitCFLadvgeo .eqv. .FALSE.) THEN
allocate(CFLadvgeoI(MNP), NumberOperationJGS(MNP), stat=istat)
IF (istat/=0) CALL WWM_ABORT('wwm_jacobi, allocate error 3')
END IF
InitCFLadvgeo=.TRUE.
NumberOperationJGS = 0
IF (LCALC) THEN
CALL COMPUTE_CFL_N_SCHEME_EXPLICIT(CFLadvgeoI)
END IF
END IF
#ifdef DEBUG
CALL LOCAL_NODE_PRINT(20506, "Before Jacobi iteration")
#endif
#ifdef TIMINGS
CALL WAV_MY_WTIME(TIME1)
#endif
p_is_converged=0
IF (ASPAR_LOCAL_LEVEL .le. 1) THEN
CALL EIMPS_ASPAR_BLOCK(ASPAR_JAC)
END IF
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'sum(abs(ASPAR_JAC))=', sum(abs(ASPAR_JAC))
WRITE(STAT%FHNDL,*) 'sum( ASPAR_JAC )=', sum(ASPAR_JAC)
#endif
IF ((ASPAR_LOCAL_LEVEL .ge. 5).and.(ASPAR_LOCAL_LEVEL .le. 7)) THEN
CALL COMPUTE_K_CRFS_XYU
END IF
#ifdef TIMINGS
CALL WAV_MY_WTIME(TIME2)
#endif
!
IF (ASPAR_LOCAL_LEVEL .eq. 0) THEN
CALL ADD_FREQ_DIR_TO_ASPAR_COMP_CADS(ASPAR_JAC)
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'Aft/Refr/Freq sum(abs(ASPAR_JAC))=', sum(abs(ASPAR_JAC))
WRITE(STAT%FHNDL,*) 'Aft/Refr/Freq sum( ASPAR_JAC )=', sum(ASPAR_JAC)
#endif
END IF
IF (ASPAR_LOCAL_LEVEL .le. 1) THEN
IF ((.NOT. LNONL) .AND. SOURCE_IMPL) THEN
DO IP = 1, NP_RES
CALL GET_BSIDE_DIAG(IP, AC2, AC2, BSIDE, DIAG, BLOC)
ASPAR_JAC(:,:,I_DIAG(IP)) = ASPAR_JAC(:,:,I_DIAG(IP)) + DIAG
B_JAC(:,:,IP) = BSIDE + BLOC
ENDDO
END IF
END IF
#ifdef TIMINGS
CALL WAV_MY_WTIME(TIME3)
#endif
NumberIterationSolver = 0
nbIter=0
LCONVERGED = .FALSE.
DO
is_converged(1) = 0
JDX=0
#ifdef DEBUG_ITERATION_LOOP
FieldOut1 = 0
#endif
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'Before iteration sum(AC2)=', sum(abs(AC2))
sumESUM=0
#endif
nbPassive = 0
DO IP=1,NP_RES
IF (IOBDP(IP) .EQ. 0 .OR. LCONVERGED(IP)) THEN
is_converged(1) = is_converged(1) + 1
cycle
END IF
WALOC = AC2(:,:,IP)
IF (WAE_JGS_CFL_LIM) THEN
IF (NumberOperationJGS(IP) .lt. CFLadvgeoI(IP)) THEN
test=.TRUE.
ELSE
test=.FALSE.
END IF
END IF
IF (.true.) THEN
! WRITE(STAT%FHNDL,*) 'IP=', IP
NumberIterationSolver(IP) = NumberIterationSolver(IP) + 1
CALL SINGLE_VERTEX_COMPUTATION(JDX, WALOC, eSum, ASPAR_DIAG)
#ifdef DEBUG
sumESUM = sumESUM + sum(abs(eSum))
#endif
eSum=eSum/ASPAR_DIAG
IF (BLOCK_GAUSS_SEIDEL) THEN
AC2(:,:,IP) = eSum
ELSE
U_JACOBI(:,:,IP) = eSum
END IF
IF (JGS_CHKCONV) THEN
Sum_new = sum(eSum)
if (Sum_new .gt. thr8) then
DiffNew = sum(abs(WALOC - eSum))
p_is_converged = DiffNew/Sum_new
else
p_is_converged = zero
endif
#ifdef DEBUG_ITERATION_LOOP
FieldOut1(IP)=p_is_converged
#endif
! WRITE(STAT%FHNDL,*) 'p_is_converged=', p_is_converged
IF (IPstatus(IP) .eq. 1) THEN
IF (p_is_converged .LT. jgs_diff_solverthr) THEN
!write(*,*) ip, p_is_converged, jgs_diff_solverthr
LCONVERGED(IP) = .TRUE.
is_converged(1) = is_converged(1) + 1
IF (WAE_JGS_CFL_LIM) THEN
NumberOperationJGS(IP) = NumberOperationJGS(IP) +1
END IF
ENDIF
END IF
END IF!JGS_CHKCONV
ELSE!test
nbPassive = nbPassive + 1
IF (JGS_CHKCONV .and. (IPstatus(IP) .eq. 1)) THEN
is_converged(1) = is_converged(1) + 1
END IF
END IF!test
END DO!IP
! WRITE(*,*) SIZE(LCONVERGED), COUNT(LCONVERGED .eqv. .TRUE.)
#ifdef DEBUG
WRITE(STAT%FHNDL,*) 'sumESUM=', sumESUM
#endif
! WRITE(STAT%FHNDL,*) 'is_converged(1)=', is_converged(1)
! WRITE(STAT%FHNDL,*) 'NP_RES=', NP_RES
! WRITE(STAT%FHNDL,*) 'nbPassive=', nbPassive
! WRITE(STAT%FHNDL,*) 'diffconv=', NP_RES - is_converged(1)
IF (JGS_CHKCONV) THEN
#ifdef MPI_PARALL_GRID
CALL MPI_ALLREDUCE(is_converged, itmp(1), 1, itype, MPI_SUM, COMM, ierr)
is_converged = itmp
#endif
p_is_converged = (real(np_total) - real(is_converged(1)))/real(np_total) * 100.
ENDIF
#ifdef MPI_PARALL_GRID
IF (BLOCK_GAUSS_SEIDEL) THEN
CALL EXCHANGE_P4D_WWM(AC2)
ELSE
CALL EXCHANGE_P4D_WWM(U_JACOBI)
END IF
#endif
IF (.NOT. BLOCK_GAUSS_SEIDEL) THEN
AC2 = U_JACOBI
ENDIF
#ifdef DEBUG
WRITE(STAT%FHNDL,*) ' After iteration sum(AC2)=', sum(abs(AC2))
#endif
#ifdef DEBUG
iIter=nbIter + 1
# ifdef NCDF
CALL DEBUG_EIMPS_TOTAL_JACOBI(iPass, iIter, FieldOut1)
# endif
#endif
!
! The termination criterions several can be chosen
!
IF (PrintLOG) THEN
!DO IP = 1, NP_RES
! IF (.not. LCONVERGED(IP)) THEN
! WRITE(*,*) IP, LCONVERGED(IP)
! ENDIF
!ENDDO
WRITE(STAT%FHNDL,'(A10,4I10,2F10.5)') 'solver', nbiter, nbPassive, is_converged(1), np_total-is_converged(1), p_is_converged, pmin
END IF
!
! Number of iterations. If too large the exit.
!
nbIter=nbIter+1
IF (nbiter .eq. maxiter) THEN
EXIT
ENDIF
!
! Check via number of converged points
!
IF (JGS_CHKCONV) THEN
IF (p_is_converged .le. pmin) EXIT
ENDIF
!
! Check via the norm
!
IF (L_SOLVER_NORM) THEN
CALL COMPUTE_JACOBI_SOLVER_ERROR(MaxNorm, SumNorm)
IF (sqrt(SumNorm) .le. WAE_SOLVERTHR) THEN
EXIT
END IF
END IF
END DO
IF (PrintLOG) THEN
WRITE(STAT%FHNDL,*) 'nbIter=', nbIter
END IF
#ifdef DEBUG
CALL LOCAL_NODE_PRINT(20506, "After Jacobi Iteration")
#endif
#ifdef TIMINGS
CALL WAV_MY_WTIME(TIME4)
#endif
AC2 = MAX(ZERO, AC2) ! Make sure there is no negative energy left ...
#ifdef TIMINGS
CALL WAV_MY_WTIME(TIME5)
#endif
#ifdef TIMINGS
# ifdef MPI_PARALL_GRID
IF (myrank == 0) THEN
# endif
WRITE(STAT%FHNDL,'("+TRACE...",A,F15.6)') 'PREPROCESSING SOURCES AND ADVECTION ', TIME2-TIME1
WRITE(STAT%FHNDL,'("+TRACE...",A,F15.6)') 'PREPROCESSING REFRACTION ', TIME3-TIME2
WRITE(STAT%FHNDL,'("+TRACE...",A,F15.6)') 'ITERATION ', TIME4-TIME3
WRITE(STAT%FHNDL,'("+TRACE...",A,F15.6)') 'STORE RESULT ', TIME5-TIME4
FLUSH(STAT%FHNDL)
# ifdef MPI_PARALL_GRID
ENDIF
# endif
#endif
#ifdef DEBUG_ITERATION_LOOP
iPass=iPass+1
#endif
CONTAINS
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE GET_BSIDE_DIAG(IP, ACin1, ACin2, BSIDE, DIAG, BLOC)
IMPLICIT NONE
INTEGER, intent(in) :: IP
REAL(rkind), intent(in) :: ACin1(NUMSIG,NUMDIR,MNP)
REAL(rkind), intent(in) :: ACin2(NUMSIG,NUMDIR,MNP)
REAL(rkind), intent(out) :: BSIDE(NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: DIAG (NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: BLOC(NUMSIG,NUMDIR)
REAL(rkind) :: PHI(NUMSIG,NUMDIR)
REAL(rkind) :: DPHIDN(NUMSIG,NUMDIR)
REAL(rkind) :: eVal
REAL(rkind) :: ePHI, TheFactor, DVS1, DVS2
REAL(rkind) :: DAM(NUMSIG), MAXDAC, eDAM
REAL(rkind) :: DELFL(NUMSIG), eFric, USFM
INTEGER IS, ID
PHI=ZERO
DPHIDN=ZERO
IF (LNONL) THEN
CALL SOURCES_IMPLICIT
ELSE
DPHIDN = DPHIDNA(:,:,IP)
PHI = PHIA(:,:,IP)
END IF
eVal = SI(IP) * DT4A
CALL GET_BLOCAL(IP, ACin1, BLOC)
!
BSIDE = eVal * (PHI - MIN(ZERO,DPHIDN) * Acin2(:,:,IP))
DIAG = - eVal * MIN(ZERO,DPHIDN) ! AR: The minus put the DHPIDN on the left side of the equation as diagonal contributions with the right sign ... it inverts the sign ... however this is wrong now for IBREAK = 2 the SWAN stuff
#ifdef DEBUG_SOURCE_TERM
WRITE(STAT%FHNDL,'(I10,10G20.10,A40)') IP, SUM(ACin1), SUM(ACin2), SUM(PHI), SUM(DPHIDN), SUM(BSIDE), SUM(DIAG), SUM(BLOC), eval, 'GET_BSIDE_DIAG'
#endif
END SUBROUTINE
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE GET_BLOCAL(IP, Ac1in, BLOC)
IMPLICIT NONE
INTEGER, INTENT(IN) :: IP
REAL(rkind), intent(in) :: AC1in(NUMSIG,NUMDIR,MNP)
REAL(rkind), INTENT(OUT) :: BLOC(NUMSIG,NUMDIR)
INTEGER ID, idx
idx=IWBNDLC_REV(IP)
IF ((LBCWA .OR. LBCSP).and.(idx.gt.0)) THEN
BLOC = WBAC(:,:,idx) * SI(IP)
ELSE
DO ID=1,NUMDIR
BLOC(:,ID) = Ac1in(:,ID,IP) * IOBPD(ID,IP)*IOBWB(IP)*IOBDP(IP)*SI(IP)
ENDDO
END IF
END SUBROUTINE
!**********************************************************************
!* *
!**********************************************************************
SUBROUTINE LINEAR_ASPAR_LOCAL(IP, ASPAR_LOC, ASPAR_DIAG, A_THE, C_THE, A_SIG, C_SIG)
IMPLICIT NONE
INTEGER, intent(in) :: IP
REAL(rkind), intent(out) :: ASPAR_LOC(NUMSIG,NUMDIR,MAX_DEG)
REAL(rkind), intent(out) :: ASPAR_DIAG(NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: A_THE(NUMSIG,NUMDIR), C_THE(NUMSIG,NUMDIR)
REAL(rkind), intent(out) :: A_SIG(NUMSIG,NUMDIR), C_SIG(NUMSIG,NUMDIR)
INTEGER :: POS_TRICK(3,2)
REAL(rkind) :: FL11(NUMSIG,NUMDIR), FL12(NUMSIG,NUMDIR), FL21(NUMSIG,NUMDIR), FL22(NUMSIG,NUMDIR), FL31(NUMSIG,NUMDIR), FL32(NUMSIG,NUMDIR)
REAL(rkind) :: CRFS(NUMSIG,NUMDIR,3), K1(NUMSIG,NUMDIR), KM(NUMSIG,NUMDIR,3), K(NUMSIG,NUMDIR,3), TRIA03
REAL(rkind) :: CXY(2,NUMSIG,NUMDIR,3)
REAL(rkind) :: DIFRU, USOC, WVC
REAL(rkind) :: DELTAL(NUMSIG,NUMDIR,3)
REAL(rkind) :: KP(NUMSIG,NUMDIR,3), NM(NUMSIG,NUMDIR)
REAL(rkind) :: DTK(NUMSIG,NUMDIR), TMP3(NUMSIG,NUMDIR)
REAL(rkind) :: LAMBDA(2,NUMSIG,NUMDIR)
INTEGER :: I1, I2, I3
INTEGER :: ID, IS, IE, IPOS
INTEGER :: I, ICON
INTEGER :: IP_fall, IPie, TheVal
INTEGER :: ID1, ID2, POS1, POS2
REAL(rkind) :: CAD(NUMSIG,NUMDIR)
REAL(rkind) :: CAS(NUMSIG,NUMDIR)
REAL(rkind) :: CP_THE(NUMSIG,NUMDIR), CM_THE(NUMSIG,NUMDIR)
REAL(rkind) :: CASS(0:NUMSIG+1), B_SIG(NUMSIG)
REAL(rkind) :: CP_SIG(0:NUMSIG+1), CM_SIG(0:NUMSIG+1)
REAL(rkind) :: eFact
POS_TRICK(1,1) = 2
POS_TRICK(1,2) = 3
POS_TRICK(2,1) = 3
POS_TRICK(2,2) = 1
POS_TRICK(3,1) = 1
POS_TRICK(3,2) = 2
ASPAR_LOC=ZERO
ASPAR_DIAG=ZERO
DO ICON = 1, CCON(IP)
IE = IE_CELL2(IP,ICON)
IPOS = POS_CELL2(IP,ICON)
I1 = INE(1,IE)
I2 = INE(2,IE)
I3 = INE(3,IE)
DO I=1,3
IPie = INE(I,IE)
DO ID=1,NUMDIR
DO IS=1,NUMSIG
IF (LSECU .OR. LSTCU) THEN
CXY(1,IS,ID,I) = CG(IS,IPie)*COSTH(ID)+CURTXY(IPie,1)
CXY(2,IS,ID,I) = CG(IS,IPie)*SINTH(ID)+CURTXY(IPie,2)
ELSE
CXY(1,IS,ID,I) = CG(IS,IPie)*COSTH(ID)
CXY(2,IS,ID,I) = CG(IS,IPie)*SINTH(ID)
END IF
IF (LSPHE) THEN
CXY(1,IS,ID,I) = CXY(1,IS,ID,I)*INVSPHTRANS(IPie,1)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I)*INVSPHTRANS(IPie,2)
END IF
IF (LDIFR) THEN
CXY(1,IS,ID,I) = CXY(1,IS,ID,I)*DIFRM(IPie)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I)*DIFRM(IPie)
IF (LSECU .OR. LSTCU) THEN
IF (IDIFFR .GT. 1) THEN
WVC = SPSIG(IS)/WK(IS,IPie)
USOC = (COSTH(ID)*CURTXY(IPie,1) + SINTH(ID)*CURTXY(IPie,2))/WVC
DIFRU = ONE + USOC * (ONE - DIFRM(IPie))
ELSE
DIFRU = DIFRM(IPie)
END IF
CXY(1,IS,ID,I) = CXY(1,IS,ID,I) + DIFRU*CURTXY(IPie,1)
CXY(2,IS,ID,I) = CXY(2,IS,ID,I) + DIFRU*CURTXY(IPie,2)
END IF
END IF
END DO
END DO
END DO
LAMBDA(:,:,:) = ONESIXTH * (CXY(:,:,:,1) + CXY(:,:,:,2) + CXY(:,:,:,3))
K(:,:,1) = LAMBDA(1,:,:) * IEN(1,IE) + LAMBDA(2,:,:) * IEN(2,IE)
K(:,:,2) = LAMBDA(1,:,:) * IEN(3,IE) + LAMBDA(2,:,:) * IEN(4,IE)
K(:,:,3) = LAMBDA(1,:,:) * IEN(5,IE) + LAMBDA(2,:,:) * IEN(6,IE)
FL11(:,:) = CXY(1,:,:,2)*IEN(1,IE)+CXY(2,:,:,2)*IEN(2,IE)
FL12(:,:) = CXY(1,:,:,3)*IEN(1,IE)+CXY(2,:,:,3)*IEN(2,IE)
FL21(:,:) = CXY(1,:,:,3)*IEN(3,IE)+CXY(2,:,:,3)*IEN(4,IE)
FL22(:,:) = CXY(1,:,:,1)*IEN(3,IE)+CXY(2,:,:,1)*IEN(4,IE)
FL31(:,:) = CXY(1,:,:,1)*IEN(5,IE)+CXY(2,:,:,1)*IEN(6,IE)
FL32(:,:) = CXY(1,:,:,2)*IEN(5,IE)+CXY(2,:,:,2)*IEN(6,IE)
CRFS(:,:,1) = - ONESIXTH * (TWO *FL31(:,:) + FL32(:,:) + FL21(:,:) + TWO * FL22(:,:) )
CRFS(:,:,2) = - ONESIXTH * (TWO *FL32(:,:) + TWO * FL11(:,:) + FL12(:,:) + FL31(:,:) )
CRFS(:,:,3) = - ONESIXTH * (TWO *FL12(:,:) + TWO * FL21(:,:) + FL22(:,:) + FL11(:,:) )
KM = MIN(ZERO,K)
KP(:,:,:) = MAX(ZERO,K)
DELTAL(:,:,:) = CRFS(:,:,:) - KP(:,:,:)
NM(:,:)=ONE/MIN(-THR,KM(:,:,1) + KM(:,:,2) + KM(:,:,3))
TRIA03 = ONETHIRD * TRIA(IE)
!
IP_fall=INE(IPOS,IE)
IF (IP_fall .ne. IP) THEN
CALL WWM_ABORT('Bugs and many more bugs')
END IF
POS1=POS_IP_ADJ(1,IPOS,IE)
POS2=POS_IP_ADJ(2,IPOS,IE)
! I1=JA_IE(IPOS,1,IE)
! I2=JA_IE(IPOS,2,IE)
! I3=JA_IE(IPOS,3,IE)
K1(:,:) = KP(:,:,IPOS)
DO ID=1,NUMDIR
DTK(:,ID) = K1(:,ID) * DT4A * IOBPD(ID,IP) * IOBWB(IP) * IOBDP(IP)
END DO
TMP3(:,:) = DTK(:,:) * NM(:,:)
ASPAR_DIAG=ASPAR_DIAG + TRIA03+DTK(:,:)- TMP3(:,:) * DELTAL(:,:,IPOS)
ASPAR_LOC(:,:,POS1)=ASPAR_LOC(:,:,POS1)-TMP3(:,:)*DELTAL(:,:,POS_TRICK(IPOS,1))
ASPAR_LOC(:,:,POS2)=ASPAR_LOC(:,:,POS2)-TMP3(:,:)*DELTAL(:,:,POS_TRICK(IPOS,2))
END DO
IF (REFRACTION_IMPL) THEN
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LTHBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPTHETA(IP,CAD)
ELSE
CAD=ZERO
END IF
CP_THE = MAX(ZERO,CAD)
CM_THE = MIN(ZERO,CAD)
eFact=(DT4D/DDIR)*SI(IP)
DO ID=1,NUMDIR
ID1 = ID_PREV(ID)
ID2 = ID_NEXT(ID)
A_THE(:,ID) = - eFact * CP_THE(:,ID1)
C_THE(:,ID) = eFact * CM_THE(:,ID2)
END DO
ASPAR_DIAG = ASPAR_DIAG + eFact * (CP_THE(:,:) - CM_THE(:,:))
ELSE
A_THE=ZERO
C_THE=ZERO
END IF
IF (FREQ_SHIFT_IMPL) THEN
TheVal=1
IF ((ABS(IOBP(IP)) .EQ. 1 .OR. ABS(IOBP(IP)) .EQ. 3) .AND. .NOT. LSIGBOUND) TheVal=0
IF (DEP(IP) .LT. DMIN) TheVal=0
IF (IOBP(IP) .EQ. 2) TheVal=0
IF (TheVal .eq. 1) THEN
CALL PROPSIGMA(IP,CAS)
ELSE
CAS=ZERO
END IF
eFact=DT4F*SI(IP)
DO ID = 1, NUMDIR
CASS(1:NUMSIG) = CAS(:,ID)
CASS(0) = 0.
CASS(NUMSIG+1) = CASS(NUMSIG)
CP_SIG = MAX(ZERO,CASS)
CM_SIG = MIN(ZERO,CASS)
DO IS=1,NUMSIG