Add scripts to deploy to maven central.

Author: bffcorreia

build.gradle

@@ -10,4 +10,7 @@ plugins {
     id 'org.jetbrains.kotlin.android' version '1.7.20' apply false
     id 'org.jetbrains.kotlin.jvm' version '1.7.20' apply false
     id 'com.google.devtools.ksp' version '1.7.20-1.0.7' apply false
-}
+    id 'io.github.gradle-nexus.publish-plugin' version '1.1.0'
+}
+
+apply from: "${rootDir}/scripts/publish-root.gradle"

peanuts/build.gradle

@@ -2,6 +2,14 @@ plugins {
     id 'org.jetbrains.kotlin.jvm'
 }
 
+ext {
+    PUBLISH_GROUP_ID = 'dev.pinkroom'
+    PUBLISH_VERSION = '0.0.1'
+    PUBLISH_ARTIFACT_ID = 'peanuts'
+}
+
+apply from: "${rootProject.projectDir}/scripts/publish-module.gradle"
+
 java {
     sourceCompatibility = JavaVersion.VERSION_1_8
     targetCompatibility = JavaVersion.VERSION_1_8

scripts/publish-module.gradle

@@ -0,0 +1,71 @@
+apply plugin: 'maven-publish'
+apply plugin: 'signing'
+
+task androidSourcesJar(type: Jar) {
+    archiveClassifier.set('sources')
+    if (project.plugins.findPlugin("com.android.library")) {
+        from android.sourceSets.main.java.srcDirs
+        from android.sourceSets.main.kotlin.srcDirs
+    }
+}
+
+artifacts {
+    archives androidSourcesJar
+}
+
+group = PUBLISH_GROUP_ID
+version = PUBLISH_VERSION
+
+afterEvaluate {
+    publishing {
+        publications {
+            release(MavenPublication) {
+                groupId PUBLISH_GROUP_ID
+                artifactId PUBLISH_ARTIFACT_ID
+                version PUBLISH_VERSION
+
+                if (project.plugins.findPlugin("com.android.library")) {
+                    from components.release
+                } else {
+                    from components.java
+                }
+
+                artifact androidSourcesJar
+
+                pom {
+                    name = PUBLISH_ARTIFACT_ID
+                    description = 'Updating your UI state is now peanuts!'
+                    url = 'https://github.com/pink-room/peanuts'
+                    licenses {
+                        license {
+                            name = 'Apache-2.0 License'
+                            url = 'https://github.com/pink-room/peanuts/blob/main/LICENSE'
+                        }
+                    }
+                    developers {
+                        developer {
+                            id = 'bffcorreia'
+                            name = 'Bruno Correia'
+                            email = '[email protected]'
+                        }
+                    }
+
+                    scm {
+                        connection = 'scm:git:github.com/pink-room/peanuts.git'
+                        developerConnection = 'scm:git:ssh://github.com/pink-room/peanuts.git'
+                        url = 'https://github.com/pink-room/peanuts/tree/main'
+                    }
+                }
+            }
+        }
+    }
+}
+
+signing {
+    useInMemoryPgpKeys(
+            rootProject.ext["signing.keyId"],
+            rootProject.ext["signing.key"],
+            rootProject.ext["signing.password"],
+    )
+    sign publishing.publications
+}

scripts/publish-root.gradle

@@ -0,0 +1,36 @@
+ext["ossrhUsername"] = ''
+ext["ossrhPassword"] = ''
+ext["sonatypeStagingProfileId"] = ''
+ext["signing.keyId"] = ''
+ext["signing.password"] = ''
+ext["signing.key"] = ''
+ext["snapshot"] = ''
+
+File secretPropsFile = project.rootProject.file('local.properties')
+if (secretPropsFile.exists()) {
+    // Read local.properties file first if it exists
+    Properties p = new Properties()
+    new FileInputStream(secretPropsFile).withCloseable { is -> p.load(is) }
+    p.each { name, value -> ext[name] = value }
+} else {
+    // Use system environment variables
+    ext["ossrhUsername"] = System.getenv('OSSRH_USERNAME')
+    ext["ossrhPassword"] = System.getenv('OSSRH_PASSWORD')
+    ext["sonatypeStagingProfileId"] = System.getenv('SONATYPE_STAGING_PROFILE_ID')
+    ext["signing.keyId"] = System.getenv('SIGNING_KEY_ID')
+    ext["signing.password"] = System.getenv('SIGNING_PASSWORD')
+    ext["signing.key"] = System.getenv('SIGNING_KEY')
+    ext["snapshot"] = System.getenv('SNAPSHOT')
+}
+
+nexusPublishing {
+    repositories {
+        sonatype {
+            stagingProfileId = sonatypeStagingProfileId
+            username = ossrhUsername
+            password = ossrhPassword
+            nexusUrl.set(uri("https://s01.oss.sonatype.org/service/local/"))
+            snapshotRepositoryUrl.set(uri("https://s01.oss.sonatype.org/content/repositories/snapshots/"))
+        }
+    }
+}