-
Notifications
You must be signed in to change notification settings - Fork 3
/
Copy pathRGB-SS-Shadebobs.bat
114 lines (86 loc) · 5.03 KB
/
RGB-SS-Shadebobs.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
@rem Use with "Screen Launcher": http://www.softpedia.com/get/Desktop-Enhancements/Screensavers/Screen-Launcher.shtml
@echo off
cd /D "%~dp0"
if defined __ goto :START
cmdwiz setfont 2
mode 80,50 & cmdwiz showmousecursor 0 & cmdwiz fullscreen 1
if %ERRORLEVEL% lss 0 set TOP=U
cmdwiz showcursor 0 & cmdwiz setmousecursorpos 10000 100
cmdwiz getdisplaydim w
set /a W=%errorlevel%/8+1
cmdwiz getdisplaydim h
set /a H=%errorlevel%/8+1
set /a WWW=W*3
set __=.
cmdgfx_input.exe m0nW16xR | call %0 %* | cmdgfx_RGB "" %TOP%Sf2:0,0,%W%,%H%t4
set __=
cls
cmdwiz fullscreen 0 & cmdwiz setfont 6 & cmdwiz showcursor 1 & mode 80,50
goto :eof
:START
setlocal ENABLEDELAYEDEXPANSION
for /F "tokens=1 delims==" %%v in ('set') do if not "%%v"=="W" if not "%%v"=="H" set "%%v="
call sindef.bat
set /a WWW=W*3, W150=W+30, W200=W+80
set /a DL=0, DR=0, KEY=0, COL=0, SIZE=2, KD=0, MODE=1, YMID=75/2, XMID=120/2, XMUL=110/3, YMUL=55/2, XMUL2=110/4, YMUL2=55/4, SWCNT=0, DRWMODE=17
set DRAW=""&set STOP=&set OUTP=&set OUTP2=
set PAL0=00??=0???,10??=40b0,20??=40b2,30??=40db,40??=c4b0,50??=c4b1,60??=c4b2,70??=c4db,80??=ecb0,90??=ecb2,a0??=ecdb,b0??=feb0,c0??=feb2,d0??=7fb1,e0??=87b1,f0??=80b1
set PAL1=00??=0???,10??=10b0,20??=10b2,30??=10db,40??=91b0,50??=91b2,60??=91db,70??=b9b0,80??=b9b2,90??=b9db,a0??=fbb0,b0??=fbb2,c0??=fbdb,d0??=efb1,e0??=ecb1,f0??=c8b2
set PAL2=00??=0???,10??=50b0,20??=50b2,30??=50db,40??=d5b0,50??=d5b1,60??=d5b2,70??=d5db,80??=d5db,90??=7db0,a0??=7db2,b0??=f7b0,c0??=f7b2,d0??=afb1,e0??=2ab0,f0??=2ab2
:: a circle shape
set /a "MX0=0, MY0=7, MX1=3, MY1=7, MX2=6, MY2=5, MX3=7, MY3=2, MX4=7, MY4=-2, MX5=6, MY5=-5, MX6=4, MY6=-7, MX7=0, MY7=-8"
set /a "MX8=-3, MY8=-8, MX9=-6, MY9=-6, MX10=-8, MY10=-3, MX11=-8, MY11=0, MX12=-7, MY12=3, MX13=-5, MY13=6, MX14=-2, MY14=7"
set /a P1=4,P2=3,P3=-2,P4=-1, SC=285,CC=-30,SC2=-295,CC2=-113
set /a "XMID=W/2, YMID=H/2, HLPY=H-3, HLPX=W/2-102/2, W150=W+30, W200=W+80, XMUL=(W-20)/4, YMUL=(H-20)/3, XMUL2=(W-30)/4, YMUL2=(H-20)/4"
set /a NOFSB=3, TIMEOUT=4000
set t1=!time: =0!
set FG1=000002&set BG1=010002&set FG2=000200&set BG2=000102&set FG3=020000&set BG3=020001
echo "cmdgfx: fbox 0 0 A"
:LOOP
for /L %%1 in (1,1,300) do if not defined STOP for %%c in (!COL!) do (
echo "cmdgfx: !DRAW:~1,-1!" Ff2:0,0,!W!,!H!
set /p INPUT=
for /f "tokens=1,2,4,6, 8,10,12,14,16,18,20,22, 24,26,28" %%A in ("!INPUT!") do ( set EV_BASE=%%A & set /a K_EVENT=%%B, K_DOWN=%%C, KEY=%%D, MOUSE_EVENT=%%E 2>nul )
if !KEY! == 112 set /a KEY=0 & cmdwiz getch
if !KEY! neq 0 set STOP=1
if !MOUSE_EVENT! neq 0 set STOP=1
set DRAW=""
for /F "tokens=1-8 delims=:.," %%a in ("!t1!:!time: =0!") do set /a "a=((((1%%e-1%%a)*60)+1%%f-1%%b)*6000+1%%g%%h-1%%c%%d)*10,a+=(a>>31)&8640000"
if !a! geq !TIMEOUT! (
set /a "SIZE=2, RS=!RANDOM! %% 4, BS=!RANDOM! %% 9, NOFSB=2 + !RANDOM! %% 2, TIMEOUT=3500+!RANDOM! %% 1500"
call :GETCOLORS
rem set /a RS=3
if !DRWMODE!==19 set /a RS=0
if !RS! lss 3 echo "cmdgfx: fbox 0 0 !CHAR!"& set /a "OLDCOL=COL, COL=!RANDOM! %% 3, DRWMODE=17" & if !COL!==!OLDCOL! set /a "COL=!RANDOM! %% 3"
if !RS! == 3 set /a DRWMODE=19
if !BS! == 8 set /a SIZE=3
set t1=!time: =0!
)
set DRAW=""
for /l %%c in (1,1,2) do (
set /a "SC+=!P1!, CC+=!P2!, SC2+=!P3!, CC2+=!P4!, RAND=!RANDOM! %% 1000"
if !RAND! lss 100 set /a SC2+=1
if !RAND! gtr 900 set /a CC-=1
if !RAND! gtr 500 if !RAND! lss 600 set /a SC+=1
for %%a in (!SC!) do for %%b in (!CC!) do for %%d in (!SC2!) do for %%e in (!CC2!) do set /a A1=%%a,A2=%%b,A3=%%d,A4=%%e & set /a "XPOS=!XMID!+(%SINE(x):x=!A1!*31416/180%*!XMUL!>>!SHR!)+(%SINE(x):x=!A4!*31416/180%*!XMUL2!>>!SHR!), YPOS=!YMID!+(%SINE(x):x=!A2!*31416/180%*!YMUL!>>!SHR!)+(%SINE(x):x=!A3!*31416/180%*!YMUL2!>>!SHR!)"
for %%a in (!SC!) do for %%b in (!CC!) do for %%d in (!SC2!) do for %%e in (!CC2!) do set /a A1=%%a,A2=%%b,A3=%%d,A4=%%e & set /a "XPOS2=!XMID!+(%SINE(x):x=!A3!*31416/180%*!YMUL!>>!SHR!)+(%SINE(x):x=!A2!*31416/180%*!XMUL2!>>!SHR!), YPOS2=!YMID!+(%SINE(x):x=!A4!*31416/180%*!XMUL!>>!SHR!)+(%SINE(x):x=!A1!*31416/180%*!YMUL2!>>!SHR!)"
for /L %%a in (0,1,14) do set /a "MXP=!MX%%a!*!SIZE!+!XPOS!, MYP=!MY%%a!*!SIZE!+!YPOS!"&set OUTP=!OUTP!!MXP!,!MYP!,
set SS2=skip&set SS3=skip
if !NOFSB! geq 2 set SS2=&for /L %%a in (0,1,14) do set /a "MXP=!MX%%a!*!SIZE!+!XPOS2!, MYP=!MY%%a!*!SIZE!+!YPOS2!"&set OUTP2=!OUTP2!!MXP!,!MYP!,
if !NOFSB! geq 3 set SS3=& for /L %%a in (0,1,14) do set /a "MXP=!MX%%a!*!SIZE!+!XPOS!, MYP=!MY%%a!*!SIZE!+!YPOS2!"&set OUTP3=!OUTP3!!MXP!,!MYP!,
set DRAW="!DRAW:~1,-1!&ipoly !FG1! !BG1! ? !DRWMODE! !OUTP:~0,-1! & !SS2! ipoly !FG2! !BG2! ? !DRWMODE! !OUTP2:~0,-1!& !SS3! ipoly !FG3! !BG3! ? !DRWMODE! !OUTP3:~0,-1!"
set OUTP=&set OUTP2=&set OUTP3=
)
set /a KEY=0
)
if not defined STOP goto LOOP
endlocal
cmdwiz delay 100
echo "cmdgfx: quit"
title input:Q
goto :eof
:GETCOLORS
for /L %%a in (1,1,3) do set /a "R=!RANDOM! %% 3, G=!RANDOM! %% 3, B=!RANDOM! %% 3" & set FG%%a=0!R!0!G!0!B!
for /L %%a in (1,1,3) do set /a "R=!RANDOM! %% 3, G=!RANDOM! %% 3, B=!RANDOM! %% 3" & set BG%%a=0!R!0!G!0!B!
set /a CHAR=!RANDOM! %% 99 + 1, CHRND=!RANDOM! %% 5
if !CHRND!==0 set CHAR=db