feat(cursor-cli): add Cursor CLI module

registry/coder-labs/modules/cursor-cli/README.md

@@ -0,0 +1,124 @@
+---
+display_name: Cursor CLI
+icon: ../../../../.icons/cursor.svg
+description: Run Cursor CLI agent in your workspace (no AgentAPI)
+verified: true
+tags: [agent, cursor, ai, cli]
+---
+
+# Cursor CLI
+
+Run the Cursor Coding Agent in your workspace using the Cursor CLI directly.
+
+A full example with MCP, rules, and pre/post install scripts:
+
+```tf
+
+data "coder_parameter" "ai_prompt" {
+  type        = "string"
+  name        = "AI Prompt"
+  default     = ""
+  description = "Build a Minesweeper in Python."
+  mutable     = true
+}
+
+module "coder-login" {
+  count    = data.coder_workspace.me.start_count
+  source   = "registry.coder.com/coder/coder-login/coder"
+  version  = "1.0.31"
+  agent_id = coder_agent.main.id
+}
+
+module "cursor_cli" {
+  source   = "registry.coder.com/coder-labs/cursor-cli/coder"
+  version  = "0.1.0"
+  agent_id = coder_agent.example.id
+  folder   = "/home/coder/project"
+
+  # Optional
+  install_cursor_cli = true
+  cursor_cli_version = "latest"
+  force              = true
+  model              = "gpt-5"
+  ai_prompt          = data.coder_parameter.ai_prompt.value
+
+  # Minimal MCP server (writes `folder/.cursor/mcp.json`):
+  mcp = jsonencode({
+    mcpServers = {
+      playwright = {
+        command = "npx"
+        args    = ["-y", "@playwright/mcp@latest", "--headless", "--isolated", "--no-sandbox"]
+      }
+      desktop-commander = {
+        command = "npx"
+        args    = ["-y", "@wonderwhy-er/desktop-commander"]
+      }
+    }
+  })
+
+  # Use a pre_install_script to install the CLI
+  pre_install_script = <<-EOT
+    #!/usr/bin/env bash
+    set -euo pipefail
+    curl -fsSL https://deb.nodesource.com/setup_20.x | bash -
+    apt-get install -y nodejs
+  EOT
+
+  # Use post_install_script to wait for the repo to be ready
+  post_install_script = <<-EOT
+    #!/usr/bin/env bash
+    set -euo pipefail
+    TARGET="$${FOLDER}/.git/config"
+    echo "[cursor-cli] waiting for $${TARGET}..."
+    for i in $(seq 1 600); do
+      [ -f "$TARGET" ] && { echo "ready"; exit 0; }
+      sleep 1
+    done
+    echo "timeout waiting for $${TARGET}" >&2
+  EOT
+
+  # Provide a map of file name to content; files are written to `folder/.cursor/rules/<name>`.
+  rules_files = {
+    "python.mdc" = <<-EOT
+        ---
+        description: RPC Service boilerplate
+        globs:
+        alwaysApply: false
+        ---
+
+        - Use our internal RPC pattern when defining services
+        - Always use snake_case for service names.
+
+        @service-template.ts
+      EOT
+
+    "frontend.mdc" = <<-EOT
+        ---
+        description: RPC Service boilerplate
+        globs:
+        alwaysApply: false
+        ---
+
+        - Use our internal RPC pattern when defining services
+        - Always use snake_case for service names.
+
+        @service-template.ts
+      EOT
+  }
+}
+```
+
+> [!NOTE]
+> A `.cursor` directory will be created in the specified `folder`, containing the MCP configuration, rules
+> Cursor CLI doesn't seem fully compatible with MCPs, so Coder tasks and Coder MCP will not work with this module.
+
+## References
+
+- See Cursor CLI docs: `https://docs.cursor.com/en/cli/overview`
+- For MCP project config, see `https://docs.cursor.com/en/context/mcp#using-mcp-json`. This module writes your `mcp_json` into `folder/.cursor/mcp.json`.
+- For Rules, see `https://docs.cursor.com/en/context/rules#project-rules`. Provide `rules_files` (map of file name to content) to populate `folder/.cursor/rules/`.
+
+## Troubleshooting
+
+- Ensure the CLI is installed (enable `install_cursor_cli = true` or preinstall it in your image)
+- Logs are written to `~/.cursor-cli-module/`

