build.common.gradle

import org.gradle.api.tasks.testing.logging.TestExceptionFormat
import org.gradle.api.tasks.testing.logging.TestLogEvent

buildscript {
    repositories {
        mavenCentral()
        mavenLocal()
    }
}

apply plugin: "java-library"
apply plugin: "checkstyle"
apply plugin: "idea"
apply plugin: "com.github.spotbugs"

apply from: "$rootProject.rootDir/build.libraries.gradle"

group = "com.transferwise.common"

repositories {
    mavenCentral()
    mavenLocal()
}

configurations {
    local {
        canBeResolved(false)
        canBeConsumed(false)
    }
    compileClasspath {
        extendsFrom(local)
    }
    runtimeClasspath {
        extendsFrom(local)
    }
    testCompileClasspath {
        extendsFrom(local)
    }
    testRuntimeClasspath {
        extendsFrom(local)
    }
    annotationProcessor {
        extendsFrom(local)
    }
    testAnnotationProcessor {
        extendsFrom(local)
    }
}

dependencies {
    local(platform(libraries.springBootDependencies))

    local(libraries.lombok)

    compileOnly libraries.spotbugsAnnotations
}

java {
    sourceCompatibility = JavaVersion.VERSION_17
    targetCompatibility = JavaVersion.VERSION_17
    withSourcesJar()
    withJavadocJar()
}

jar {
    manifest {
        attributes(
                "Implementation-Title": "Transferwise Base Utils",
                "Implementation-Version": archiveVersion
        )
    }
}

compileJava {
    options.encoding = 'utf-8'
    options.compilerArgs << '-parameters'
    options.compilerArgs << '-Xlint'
    options.compilerArgs << '-Xlint:-processing'

    options.fork = true
    options.forkOptions.jvmArgs << '-Xmx256m'
}

compileTestJava {
    options.fork = true
    options.forkOptions.jvmArgs << '-Xmx256m'
}

test {
    // To test ThreadUtils
    // jvmArgs "-Xlog:safepoint=info"

    useJUnitPlatform()

    testLogging {
        events TestLogEvent.STARTED, TestLogEvent.FAILED, TestLogEvent.SKIPPED, TestLogEvent.PASSED,
                TestLogEvent.STANDARD_ERROR
        showExceptions = true
        showStackTraces = true
        exceptionFormat = TestExceptionFormat.FULL
    }
}

tasks.findAll { it.name.startsWith("spotbugs") }*.configure {
    excludeFilter = file("$rootProject.rootDir/spotbugs-exclude.xml")

    reports {
        xml.required = true
        html.required = true
    }
}

tasks.withType(Checkstyle).configureEach {
    config = resources.text.fromFile(file("$rootProject.rootDir/google_checks.xml"))

    // Deprecated, checkstyle does not like the namings.
    exclude "com/transferwise/common/baseutils/tracing/**"

    maxWarnings = 0

    reports {
        xml.required = true
        html.required = true
    }
}