-
Notifications
You must be signed in to change notification settings - Fork 3
/
Copy pathScreenFull-Automata-_RandMooreExtended.bat
257 lines (218 loc) · 10.4 KB
/
ScreenFull-Automata-_RandMooreExtended.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
@echo off
cd /D "%~dp0"
if defined __ goto :START
cmdwiz setfont 6
mode 80,50 & cmdwiz showmousecursor 0 & cmdwiz fullscreen 1
if %ERRORLEVEL% lss 0 set TOP=U
cls & cmdwiz showcursor 0 & cmdwiz setmousecursorpos 10000 100
cmdwiz getdisplaydim w
set /a W=%errorlevel%
cmdwiz getdisplaydim h
set /a H=%errorlevel%
set __=.
set /a density=50
call %0 %* | cmdgfx_gdi "fbox 0 0 db" %TOP%m0OW0Sfa:0,0,%W%,%H%nt8
set __=
set W=&set H=&set density=
cmdwiz fullscreen 0 & cls & cmdwiz setfont 6 & cmdwiz showcursor 1 & mode 80,50
goto :eof
:START
setlocal ENABLEDELAYEDEXPANSION
set EXTRA=&for /L %%a in (1,1,200) do set EXTRA=!EXTRA!xtra
call :MAKERULES stay
call :MAKERULES born
set zoomFont=abcdef
set /a XTXT=2, YTXT=4, HLP=1, FPS=0, CRXTR=0, WVAL=0, slowDeath=0, liveCol=1, updateRate=0, rateCnt=0, XSC=0, YSC=0, zoom=0, WSC=W,HSC=H, forcedWait=0
set font=!zoomFont:~%zoom%,1!
set TS=&if !HLP!==0 set TS=skip
set FS=&if !FPS!==0 set FS=skip
set LKEY=""& set SCHR="()*+,-./0123456789:;<=>?@ABCDEFGHIJKLMNOPQRSTUVWXYZ[\] _ abcdefghijklmnopqrstuvwxyz{|}~"
set KEY=
set /a stayOld=0, bornOld=0, NH=3, initPrep=1, c0pos=0, opType=0
set OPOUT=""
::Disintegrate/explode
set /a stay=33145,born=8244,density=60,liveCol=5,slowDeath=1,NH=3 & set PAL=000000,8a09c6,0bb285,aadb3b,32f328,05a1e8,b208a1,ca4a81,f04a68,30b7e1,924657,ee3e86,013a2f,c12a10,ee9c13,ea3ac6,
:BEGIN
if not "!PAL!"=="" set COL0=%PAL:~0,7%& echo "cmdgfx: " - !PAL!
set /a CNT=-1, MAXBITS=8 & for %%a in (8 12 12 16 20 24 16 12 10 10 12 10 10 16) do set /a CNT+=1 & if !CNT!==!NH! set /a MAXBITS=%%a
set /a MAXVAL="(1 << (!MAXBITS!))-1"
if !initPrep! == 1 (
if !opType! == 0 call :PREP 1
if !opType! == 1 call :PREP
if !opType! == 2 call :PREP 2
if !opType! == 3 call :PREP 0 2
)
for /l %%a in () do (
set /a rateCnt+=1
if !rateCnt! geq !updateRate! (
set XTRP=""
if !CRXTR! == 1 for /l %%b in (1,1,10) do set /a "XP=!RANDOM! %% !W!, YP=!RANDOM! %% !H!" & set XTRP="!XTRP:~1,-1! & pixel 1 0 db !XP!,!YP!"
set /a iflc=-1, ifi=-1
if not "!inFileLineCount!" == "" set /a iflc=inFileLineCount-1, ifi=inFileIndex
echo "cmdgfx: block 0 0,0,%w%,%h% 0,0 -1 0 0 - DLL:eextern:randMooreExtended:!stay!,!born!,!slowDeath!,!liveCol!,!NH! & !XTRP:~1,-1! & !TS! text b 0 0 !stay!__!born!__!density!__(!slowDeath!_!liveCol!)_!NH!___(!ifi!/!iflc!) !XTXT!,!YTXT! 5 & !FS! text b 0 0 [FRAMECOUNT] 2,28 5 & skip %EXTRA%%EXTRA%%EXTRA%%EXTRA%" f!font!:0,0,%W%,%H%,!WSC!,!HSC!,!XSC!,!YSC!
set /a rateCnt=0
) else (
echo "cmdgfx: skip %EXTRA%%EXTRA%%EXTRA%%EXTRA%" f!font!:0,0,%W%,%H%,!WSC!,!HSC!,!XSC!,!YSC!
)
if exist EL.dat set /p EVENTS=<EL.dat & del /Q EL.dat >nul 2>nul & set /a "KEY=!EVENTS!>>22, MOUSE_EVENT=!EVENTS!&1"
if !KEY! neq 0 (
if !KEY! leq 126 if !KEY! geq 40 set /A MKEY=!KEY!-40+1 & for %%M in (!MKEY!) do set LKEY="!SCHR:~%%M,1!"
if !KEY! == 13 set /a stayOld=stay, bornOld=born & call :MAKERULES stay & call :MAKERULES born & call :PREP 1
if !LKEY! == "<" set /a stay=stayOld, born=bornOld & call :PREP 1
if !KEY! == 32 call :PREP 1
if !KEY! == 9 call :PREP
if !LKEY! == "." call :PREP 0 2
if !LKEY! == "," call :PREP 2
if !LKEY! == "f" set /a FPS=1-FPS & set FS=&if !FPS!==0 set FS=skip
if !KEY! geq 48 if !KEY! leq 57 set /a "density=(KEY-47)*10" & call :PREP 1
if !KEY! == 333 set /a "density+=1" & call :PREP 1
if !KEY! == 331 set /a "density-=1" & call :PREP 1
if !KEY! == 328 call :GETPATTERNFROMFILE -1
if !KEY! == 336 call :GETPATTERNFROMFILE 1
if !LKEY! == "g" if not "!inFileLineCount!" == "" call :GETPATTERNINDEX & call :GETPATTERNFROMFILE 0
if !LKEY! == "a" set /a "stay-=1" & (if !stay! lss 0 set /a stay=!MAXVAL!) & call :PREP 1
if !LKEY! == "A" set /a "stay+=1" & (if !stay! gtr !MAXVAL! set /a stay=0) & call :PREP 1
if !LKEY! == "b" set /a "born-=1" & (if !born! lss 0 set /a born=!MAXVAL!) & call :PREP 1
if !LKEY! == "B" set /a "born+=1" & (if !born! gtr !MAXVAL! set /a born=0) & call :PREP 1
if !LKEY! == "c" call :RAND_PALETTE
if !LKEY! == "C" if not "!PAL!"=="" (if !c0pos!==0 set PAL=000000,!PAL:~7!) & (if !c0pos!==1 set PAL=ffffff,!PAL:~7!) & (if !c0pos!==2 set PAL=!COL0!!PAL:~7!) & echo "cmdgfx: " - !PAL! & set /a c0pos+=1 & if !c0pos! gtr 2 set /a c0pos=0
if !LKEY! == "d" set PAL=& echo "cmdgfx: " - -
if !LKEY! == "P" echo !PAL! >> data\randMoorePalette.txt
if !LKEY! == "s" call :SAVE_CURRENT
if !LKEY! == "S" call :SAVE_CURRENT 1
if !KEY! == 26 if !zoom! gtr 0 set /a "XSC=W/2-WSC/2, YSC=H/2-HSC/2" & rem ^Z
if !LKEY! == "Z" call :ADJUSTZOOM 1
if !LKEY! == "z" call :ADJUSTZOOM -1
if !LKEY! == "X" if !zoom! gtr 0 set /a "XSC+=10, XMAX=W-WSC" & if !XSC! geq !XMAX! set /a XSC=XMAX-1
if !LKEY! == "x" if !zoom! gtr 0 set /a "XSC-=10" & if !XSC! lss 0 set /a XSC=0
if !LKEY! == "Y" if !zoom! gtr 0 set /a "YSC+=10, YMAX=H-HSC" & if !YSC! geq !YMAX! set /a YSC=YMAX-1
if !LKEY! == "y" if !zoom! gtr 0 set /a "YSC-=10" & if !YSC! lss 0 set /a YSC=0
if !LKEY! == "h" set /a HLP=1-HLP & set TS=&if !HLP!==0 set TS=skip
if !LKEY! == "r" set /a CRXTR=1-CRXTR
if !LKEY! == "w" set /a WVAL=10, updateRate+=1 & echo "cmdgfx: " W!WVAL!
if !LKEY! == "W" set /a updateRate=0, WVAL=0 & echo "cmdgfx: " W!WVAL!
if !LKEY! == "l" set /a "liveCol-=1" & if !liveCol! lss 1 set /a liveCol=1
if !LKEY! == "L" set /a "liveCol+=1" & if !liveCol! gtr 15 set /a liveCol=15
if !LKEY! == "m" set /a "slowDeath=1-slowDeath"
if !LKEY! == "n" set /a NH-=1 & (if !NH! lss 0 set /a NH=13) & call :PREP 1
if !LKEY! == "N" set /a NH+=1 & (if !NH! gtr 13 set /a NH=0) & call :PREP 1
if !LKEY! == "p" cmdwiz getch
if !KEY! == 27 cmdwiz delay 100 & echo "cmdgfx: quit" & exit
)
set /a KEY=0
set LKEY=""
)
:PREP
set OPOUT=""
if "%1"=="1" set /a opType=0 & echo "cmdgfx: block 0 0,0,%w%,%h% 0,0 -1 0 0 - min(random()*100/(101-%density%),1)*!liveCol!" & goto :eof
echo "cmdgfx: fbox 0 0 db" nW0
if "%1"=="2" set /a opType=2 & set /a SIZ=20 + !random! %% 80, WH=w/2-SIZ/2,HH=h/2-SIZ/2 & echo "cmdgfx: block 0 !WH!,!HH!,!SIZ!,!SIZ! !WH!,!HH! -1 0 0 - min(random()*100/(101-%density%),1)*!liveCol!" & goto :eof
if "%1"=="" (
set /a opType=1
for /l %%a in (1,1,65) do (
set /a "XP=!RANDOM! %% !W!, YP=!RANDOM! %% !H!, XS=!RANDOM! %% 100 + 5, YS=!RANDOM! %% 100 + 5, OP=!RANDOM! %% 4, XP2=XP+XS, YP2=YP+YS"
if !OP!==0 echo "cmdgfx: fellipse !liveCol! 0 db !XP!,!YP!,!XS!,!YS!" n
if !OP!==1 echo "cmdgfx: fbox !liveCol! 0 db !XP!,!YP!,!XS!,!YS!" n
if !OP!==2 echo "cmdgfx: line !liveCol! 0 db !XP!,!YP!,!XP2!,!YP!" n
if !OP!==3 echo "cmdgfx: line !liveCol! 0 db !XP!,!YP!,!XP!,!YP2!" n
)
) else (
set /a opType=3
for /l %%a in (1,1,1) do (
set /a "XP=!W!/2, YP=!H!/2, XS=!RANDOM! %% 500 + 400, YS=!RANDOM! %% 200 + 300, OP=!RANDOM! %% 4"
if !OP!==0 echo "cmdgfx: fellipse !liveCol! 0 db !XP!,!YP!,!YS!,!YS!" n & set OPOUT="& set /a initPrep=0 & echo \"cmdgfx: fellipse !liveCol! 0 db !XP!,!YP!,!YS!,!YS!\" n"
if !OP!==1 echo "cmdgfx: fbox !liveCol! 0 db !XP!,!YP!,!YS!,!YS!" nV & set OPOUT="& set /a initPrep=0 & echo \"cmdgfx: fbox !liveCol! 0 db !XP!,!YP!,!YS!,!YS!\" nV"
if !OP!==2 echo "cmdgfx: fellipse !liveCol! 0 db !XP!,!YP!,!XS!,!YS!" n & set OPOUT="& set /a initPrep=0 & echo \"cmdgfx: fellipse !liveCol! 0 db !XP!,!YP!,!XS!,!YS!\" n"
if !OP!==3 echo "cmdgfx: fbox !liveCol! 0 db !XP!,!YP!,!XS!,!YS!" nV & set OPOUT="& set /a initPrep=0 & echo \"cmdgfx: fbox !liveCol! 0 db !XP!,!YP!,!XS!,!YS!\" nV"
)
)
set /a XP=0, YP=H2
echo "cmdgfx: " W!WVAL!
goto :eof
:MAKERULES
set /a VD=0
set /a "BITC=!RANDOM! %% 3 + 2"
for /l %%a in (1,1,!MAXBITS!) do (
set /a "BITT=!RANDOM! %% !BITC!"
if !BITT! gtr 0 set /a BIT=0
if !BITT! equ 0 set /a BIT=1
set /a "VD=(VD << 1) | BIT"
)
set %1=!VD!
set /a c0pos=0
goto :eof
:RAND_PALETTE
set PAL=
set /a BLCH=0
for /l %%d in (1,1,16) do (
set /a "BL=!RANDOM! %% 100"
for /l %%e in (1,1,3) do (
set /a "C=!RANDOM! %% 256"
if !BL! lss !BLCH! set /a C=0
set /a "CNT=-1, C1=C/16, C2=C %% 16"
for %%f in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do set /a CNT+=1 & if !CNT!==!C1! set PAL=!PAL!%%f
set /a CNT=-1 & for %%f in (0 1 2 3 4 5 6 7 8 9 a b c d e f) do set /a CNT+=1 & if !CNT!==!C2! set PAL=!PAL!%%f
)
set PAL=!PAL!,
)
set PAL=%PAL:~0,-1%
echo "cmdgfx: " - !PAL!
set COL0=%PAL:~0,7%
set /a c0pos=0
goto :eof
:SAVE_CURRENT
set /a savePal=0
if "%~1" == "1" if not "!PAL!"=="" set /a savePal=1
set WVS=& if !WVAL! neq 0 set WVS=,WVAL=!WVAL!,updateRate=!updateRate!
if !savePal! == 0 cmdwiz print "::set /a stay=!stay!,born=!born!,density=!density!,liveCol=!liveCol!,slowDeath=!slowDeath!,NH=!NH!,opType=!opType!%WVS% !OPOUT:~1,-1!\n" >> data\randMoore-Extended-Set.txt
if !savePal! == 1 cmdwiz print "::set /a stay=!stay!,born=!born!,density=!density!,liveCol=!liveCol!,slowDeath=!slowDeath!,NH=!NH!,opType=!opType!%WVS% !OPOUT:~1,-1!& set PAL=!PAL!\n" >> data\randMoore-Extended-Set.txt
set WVS=
goto :eof
:GETPATTERNFROMFILE
set inFile=data\randMooreExtended-data.txt
if not "%inFileIndex%" == "" set /a inFileIndex += %1
if "%inFileIndex%" == "" (
set /a inFileIndex=0
set /a inFileLineCount=0
for /f "tokens=*" %%a in ('type "%inFile%"') do set /a inFileLineCount+=1
)
if %inFileIndex% geq !inFileLineCount! set /a inFileIndex=0
if %inFileIndex% lss 0 set /a inFileIndex=!inFileLineCount!-1
set /a cnt=0, initPrep=1, WVAL=0, updateRate=0, opType=0
set PAL=
for /f "tokens=*" %%a in ('type "%inFile%"') do (if !cnt! == !inFileIndex! set pattern="%%a")& set /a cnt+=1
echo "cmdgfx: fbox 0 0 db" - - -
%pattern:~1,-1%
if not "!PAL!"=="" set COL0=%PAL:~0,7%& echo "cmdgfx: " - !PAL!
if !forcedWait! == 0 set /a WVAL=0, updateRate=0 & echo "cmdgfx: " W!WVAL!
if !forcedWait! == 1 echo "cmdgfx: " W!WVAL!
set /a forcedWait=0
if !initPrep! == 1 (
if !opType! == 0 call :PREP 1
if !opType! == 1 call :PREP
if !opType! == 2 call :PREP 2
if !opType! == 3 call :PREP 0 2
)
set pattern=
set /a c0pos=0
goto :eof
:GETPATTERNINDEX
set /a KEY=0,VAL=0
:KEYLOOP
echo "cmdgfx: skip %EXTRA%%EXTRA%%EXTRA%%EXTRA%"
if exist EL.dat set /p EVENTS=<EL.dat & del /Q EL.dat >nul 2>nul & set /a "KEY=!EVENTS!>>22"
if !KEY! geq 48 if !KEY! leq 57 set /a "VAL=VAL*10+(KEY-48), KEY=0"
if not !KEY! == 13 goto :KEYLOOP
set /a inFileIndex = VAL, KEY=0
if %inFileIndex% geq !inFileLineCount! set /a inFileIndex=0
if %inFileIndex% lss 0 set /a inFileIndex=!inFileLineCount!-1
goto :eof
:ADJUSTZOOM
set /a "zoom+=%1"
if !zoom! gtr 5 set /a zoom=5
if !zoom! lss 0 set /a zoom=0
set /a "WSC=W/(zoom+1),HSC=H/(zoom+1)"
set font=!zoomFont:~%zoom%,1!
set /a "XMAX=W-WSC" & if !XSC! geq !XMAX! set /a XSC=XMAX-1
set /a "YMAX=H-HSC" & if !YSC! geq !YMAX! set /a YSC=YMAX-1
goto :eof