registry/coder-labs/modules/cursor-cli/cursor-cli.tftest.hcl

@@ -0,0 +1,116 @@
+// Terraform tests for the cursor-cli module
+// Validates that we render expected script content given inputs
+
+run "defaults" {
+  command = plan
+
+  variables {
+    agent_id = "test-agent"
+    folder   = "/home/coder"
+  }
+
+  assert {
+    condition     = can(regex("Cursor CLI", resource.coder_script.cursor_cli.display_name))
+    error_message = "Expected coder_script to be created"
+  }
+}
+
+run "non_interactive_mode" {
+  command = plan
+
+  variables {
+    agent_id      = "test-agent"
+    folder        = "/home/coder"
+    output_format = "json"
+    ai_prompt     = "refactor the auth module to use JWT tokens"
+  }
+
+  assert {
+    // non-interactive always prints; output format propagates
+    condition     = can(regex("OUTPUT_FORMAT='json'", resource.coder_script.cursor_cli.script))
+    error_message = "Expected OUTPUT_FORMAT to be propagated"
+  }
+
+  assert {
+    condition     = can(regex("AI_PROMPT='refactor the auth module to use JWT tokens'", resource.coder_script.cursor_cli.script))
+    error_message = "Expected ai_prompt to be propagated via AI_PROMPT"
+  }
+}
+
+run "model_and_force" {
+  command = plan
+
+  variables {
+    agent_id = "test-agent"
+    folder   = "/home/coder"
+    model    = "test-model"
+    force    = true
+  }
+
+  assert {
+    condition     = can(regex("MODEL='test-model'", resource.coder_script.cursor_cli.script))
+    error_message = "Expected MODEL to be propagated"
+  }
+
+  assert {
+    condition     = can(regex("FORCE='true'", resource.coder_script.cursor_cli.script))
+    error_message = "Expected FORCE true to be propagated"
+  }
+}
+
+run "additional_settings_propagated" {
+  command = plan
+
+  variables {
+    agent_id = "test-agent"
+    folder   = "/home/coder"
+    mcp_json = jsonencode({ mcpServers = { foo = { command = "foo", type = "stdio" } } })
+    rules_files = {
+      "global.yml" = "version: 1\nrules:\n  - name: global\n    include: ['**/*']\n    description: global rule"
+    }
+    pre_install_script  = "#!/bin/bash\necho pre-install"
+    post_install_script = "#!/bin/bash\necho post-install"
+  }
+
+  // Ensure project mcp_json is passed
+  assert {
+    condition     = can(regex(base64encode(jsonencode({ mcpServers = { foo = { command = "foo", type = "stdio" } } })), resource.coder_script.cursor_cli.script))
+    error_message = "Expected PROJECT_MCP_JSON (base64) to be in the install step"
+  }
+
+  // Ensure rules map is passed
+  assert {
+    condition     = can(regex(base64encode(jsonencode({ "global.yml" : "version: 1\nrules:\n  - name: global\n    include: ['**/*']\n    description: global rule" })), resource.coder_script.cursor_cli.script))
+    error_message = "Expected PROJECT_RULES_JSON (base64) to be in the install step"
+  }
+
+  // Ensure pre/post install scripts are embedded
+  assert {
+    condition     = can(regex(base64encode("#!/bin/bash\necho pre-install"), resource.coder_script.cursor_cli.script))
+    error_message = "Expected pre-install script to be embedded"
+  }
+  assert {
+    condition     = can(regex(base64encode("#!/bin/bash\necho post-install"), resource.coder_script.cursor_cli.script))
+    error_message = "Expected post-install script to be embedded"
+  }
+}
+
+run "api_key_env_var" {
+  command = plan
+
+  variables {
+    agent_id = "test-agent"
+    folder   = "/home/coder"
+    api_key  = "sk-test-123"
+  }
+
+  assert {
+    condition     = resource.coder_env.cursor_api_key[0].name == "CURSOR_API_KEY"
+    error_message = "Expected CURSOR_API_KEY env to be created when api_key is set"
+  }
+
+  assert {
+    condition     = resource.coder_env.cursor_api_key[0].value == "sk-test-123"
+    error_message = "Expected CURSOR_API_KEY env value to be set from api_key"
+  }
+}