build.gradle

plugins {
	id "fabric-loom" version "1.0-SNAPSHOT"
	id "io.github.juuxel.loom-quiltflower" version "1.7.3"
	id "io.github.p03w.machete" version "1.2.0"
	id "org.quiltmc.quilt-mappings-on-loom" version "4.2.1"
}

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

repositories {
	maven {
		url "https://api.modrinth.com/maven"
		content { includeGroup "maven.modrinth" }
	}
	maven { url "https://maven.quiltmc.org/repository/release" }
	maven { url "https://pkgs.dev.azure.com/djtheredstoner/DevAuth/_packaging/public/maven/v1" } //dev-auth
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"

	mappings loom.layered {
		it.addLayer(quiltMappings.mappings("org.quiltmc:quilt-mappings:${project.quilt_mappings}:v2"))
		it.mappings("net.fabricmc:yarn:${project.yarn_mappings}:v2")
	}

	modImplementation "net.fabricmc:fabric-loader:${project.fabric_loader}"
	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_api}"

	modLocalRuntime "maven.modrinth:lazydfu:0.1.3"
	modLocalRuntime "maven.modrinth:ferrite-core:5.0.0-fabric"
	modLocalRuntime "maven.modrinth:starlight:1.1.1+1.19"
	modLocalRuntime "maven.modrinth:modmenu:4.0.6"
	modLocalRuntime "me.djtheredstoner:DevAuth-fabric:1.0.0"
}

processResources {
	inputs.property "version", project.version
	filesMatching("fabric.mod.json") {
		expand "version": project.version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = "UTF-8"
	it.options.release = 17
}

java {
	sourceCompatibility = JavaVersion.VERSION_17
	targetCompatibility = JavaVersion.VERSION_17

	withSourcesJar()
}