configure maven publishing

edward3h · Mar 1, 2025 · 41e48e5 · 41e48e5
1 parent 996ff8b
commit 41e48e5
Show file tree

Hide file tree

Showing 5 changed files with 64 additions and 0 deletions.
diff --git a/buildSrc/src/main/kotlin/publishing-convention.gradle.kts b/buildSrc/src/main/kotlin/publishing-convention.gradle.kts
@@ -0,0 +1,60 @@
+import org.gradle.api.publish.maven.MavenPublication
+import org.gradle.api.tasks.javadoc.Javadoc
+
+plugins {
+    java
+    id("maven-publish")
+    id("signing")
+}
+
+group = rootProject.group
+version = rootProject.version
+
+tasks.withType<Javadoc>() {
+    if(JavaVersion.current().isJava9Compatible()) {
+        (options as StandardJavadocDocletOptions).addBooleanOption("html5", true)
+    }
+}
+
+java {
+    withJavadocJar()
+    withSourcesJar()
+}
+
+publishing {
+    publications {
+        create<MavenPublication>("maven") {
+            from(components["java"])
+
+            pom {
+                name = "kiwiproc"
+                description = "Java build time SQL support"
+                url = "https://github.com/edward3h/kiwiproc"
+                licenses {
+                    license {
+                        name = "GNU General Public License, Version 3"
+                        url = "https://choosealicense.com/licenses/gpl-3.0/"
+                    }
+                }
+                developers {
+                    developer {
+                        name = "Edward Harman"
+                        email = "[email protected]"
+                    }
+                }
+                scm {
+                    connection = "https://github.com/edward3h/kiwiproc.git"
+                    developerConnection = "[email protected]:edward3h/kiwiproc.git"
+                    url = "https://github.com/edward3h/kiwiproc"
+                }
+            }
+        }
+    }
+}
+
+signing {
+    val signingKey = findProperty("signingKey").toString()
+    val signingPassword = findProperty("signingPassword").toString()
+    useInMemoryPgpKeys(signingKey, signingPassword)
+    sign(publishing.publications["maven"])
+}
diff --git a/processor/build.gradle.kts b/processor/build.gradle.kts
@@ -1,5 +1,6 @@
 plugins {
     id("java-convention")
+    id("publishing-convention")
 }
 
 dependencies {

diff --git a/querymeta/build.gradle.kts b/querymeta/build.gradle.kts
@@ -1,5 +1,6 @@
 plugins {
     id("java-convention")
+    id("publishing-convention")
 }
 
 dependencies {

diff --git a/runtime/build.gradle.kts b/runtime/build.gradle.kts
@@ -1,5 +1,6 @@
 plugins {
     id("java-convention")
+    id("publishing-convention")
 }
 
 dependencies {

diff --git a/shared/build.gradle.kts b/shared/build.gradle.kts
@@ -1,5 +1,6 @@
 plugins {
     id("java-convention")
+    id("publishing-convention")
 }
 
 dependencies {