build.gradle

plugins {
    id 'fabric-loom' version '1.8.12'
    id 'babric-loom-extension' version '1.8.9'
    id 'maven-publish'
    id("com.modrinth.minotaur") version "2.+"
    id "com.diffplug.spotless" version "6.2.2"
}

sourceCompatibility = targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

loom {
    mixin {
        useLegacyMixinAp = true
    }
    customMinecraftManifest.set("https://babric.github.io/manifest-polyfill/${minecraft_version}.json")
    intermediaryUrl.set("https://maven.glass-launcher.net/babric/babric/intermediary/%1\$s/intermediary-%1\$s-v2.jar")
}

repositories {
    // Add repositories to retrieve artifacts from in here.
    // You should only use this when depending on other mods because
    // Loom adds the essential maven repositories to download Minecraft and libraries from automatically.
    // See https://docs.gradle.org/current/userguide/declaring_repositories.html
    // for more information about repositories.

    // Used for the fabric toolchain in this project.
    maven {
        name = 'Babric'
        url = 'https://maven.glass-launcher.net/babric'
    }
    // Used for mappings.
    maven {
        name = 'Glass Releases'
        url = 'https://maven.glass-launcher.net/releases'
    }
    // Used for StationAPI and HowManyItems.
    maven {
        name = 'Glass Snapshots'
        url = 'https://maven.glass-launcher.net/snapshots'
    }
    // Used for a StationAPI dependency.
    maven {
        name = 'Froge'
        url 'https://maven.minecraftforge.net/'
    }
    // Used for projects that do not have a maven repository, but do have a GitHub repository with working build scripts.
    maven {
        name = 'Jitpack'
        url = 'https://jitpack.io'
    }
    // Used for another StationAPI dependency
    exclusiveContent {
        forRepository {
            maven {
                name = "Modrinth"
                url = "https://api.modrinth.com/maven"
            }
        }
        filter {
            includeGroup "maven.modrinth"
        }
    }
    mavenCentral()
}

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings "net.glasslauncher:biny:${project.yarn_mappings}:v2"
    modImplementation "babric:fabric-loader:${project.loader_version}"

    def lombok = "org.projectlombok:lombok:1.18.22"
    compileOnly lombok
    annotationProcessor lombok
    include(implementation("com.github.GeyserMC:MCAuthLib:d9d773e5d50327c33898c65cd545a4f6ef3ba1b5"))
    implementation(include("blue.endless:jankson:1.2.1") as Dependency)

    implementation "com.google.guava:guava:33.2.1-jre"
    implementation "com.google.code.gson:gson:2.9.0"
    implementation "org.slf4j:slf4j-api:1.8.0-beta4"
    implementation 'org.apache.logging.log4j:log4j-slf4j18-impl:2.17.2'
    implementation(include("me.carleslc:Simple-Yaml:1.8.4") as Dependency)

    // Optional, but convenient mods for mod creators and users alike.
    modImplementation("net.glasslauncher.mods:ModMenu:${project.modmenu_version}") {
        transitive false
    }

    modImplementation("net.glasslauncher.mods:glass-networking:${project.glass_networking_version}") {
        transitive false
    }

    modImplementation("net.glasslauncher.mods:GlassConfigAPI:${project.gcapi_version}") {
        transitive false
    }

    modImplementation("com.github.matthewperiut:retrocommands:${project.retrocommands_version}") {
        transitive false
    }

//	// StationAPI dependency
//	modImplementation "net.modificationstation:StationAPI:${project.stapi_version}"
//
//	// StationAPI development mods
//	modImplementation("net.glasslauncher.mods:AlwaysMoreItems:${project.alwaysmoreitems_version}") {
//		transitive false
//	}
//
//	modImplementation("com.github.paulevsGitch:BHCreative:${project.bhcreative_version}"){
//		transitive false
//	}
//
//	modImplementation("net.danygames2014:spawneggs:${project.spawneggs_version}") {
//		transitive false
//	}
//
//	modRuntimeOnly ("maven.modrinth:fast-stapi-intro:${project.stapi_fast_intro_version}") {
//		transitive false
//	}
}

processResources {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

spotless {
    ratchetFrom "origin/master"
    java {
        licenseHeaderFile(rootProject.file("HEADER"))
    }
}

modrinth {
    token = System.getenv("MODRINTH_TOKEN")
    projectId = "cTg2WC1D"
    uploadFile = remapJar
    gameVersions = [project.minecraft_version]
    loaders = ["fabric"]
    changelog = rootProject.file("CHANGELOG.md").text
    syncBodyFrom = rootProject.file("README.md").text
}
tasks.modrinth.dependsOn(tasks.modrinthSyncBody)