Support bundling CLI and minor updates

.github/workflows/ci.yml

@@ -0,0 +1,29 @@
+name: Build
+
+on:
+  pull_request:
+  push:
+    branches:
+      - master
+  workflow_dispatch:
+
+jobs:
+  build:
+    strategy:
+      matrix:
+        os: [ ubuntu-latest, windows-latest ]
+    runs-on: ${{ matrix.os }}
+    steps:
+      - uses: actions/checkout@v4
+      - uses: actions/setup-java@v4
+        with:
+          distribution: 'zulu'
+          java-version: 21
+      - uses: gradle/actions/setup-gradle@v4
+      - run: ./gradlew build
+      - uses: actions/upload-artifact@v4
+        if: matrix.os == 'ubuntu-latest'
+        with:
+          name: svg2compose-binary
+          path: build/libs/svg2compose-*-binary.jar
+          if-no-files-found: error

build.gradle.kts

@@ -1,35 +1,41 @@
-import org.jetbrains.kotlin.gradle.tasks.KotlinCompile
-
 plugins {
-    kotlin("jvm") version "1.5.21"
+    kotlin("jvm") version "2.0.0"
+    id("com.github.gmazzo.buildconfig") version "5.4.0"
     id("maven-publish")
 }
 
 group = "br.com.devsrsouza"
 version = "0.7.0"
+description = "Converts SVG or Android Vector Drawable to Compose code."
+val baseName = "svg2compose"
 
-repositories {
-    mavenCentral()
-    maven("https://maven.google.com")
-    maven("https://jetbrains.bintray.com/trove4j")
-}
+val r8: Configuration by configurations.creating
 
 dependencies {
-    implementation("com.google.guava:guava:23.0")
-    implementation("com.android.tools:sdk-common:27.2.0-alpha16")
-    implementation("com.android.tools:common:27.2.0-alpha16")
-    implementation("com.squareup:kotlinpoet:1.9.0")
+    implementation("com.google.guava:guava:33.2.1-jre")
+    implementation("com.android.tools:sdk-common:31.5.1")
+    implementation("com.android.tools:common:31.5.1")
+    implementation("com.squareup:kotlinpoet:1.18.1")
     implementation("org.ogce:xpp3:1.1.6")
+    implementation("com.github.ajalt.clikt:clikt:4.4.0")
 
     testImplementation(kotlin("test-junit"))
+
+    r8("com.android.tools:r8:8.3.37")
 }
 
 tasks.test {
     useJUnit()
 }
 
-tasks.withType<KotlinCompile>() {
-    kotlinOptions.jvmTarget = "1.8"
+java {
+  toolchain.languageVersion = JavaLanguageVersion.of(11)
+}
+
+buildConfig {
+    buildConfigField("VERSION_NAME", version.toString())
+    buildConfigField("DESCRIPTION", description)
+    packageName = "br.com.devsrsouza.svg2compose"
 }
 
 publishing {
@@ -39,3 +45,100 @@ publishing {
         }
     }
 }
+
+tasks.withType<Jar>().configureEach {
+    archiveBaseName = baseName
+    archiveVersion = version.toString()
+
+    manifest {
+        attributes["Main-Class"] = "br.com.devsrsouza.svg2compose.MainKt"
+        attributes["Implementation-Version"] = version.toString()
+    }
+}
+
+val fatJar by tasks.registering(Jar::class) {
+    dependsOn(configurations.runtimeClasspath)
+    dependsOn(tasks.jar)
+
+    from(sourceSets.main.map { it.output.classesDirs + it.output.resourcesDir })
+    from(configurations.runtimeClasspath.map { it.asFileTree.files.map(::zipTree) })
+
+    archiveClassifier = "fat"
+
+    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
+
+    exclude(
+        "**/*.kotlin_metadata",
+        "**/*.kotlin_builtins",
+        "**/*.kotlin_module",
+        "**/module-info.class",
+        "assets/**",
+        "font_metrics.properties",
+        "META-INF/AL2.0",
+        "META-INF/DEPENDENCIES",
+        "META-INF/jdom-info.xml",
+        "META-INF/LGPL2.1",
+        "META-INF/maven/**",
+        "META-INF/native-image/**",
+        "META-INF/proguard/**",
+        "META-INF/*.version",
+        "META-INF/*.SF",
+        "META-INF/*.DSA",
+        "META-INF/*.RSA",
+        "**/*.proto",
+        "**/*.dex",
+        "**/LICENSE**",
+        "**/NOTICE**",
+        "r8-version.properties",
+        "migrateToAndroidx/*",
+        "xsd/catalog.xml",
+    )
+}
+
+val r8File = layout.buildDirectory.file("libs/$baseName-$version-r8.jar").map { it.asFile }
+val rulesFile = project.file("src/main/proguard-rules.pro")
+val r8Jar by tasks.registering(JavaExec::class) {
+    dependsOn(fatJar)
+
+    val fatJarFile = fatJar.get().archiveFile
+    inputs.file(fatJarFile)
+    inputs.file(rulesFile)
+    outputs.file(r8File)
+
+    classpath(r8)
+    mainClass = "com.android.tools.r8.R8"
+    args(
+        "--release",
+        "--classfile",
+        "--output", r8File.get().path,
+        "--pg-conf", rulesFile.path,
+        "--lib", System.getProperty("java.home"),
+        fatJarFile.get().toString(),
+    )
+}
+
+val binaryFile = layout.buildDirectory.file("libs/$baseName-$version-binary.jar").map { it.asFile }
+val binaryJar by tasks.registering(Task::class) {
+    dependsOn(r8Jar)
+
+    val r8FileProvider = layout.file(r8File)
+    val binaryFileProvider = layout.file(binaryFile)
+    inputs.files(r8FileProvider)
+    outputs.file(binaryFileProvider)
+
+    doLast {
+        val r8File = r8FileProvider.get().asFile
+        val binaryFile = binaryFileProvider.get().asFile
+
+        binaryFile.parentFile.mkdirs()
+        binaryFile.delete()
+        binaryFile.writeText("#!/bin/sh\n\nexec java \$JAVA_OPTS -jar \$0 \"\$@\"\n\n")
+        binaryFile.appendBytes(r8File.readBytes())
+
+        binaryFile.setExecutable(true, false)
+    }
+}
+
+tasks.assemble {
+    dependsOn(binaryJar)
+}

gradle.properties

@@ -1 +1,5 @@
 kotlin.code.style=official
+
+org.gradle.caching=true
+org.gradle.jvmargs=-Dfile.encoding=UTF-8
+org.gradle.parallel=true

gradle/wrapper/gradle-wrapper.properties

@@ -1,5 +1,7 @@
 distributionBase=GRADLE_USER_HOME
 distributionPath=wrapper/dists
-distributionUrl=https\://services.gradle.org/distributions/gradle-6.6.1-bin.zip
+distributionUrl=https\://services.gradle.org/distributions/gradle-8.9-bin.zip
+networkTimeout=10000
+validateDistributionUrl=true
 zipStoreBase=GRADLE_USER_HOME
 zipStorePath=wrapper/dists