-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathComplex_Functions.inc
818 lines (585 loc) · 18.9 KB
/
Complex_Functions.inc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
/*
https://github.com/t-o-k/POV-Ray-complex-functions
Copyright (c) 2021-2022 Tor Olav Kristensen, http://subcube.com
Use of this source code is governed by the GNU Lesser General Public License version 3,
which can be found in the LICENSE file.
*/
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
#version 3.7;
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
#declare TAU = 2*pi;
#macro IndexOfString(Str, Strings)
#local NoOfStrings = dimension_size(Strings, 1);
#local Found = false;
#local Idx = 0;
#while ((! Found) & (Idx < NoOfStrings))
#if (strcmp(Str, Strings[Idx]) = 0)
#local Found = true;
#else
#local Idx = Idx + 1;
#end // if
#end // while
#if (! Found)
#local Idx = -1;
#end // if
Idx
#end // macro IndexOfString
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
#macro HandleZerosFunction(PowFn)
function(re1, im1, re2, im2) {
select(
im1,
PowFn(re1, im1, re2, im2), // (re1 + im1*j)^(re2 + im2*j)
select(
re1,
PowFn(re1, im1, re2, im2), // re1^(re2 + im2*j)
select(
im2,
0, // 0^(re2 + im2*j) = 0
select(
re2,
0, // 0^re2 = 0
PowFn(re1, im1, re2, im2), // 0^0 = ?
0 // 0^re2 = 0
),
0 // 0^(re2 + im2*j) = 0
),
PowFn(re1, im1, re2, im2) // re1^(re2 + im2*j)
),
PowFn(re1, im1, re2, im2) // (re1 + im1*j)^(re2 + im2*j)
)
}
#end // macro HandleZerosFunction
// j = sqrt(-1)
// Z = re + im*j
#declare NO_OF_OPERATORS = 30;
#declare OPERATOR_TYPES =
array[NO_OF_OPERATORS] {
// Re(Z) = re
"Re",
// Im(Z) = im
"Im",
// Id(Z) = Z
"Id",
// Pos(Z) = +Z
"Pos",
// Neg(Z) = -Z
"Neg",
// Conj(Z) = re - im*j
"Conj",
// Abs(Z) = |Z| = sqrt(Z*conj(Z))
"Abs",
// Phase(Z) = atan2(im, re)
"Phase",
// Ln(Z) = ln(abs(Z)) + phase(Z)*j
"Ln",
// Exp(Z) = e^Z
"Exp",
// Sqr(Z) = Z^2
"Sqr",
// Sqrt(Z) = Z^0.5
"Sqrt",
// Inv(Z) = 1/Z
"Inv",
// Cos(Z) = (e^(-Z*j) + e^(+Z*j))/2
"Cos",
// Acos(Z) = -ln(Z + sqrt(1 - Z^2)*j)*j
"Acos",
// Sin(Z) = (e^(-Z*j) - e^(+Z*j))/2*j
"Sin",
// Asin(Z) = -ln(sqrt(1 - Z^2) + Z*j)*j
"Asin",
// Tan(Z) = sin(Z)/cos(Z)
"Tan",
// Atan(Z) = (ln(1 - Z*j) - ln(1 + Z*j))/2*j
"Atan",
// Cosh(Z) = +(e^(+Z) + e^(-Z))/2
"Cosh",
// Acosh(Z) = +2*ln(+sqrt((Z + 1)/2) +sqrt((Z - 1)/2))
"Acosh",
// Sinh(Z) = +(e^(+Z) - e^(-Z))/2
"Sinh",
// Asinh(Z) = +ln(Z + sqrt(+Z^2 +1))
"Asinh",
// Tanh(Z) = sinh(Z)/cosh(Z)
"Tanh",
// Atanh(Z) = (ln(1 + Z) - ln(1 - Z))/2
"Atanh",
// Add(Z1, Z2) = Z1 + Z2
"Add",
// Sub(Z1, Z2) = Z1 - Z2
"Sub",
// Mul(Z1, Z2) = Z1*Z2
"Mul",
// Div(Z1, Z2) = Z1/Z2
"Div",
// Pow(Z1, Z2) = Z1^Z2
"Pow"
}
;
#declare NO_OF_ARGUMENTS =
array[NO_OF_OPERATORS] {
// Re
1,
// Im
1,
// Id
1,
// Pos
1,
// Neg
1,
// Conj
1,
// Abs
1,
// Phase
1,
// Ln
1,
// Exp
1,
// Sqr
1,
// Sqrt
1,
// Inv
1,
// Cos
1,
// Acos
1,
// Sin
1,
// Asin
1,
// Tan
1,
// Atan
1,
// Cosh
1,
// Acosh
1,
// Sinh
1,
// Asinh
1,
// Tanh
1,
// Atanh
1,
// Add
2,
// Sub
2,
// Mul
2,
// Div
2,
// Pow
2
}
;
#declare RE_OPERATOR_FUNCTIONS =
array[NO_OF_OPERATORS] {
// Re
function(re, im) { re },
// Im
function(re, im) { 0 },
// Id
function(re, im) { re },
// Pos
function(re, im) { +re },
// Neg
function(re, im) { -re },
// Conj
function(re, im) { +re },
// Abs
function(re, im) { +sqrt(+pow(re, 2) +pow(im, 2)) },
// Phase
function(re, im) { +atan2(im, re) },
// Ln
function(re, im) { +ln(+pow(re, 2) +pow(im, 2))/2 },
// Exp
function(re, im) { +exp(re)*cos(im) },
// Sqr
function(re, im) { +pow(re, 2) -pow(im, 2) },
// Sqrt
function(re, im) {
+sqrt((sqrt(+pow(re, 2) +pow(im, 2)) +re)/2)
// pow(+pow(re, 2) +pow(im, 2), 0.25)*cos(atan2(im, re)/2)
},
// Inv
function(re, im) { +re/(+pow(re, 2) +pow(im, 2)) },
// Cos
function(re, im) { +cos(re)*cosh(im) },
// Acos
function(re, im) {
+atan2(
+im
+pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*cos(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
+re
-pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*sin(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2)
)
},
// Sin
function(re, im) { +sin(re)*cosh(im) },
// Asin
function(re, im) {
+atan2(
+re
+pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*sin(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
-im
+pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*cos(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2)
)
},
// Tan
function(re, im) { +sin(2*re)/(+cos(2*re) +cosh(2*im)) },
// Atan
function(re, im) {
+(
+atan2(+re, +1 -im)
-atan2(-re, +1 +im)
)/2
},
// Cosh
function(re, im) { +cosh(re)*cos(im) },
// Acosh
function(re, im) {
+ln(
+pow(
+pow((+pow(re + 1, 2) +pow(im, 2))/4, 0.25)*cos(atan2(im/2, (re + 1)/2)/2)
+pow((+pow(re - 1, 2) +pow(im, 2))/4, 0.25)*cos(atan2(im/2, (re - 1)/2)/2),
2
)
+pow(
+pow((+pow(re + 1, 2) +pow(im, 2))/4, 0.25)*sin(atan2(im/2, (re + 1)/2)/2)
+pow((+pow(re - 1, 2) +pow(im, 2))/4, 0.25)*sin(atan2(im/2, (re - 1)/2)/2),
2
)
)
},
// Sinh
function(re, im) { +sinh(re)*cos(im) },
// Asinh
function(re, im) {
ln(
+pow(
+re
+pow(+pow(+1 +pow(re, 2) -pow(im, 2), 2) +4*pow(re*im, 2), 0.25)
*cos(atan2(+2*re*im, +1 +pow(re, 2) -pow(im, 2))/2),
2
)
+pow(
+im
+pow(+pow(+1 +pow(re, 2) -pow(im, 2), 2) +4*pow(re*im, 2), 0.25)
*sin(atan2(+2*re*im, +1 +pow(re, 2) -pow(im, 2))/2),
2
)
)/2
},
// Tanh
function(re, im) { +sinh(2*re)/(+cosh(2*re) +cos(2*im)) },
// Atanh
function(re, im) {
(
+ln(+pow(+1 +re, 2) +pow(+im, 2))
-ln(+pow(+1 -re, 2) +pow(-im, 2))
)/4
},
// Add
function(re1, im1, re2, im2) { +re1 +re2 },
// Sub
function(re1, im1, re2, im2) { +re1 -re2 },
// Mul
function(re1, im1, re2, im2) { +re1*re2 -im1*im2 },
// Div
function(re1, im1, re2, im2) {
(+re1*re2 +im1*im2)
/
(+re2*re2 +im2*im2)
},
// Pow
function(re1, im1, re2, im2) {
exp(+re2/2*ln(+pow(re1, 2) +pow(im1, 2)) -im2*atan2(im1, re1))
*
cos(+im2/2*ln(+pow(re1, 2) +pow(im1, 2)) +re2*atan2(im1, re1))
}
}
;
#declare IM_OPERATOR_FUNCTIONS =
array[NO_OF_OPERATORS] {
// Re
function(re, im) { 0 },
// Im
function(re, im) { im },
// Id
function(re, im) { im },
// Pos
function(re, im) { +im },
// Neg
function(re, im) { -im },
// Conj
function(re, im) { -im },
// Abs
function(re, im) { 0 },
// Phase
function(re, im) { 0 },
// Ln
function(re, im) { +atan2(im, re) },
// Exp
function(re, im) { +exp(re)*sin(im) },
// Sqr
function(re, im) { +2*re*im },
// Sqrt
function(re, im) {
+sqrt((sqrt(+pow(re, 2) +pow(im, 2)) -re)/2)*select(im, -1, +1)
// pow(+pow(re, 2) +pow(im, 2), 0.25)*sin(atan2(im, re)/2)
},
// Inv
function(re, im) { -im/(+pow(re, 2) +pow(im, 2)) },
// Cos
function(re, im) { -sin(re)*sinh(im) },
// Acos
function(re, im) {
-ln(
+pow(
+re
-pow(pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*sin(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
2
)
+pow(
+im
+pow(pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*cos(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
2
)
)/2
},
// Sin
function(re, im) { +cos(re)*sinh(im) },
// Asin
function(re, im) {
-ln(
+pow(
-im
+pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*cos(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
2
)
+pow(
+re
+pow(+pow(+1 -pow(re, 2) +pow(im, 2), 2) +pow(-2*re*im, 2), 0.25)
*sin(atan2(-2*re*im, +1 -pow(re, 2) +pow(im, 2))/2),
2
)
)/2
},
// Tan
function(re, im) { +sinh(2*im)/(+cos(2*re) +cosh(2*im)) },
// Atan
function(re, im) {
-(
+ln(+pow(+re, 2) +pow(+1 -im, 2))
-ln(+pow(-re, 2) +pow(+1 +im, 2))
)/4
},
// Cosh
function(re, im) { +sinh(re)*sin(im) },
// Acosh
function(re, im) {
atan2(
+pow((+pow(+re +1, 2) +pow(im, 2))/4, 0.25)*sin(atan2(im/2, (+re +1)/2)/2)
+pow((+pow(+re -1, 2) +pow(im, 2))/4, 0.25)*sin(atan2(im/2, (+re -1)/2)/2),
+pow((+pow(+re +1, 2) +pow(im, 2))/4, 0.25)*cos(atan2(im/2, (+re +1)/2)/2)
+pow((+pow(+re -1, 2) +pow(im, 2))/4, 0.25)*cos(atan2(im/2, (+re -1)/2)/2)
)*2
},
// Sinh
function(re, im) { +cosh(re)*sin(im) },
// Asinh
function(re, im) {
+atan2(
+im
+pow(+pow(+1 +pow(re, 2) -pow(im, 2), 2) +4*pow(re*im, 2), 0.25)
*sin(atan2(+2*re*im, +1 +pow(re, 2) -pow(im, 2))/2),
+re
+pow(+pow(+1 +pow(re, 2) -pow(im, 2), 2) +4*pow(re*im, 2), 0.25)
*cos(atan2(+2*re*im, +1 +pow(re, 2) -pow(im, 2))/2)
)
},
// Tanh
function(re, im) { +sin(2*im)/(cosh(2*re) + cos(2*im)) },
// Atanh
function(re, im) {
(
+atan2(+im, +1 +re)
-atan2(-im, +1 -re)
)/2
},
// Add
function(re1, im1, re2, im2) { +im1 +im2 },
// Sub
function(re1, im1, re2, im2) { +im1 -im2 },
// Mul
function(re1, im1, re2, im2) { +re1*im2 +im1*re2 },
// Div
function(re1, im1, re2, im2) {
(-re1*im2 +im1*re2)
/
(+re2*re2 +im2*im2)
},
// Pow
function(re1, im1, re2, im2) {
exp(+re2/2*ln(+pow(re1, 2) +pow(im1, 2)) -im2*atan2(im1, re1))
*
sin(+im2/2*ln(+pow(re1, 2) +pow(im1, 2)) +re2*atan2(im1, re1))
}
}
;
#undef NO_OF_OPERATORS
#declare POW_IDX = IndexOfString("Pow", OPERATOR_TYPES);
#undef RE_OPERATOR_FUNCTIONS[POW_IDX]
#declare RE_OPERATOR_FUNCTIONS[POW_IDX] =
HandleZerosFunction(
function(re1, im1, re2, im2) {
exp(+re2/2*ln(+pow(re1, 2) +pow(im1, 2)) -im2*atan2(im1, re1))
*
cos(+im2/2*ln(+pow(re1, 2) +pow(im1, 2)) +re2*atan2(im1, re1))
}
)
;
#undef IM_OPERATOR_FUNCTIONS[POW_IDX]
#declare IM_OPERATOR_FUNCTIONS[POW_IDX] =
HandleZerosFunction(
function(re1, im1, re2, im2) {
exp(+re2/2*ln(+pow(re1, 2) +pow(im1, 2)) -im2*atan2(im1, re1))
*
sin(+im2/2*ln(+pow(re1, 2) +pow(im1, 2)) +re2*atan2(im1, re1))
}
)
;
#undef POW_IDX
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10
#macro ReZFunction()
function(re, im) { re }
#end // macro ReZFunction
#macro ImZFunction()
function(re, im) { im }
#end // macro ImZFunction
#macro ReConstFunction(ReVal)
function(re, im) { ReVal }
#end // macro ReConstFunction
#macro ImConstFunction(ImVal)
function(re, im) { ImVal }
#end // macro ImConstFunction
#macro Args1Function(OpFn, ReFns, ImFns, Arg)
function(re, im) {
OpFn(
ReFns[Arg](re, im), ImFns[Arg](re, im)
)
}
#end // macro Args1Function
#macro Args2Function(OpFn, ReFns, ImFns, Arg1, Arg2)
function(re, im) {
OpFn(
ReFns[Arg1](re, im), ImFns[Arg1](re, im),
ReFns[Arg2](re, im), ImFns[Arg2](re, im)
)
}
#end // macro Args2Function
#macro GetOpFunction(OpFns, ReFns, ImFns, ExprType, ArgNoFn)
#local Idx = IndexOfString(ExprType, OPERATOR_TYPES);
#if (Idx < 0)
#error "Unknown function type"
#end // if
#switch (NO_OF_ARGUMENTS[Idx])
#case (1)
Args1Function(OpFns[Idx], ReFns, ImFns, ArgNoFn(1))
#break
#case (2)
Args2Function(OpFns[Idx], ReFns, ImFns, ArgNoFn(1), ArgNoFn(2))
#break
#else
#error "Uknown problem"
#end // switch
#end // macro GetOpFunction
#macro ReChooseFunction(ReFns, ImFns, ExprType, ArgNoFn)
#if (strcmp(ExprType, "Z") = 0)
ReZFunction()
#else
#if (strcmp(ExprType, "Const") = 0)
#local ReVal = ArgNoFn(-1);
ReConstFunction(ReVal)
#else
GetOpFunction(RE_OPERATOR_FUNCTIONS, ReFns, ImFns, ExprType, ArgNoFn)
#end // if
#end // if
#end // macro ReChooseFunction
#macro ImChooseFunction(ReFns, ImFns, ExprType, ArgNoFn)
#if (strcmp(ExprType, "Z") = 0)
ImZFunction()
#else
#if (strcmp(ExprType, "Const") = 0)
#local ImVal = ArgNoFn(-2);
ImConstFunction(ImVal)
#else
GetOpFunction(IM_OPERATOR_FUNCTIONS, ReFns, ImFns, ExprType, ArgNoFn)
#end // if
#end // if
#end // macro ImChooseFunction
#macro AssembleFunctions(ExprTypes, ArgNoFns, ReFns, ImFns)
#local No = dimension_size(ExprTypes, 1);
#for (I, 0, No-1)
#declare ExprType = ExprTypes[I];
#declare ReFns[I] = ReChooseFunction(ReFns, ImFns, ExprType, ArgNoFns[I])
#declare ImFns[I] = ImChooseFunction(ReFns, ImFns, ExprType, ArgNoFns[I])
#end // for
#end // macro AssembleFunctions
#macro ZFn()
function(s) { 0 + sqrt(-1) } // This function should never be called.
#end // macro ZFn
#macro RealConstFn(ReVal)
function(s) { select(s + 1, 0, ReVal, 0) }
#end // macro RealConstFn
#macro ImagConstFn(ImVal)
function(s) { select(s + 2, 0, ImVal, 0) }
#end // macro ImagConstFn
#macro ComplexConstFn(ReVal, ImVal)
function(s) { select(s + 1, select(s + 2, 0, ImVal, 0), ReVal, 0) }
#end // macro ComplexConstFn
#macro Arg1Fn(Arg1)
function(s) { select(s - 1, -1, Arg1, -1) }
#end // macro Arg1Fn
#macro Arg2Fn(Arg1, Arg2)
function(s) { select(s - 1, -1, Arg1, select(s - 2, -1, Arg2, -1)) }
#end // macro Arg2Fn
#macro FinalFunction(Fns)
#local NoOfFns = dimension_size(Fns, 1);
function(re, im) { Fns[NoOfFns-1](re, im) }
#end // macro FinalFunction
#macro GetReOpFunction(OpName)
#local Idx = IndexOfString(OpName, OPERATOR_TYPES);
function(re, im) { RE_OPERATOR_FUNCTIONS[Idx](re, im) }
#end // macro GetReOpFunction
#macro GetImOpFunction(OpName)
#local Idx = IndexOfString(OpName, OPERATOR_TYPES);
function(re, im) { IM_OPERATOR_FUNCTIONS[Idx](re, im) }
#end // macro GetImOpFunction
#macro CompoundFunction(Fn, ReFn, ImFn)
function(re, im) { Fn(ReFn(re, im), ImFn(re, im)) }
#end // macro CompoundFunction
#macro MagnitudeFunction(ReFn, ImFn)
CompoundFunction(GetReOpFunction("Abs"), ReFn, ImFn)
#end // macro MagnitudeFunction
#macro PhaseFunction(ReFn, ImFn)
CompoundFunction(GetReOpFunction("Phase"), ReFn, ImFn )
#end // macro PhaseFunction
// ===== 1 ======= 2 ======= 3 ======= 4 ======= 5 ======= 6 ======= 7 ======= 8 ======= 9 ======= 10