♻️ Groovy -> kts 파일 마이그레이션 (#119)

* ♻️ Groovy -> kts 파일 마이그레이션

* 🚨 규칙 완화

.editorconfig

@@ -2,4 +2,4 @@
 max_line_length = 140
 
 [*.{kt, kts}]
-ktlint_disabled_rules = import-ordering, no-wildcard-imports, trailing-comma-on-declaration-site, trailing-comma-on-call-site
+ktlint_disabled_rules = import-ordering, no-wildcard-imports, trailing-comma-on-declaration-site, trailing-comma-on-call-site, final-newline

app/build.gradle.kts

@@ -0,0 +1,122 @@
+plugins {
+    alias(libs.plugins.android.application)
+    alias(libs.plugins.kotlin.android)
+    alias(libs.plugins.kotlin.kapt)
+    alias(libs.plugins.dagger.hilt)
+    alias(libs.plugins.google.services)
+    alias(libs.plugins.crashlytics)
+    alias(libs.plugins.ktlint)
+    alias(libs.plugins.ksp)
+    alias(libs.plugins.secret)
+    alias(libs.plugins.kotlinx.serialization)
+}
+
+android {
+    namespace = "org.sopt.official"
+    compileSdk = 33
+
+    defaultConfig {
+        applicationId = "org.sopt.official"
+        minSdk = 28
+        targetSdk = 33
+        versionCode = 1
+        versionName = "1.0.0"
+
+        testInstrumentationRunner = "androidx.test.runner.AndroidJUnitRunner"
+    }
+
+    buildTypes {
+        release {
+            isMinifyEnabled = true
+            isShrinkResources = true
+            proguardFiles(
+                getDefaultProguardFile("proguard-android-optimize.txt"),
+                "proguard-rules.pro"
+            )
+        }
+    }
+    applicationVariants.all {
+        val variant = this
+        kotlin {
+            sourceSets {
+                getByName(variant.name) {
+                    kotlin.srcDir("build/generated/ksp/${variant.name}/kotlin")
+                }
+            }
+        }
+    }
+    compileOptions {
+        sourceCompatibility = JavaVersion.VERSION_11
+        targetCompatibility = JavaVersion.VERSION_11
+    }
+    kotlinOptions {
+        jvmTarget = "11"
+    }
+    composeOptions {
+        kotlinCompilerExtensionVersion = libs.versions.compose.compiler.get()
+    }
+    buildFeatures {
+        viewBinding = true
+        compose = true
+    }
+}
+
+dependencies {
+    implementation(libs.kotlin.serialization.json)
+    implementation(libs.core.ktx)
+    implementation(platform(libs.compose.bom))
+    implementation(libs.bundles.compose)
+    implementation(libs.appcompat)
+    implementation(libs.lifecycle.viewmodel)
+    implementation(libs.startup)
+    implementation(libs.security)
+
+    implementation(libs.material)
+    implementation(libs.bundles.accompanist)
+    implementation(libs.inappupdate)
+
+    implementation(platform(libs.okhttp.bom))
+    implementation(libs.bundles.okhttp)
+    implementation(libs.retrofit)
+    implementation(libs.retrofit.kotlin.serialization.converter)
+    implementation(libs.timber)
+
+    implementation(libs.bundles.compose)
+
+    implementation(libs.bundles.mavericks)
+
+    implementation(libs.hilt)
+    kapt(libs.hilt.kapt)
+
+    implementation(platform(libs.firebase))
+    implementation(libs.bundles.firebase)
+
+    implementation(libs.compose.destination.core)
+    ksp(libs.compose.destination.ksp)
+
+    androidTestImplementation(platform(libs.compose.bom))
+    testImplementation(libs.junit)
+    androidTestImplementation(libs.bundles.compose.test)
+    androidTestImplementation(libs.bundles.android.test)
+    debugImplementation(libs.bundles.compose.android.test)
+
+    debugImplementation(libs.bundles.flipper)
+    releaseImplementation(libs.flipper.noop)
+    debugImplementation(libs.flipper.network) {
+        exclude(group = "com.squareup.okhttp3", module = "okhttp")
+    }
+}
+
+secrets {
+    defaultPropertiesFileName = "secrets.defaults.properties"
+
+    ignoreList.add("sdk.*")
+}
+
+ktlint {
+    android.set(true)
+    debug.set(true)
+    coloredOutput.set(true)
+    verbose.set(true)
+    outputToConsole.set(true)
+}

app/proguard-rules.pro

@@ -1,6 +1,6 @@
 # Add project specific ProGuard rules here.
 # You can control the set of applied configuration files using the
-# proguardFiles setting in build.gradle.
+# proguardFiles setting in build.gradle.kts.
 #
 # For more details, see
 #   http://developer.android.com/guide/developing/tools/proguard.html

build.gradle.kts

@@ -0,0 +1,34 @@
+buildscript {
+    repositories {
+        google()
+        mavenCentral()
+        gradlePluginPortal()
+    }
+
+    dependencies {
+        classpath(libs.kotlin.gradleplugin)
+        classpath(libs.hilt.plugin)
+        classpath(libs.agp)
+        classpath(libs.crashlytics.plugin)
+        classpath(libs.ktlint)
+        classpath(libs.secret.plugin)
+    }
+}
+
+plugins {
+    alias(libs.plugins.android.application) apply false
+    alias(libs.plugins.android.library) apply false
+    alias(libs.plugins.kotlin.android) apply false
+    alias(libs.plugins.kotlin.kapt) apply false
+    alias(libs.plugins.dagger.hilt) apply false
+    alias(libs.plugins.google.services) apply false
+    alias(libs.plugins.crashlytics) apply false
+    alias(libs.plugins.ktlint) apply false
+    alias(libs.plugins.ksp) apply false
+    alias(libs.plugins.secret) apply false
+    alias(libs.plugins.kotlinx.serialization) apply false
+}
+
+tasks.register("clean", Delete::class) {
+    delete(rootProject.buildDir)
+}

settings.gradle → settings.gradle.kts

@@ -14,4 +14,4 @@ dependencyResolutionManagement {
     }
 }
 rootProject.name = "SOPT"
-include ':app'
+include(":app")