build.gradle

apply plugin: "java"
apply plugin: "war"
apply plugin: "tomcat"
apply plugin: "idea"
apply plugin: "maven"

group = "org.springframework.data"
version = "$sdRestVersion"
archivesBaseName = "spring-data-rest-webmvc"

project.sourceCompatibility = 1.6
project.targetCompatibility = 1.6

configurations.all {
  exclude group: "commons-logging"
  exclude module: "slf4j-log4j12"
  exclude module: "servlet-api"
}

buildscript {
  repositories {
    add(new org.apache.ivy.plugins.resolver.URLResolver()) {
      name = 'GitHub'
      addArtifactPattern 'http://cloud.github.com/downloads/[organisation]/[module]/[module]-[revision].[ext]'
    }
  }

  dependencies {
    classpath 'bmuschko:gradle-tomcat-plugin:0.9.5'
  }
}

repositories {
  maven { url "http://repo.springsource.org/libs-snapshot" }
  maven { url "http://repo.springsource.org/libs-milestone" }
  maven { url "http://repo.springsource.org/libs-release" }
}

dependencies {

  // Logging
  compile "org.slf4j:slf4j-api:$slf4jVersion"
  runtime "org.slf4j:jcl-over-slf4j:$slf4jVersion"
  runtime "ch.qos.logback:logback-classic:$logbackVersion"

  // JPA
  compile "org.hibernate.javax.persistence:hibernate-jpa-2.0-api:1.0.1.Final"
  runtime "org.hibernate:hibernate-entitymanager:$hibernateVersion"
  runtime "org.hsqldb:hsqldb:2.2.8"

  // Spring
  compile("org.springframework:spring-aop:$springVersion") { force = true }
  compile("org.springframework:spring-asm:$springVersion") { force = true }
  compile("org.springframework:spring-beans:$springVersion") { force = true }
  compile("org.springframework:spring-context:$springVersion") { force = true }
  compile("org.springframework:spring-core:$springVersion") { force = true }
  compile("org.springframework:spring-expression:$springVersion") { force = true }
  compile("org.springframework:spring-orm:$springVersion") { force = true }
  compile("org.springframework:spring-tx:$springVersion") { force = true }
  compile("org.springframework:spring-web:$springVersion") { force = true }
  compile("org.springframework:spring-webmvc:$springVersion") { force = true }
  compile "javax.inject:javax.inject:1"

  // Spring Data
  compile "org.springframework.data:spring-data-commons-core:$sdCommonsVersion"
  compile "org.springframework.data:spring-data-jpa:$sdJpaVersion"

  // Spring Data REST
  compile "org.springframework.data:spring-data-rest-webmvc:$sdRestVersion"

  // Servlet 3.0
  providedCompile "javax.servlet:javax.servlet-api:3.0.1"

  tomcat "org.apache.tomcat.embed:tomcat-embed-core:${tomcatVersion}",
         "org.apache.tomcat.embed:tomcat-embed-logging-juli:${tomcatVersion}"
  tomcat("org.apache.tomcat.embed:tomcat-embed-jasper:${tomcatVersion}") {
    exclude group: 'org.eclipse.jdt.core.compiler', module: 'ecj'
  }
}

task wrapper(type: Wrapper) { gradleVersion = "1.1" }

idea {
  project {
    jdkName = "1.6"
    languageLevel = "1.6"
    ipr {
      withXml { xml ->
        xml.node.component.find { it.@name == "VcsDirectoryMappings" }.mapping.@vcs = "Git"
        xml.node.component.find { it.@name == "ProjectRootManager" }.output.@url = "file://\$PROJECT_DIR\$/build"
      }
    }
  }
}